268a7f29f7ea58a1ce3ba326a37125e4297e9bde
[spider.git] / perl / convkeps.pl
1 #!/usr/bin/perl -w
2 #
3 # Convert an Amsat 2 line keps bull into Sun.pm format
4 #
5 # This program will accept on stdin a standard AMSAT 2 line keps
6 # bull such as you would find in an email or from the packet network
7 #
8 # It will write a file called /spider/local/Keps.pm, this means that
9 # the latest version will be read in every time you restart the 
10 # cluster.pl. You can also call Sun::load from a cron line if
11 # you like to re-read it automatically. If you update it manually
12 # load/keps will load the latest version into the cluster
13 #
14 # This program is designed to be called from /etc/aliases or
15 # a .forward file so you can get yourself on the keps mailing
16 # list from AMSAT and have the keps updated automatically once
17 # a week.
18 #
19 # I will distribute the latest keps with every patch but you can
20 # get your own data from: 
21 #
22 # http://www.amsat.org/amsat/ftp/keps/current/nasa.all
23 #
24 # Please note that this will UPDATE your keps file
25
26 # Usage: 
27 #    email | convkeps.pl        (in amsat email format)  
28 #    convkeps.pl -p keps.in     (a file with just plain keps)
29
30 # if you add the -c flag then the %keps hash will be cleared down
31 # before adding the new ones.
32 #
33 # Copyright (c) 2000 Dirk Koopman G1TLH
34 #
35 # $Id$
36 #
37
38 require 5.004;
39 package Sun;
40
41 # search local then perl directories
42 BEGIN {
43         # root of directory tree for this system
44         $root = "/spider"; 
45         $root = $ENV{'DXSPIDER_ROOT'} if $ENV{'DXSPIDER_ROOT'};
46         
47         unshift @INC, "$root/perl";     # this IS the right way round!
48         unshift @INC, "$root/local";
49 }
50
51 use strict;
52 use vars qw($root %keps);
53
54 use Data::Dumper;
55 require Keps;
56
57 my $fn = "$root/local/Keps.pm";
58 my $state = 0;
59 my $name;
60 my $ref;
61 my $line;
62 my $f = \*STDIN;
63
64 while (@ARGV) {
65         my $arg = shift @ARGV;
66         if ($arg eq '-p') {
67                 $state = 1;
68         } elsif ($arg eq '-e') {
69                 $state = 0;
70         } elsif ($arg eq '-c') {
71                 %keps = ();
72         } elsif ($arg =~ /^-/) {
73                 die "Usage: convkeps.pl [-c] [-e|-p] [<filename>]\n\t-p - plain file just containing keps\n\t-e - amsat email format input file (default)\n\t-c - clear Keps data before adding this lot\n";
74         } else {
75                 open (IN, $arg) or die "cannot open $arg (!$)";
76                 $f = \*IN;
77         }
78 }
79
80 while (<$f>) {
81         ++$line;
82         chomp;
83         s/^\s+//;
84     s/[\s\r]+$//;
85         next unless $_;
86         last if m{^/EX}i;
87         last if m{^-};
88         
89         if ($state == 0 && /^TO ALL/) {
90                 $state = 1;
91         } elsif ($state == 1) {
92                 last if m{^/EX/i};
93                 
94                 if (/^\w+/) {
95                         s/\s/-/g;
96                         $name = uc $_;
97                         $ref = $keps{$name} = {}; 
98                         $state = 2;
99                 }
100         } elsif ($state == 2) {
101                 if (/^1 /) {
102                         my ($id, $number, $epoch, $decay, $mm2, $bstar, $elset) = unpack "xxa5xxa5xxxa15xa10xa8xa8xxxa4x", $_;
103                         $ref->{id} = $id - 0;
104                         $ref->{number} = $number - 0;
105                         $ref->{epoch} = $epoch - 0;
106                         $ref->{mm1} = $decay - 0;
107                         $ref->{mm2} = genenum($mm2);
108                         $ref->{bstar} = genenum($bstar);
109                         $ref->{elset} = $elset - 0;
110                         #print "$id $number $epoch $decay $mm2 $bstar $elset\n"; 
111                         #print "mm2: $ref->{mm2} bstar: $ref->{bstar}\n";
112                         
113                         $state = 3;
114                 } else {
115                         print "out of order on line $line\n";
116                         undef $ref;
117                         delete $keps{$name};
118                         $state = 1;
119                 }
120         } elsif ($state == 3) {
121                 if (/^2 /) {
122                         my ($id, $incl, $raan, $ecc, $peri, $man, $mmo, $orbit) = unpack "xxa5xa8xa8xa7xa8xa8xa11a5x", $_;
123                         $ref->{meananomaly} = $man - 0;
124                         $ref->{meanmotion} = $mmo - 0;
125                         $ref->{inclination} = $incl - 0;
126                         $ref->{eccentricity} = ".$ecc" - 0;
127                         $ref->{argperigee} = $peri - 0;
128                         $ref->{raan} = $raan - 0;
129                         $ref->{orbit} = $orbit - 0;
130                 } else {
131                         print "out of order on line $line\n";
132                         delete $keps{$name};
133                 }
134                 undef $ref;
135                 $state = 1;
136         }
137 }
138
139 my $dd = new Data::Dumper([\%keps], [qw(*keps)]);
140 $dd->Indent(1);
141 $dd->Quotekeys(0);
142 open(OUT, ">$fn") or die "$fn $!";
143 print OUT "#\n# this file is automatically produced by convkeps.pl\n#\n";
144 print OUT "# Last update: ", scalar gmtime, "\n#\n";
145 print OUT "\npackage Sun;\n\n";
146 print OUT $dd->Dumpxs;
147 print OUT "1;\n";
148 close(OUT);
149
150
151 # convert (+/-)00000-0 to (+/-).00000e-0
152 sub genenum
153 {
154         my ($sign, $frac, $esign, $exp) = unpack "aa5aa", shift;
155         $esign = '+' if $esign eq ' ';
156         my $n = $sign . "." . $frac . 'e' . $esign . $exp;
157         return $n - 0;
158 }
159