perl/RBN.pm

   1 #
   2 # The RBN connection system
   3 #
   4 # Copyright (c) 2020 Dirk Koopman G1TLH
   5 #
   6
   7 use warnings;
   8 use strict;
   9
  10 package RBN;
  11
  12 use 5.10.1;
  13
  14 use DXUtil;
  15 use DXDebug;
  16 use DXLog;
  17 use DXUser;
  18 use DXChannel;
  19 use Math::Round qw(nearest);
  20 use Date::Parse;
  21 use Time::HiRes qw(clock_gettime CLOCK_REALTIME);
  22 use Spot;
  23
  24 our @ISA = qw(DXChannel);
  25
  26 our $startup_delay = 5*60;              # don't send anything out until this timer has expired
  27                                 # this is to allow the feed to "warm up" with duplicates
  28                                 # so that the "big rush" doesn't happen.
  29
  30 our $minspottime = 60*60;               # the time between respots of a callsign - if a call is
  31                                 # still being spotted (on the same freq) and it has been
  32                                 # spotted before, it's spotted again after this time
  33                                 # until the next minspottime has passed.
  34
  35 our $beacontime = 5*60;                 # same as minspottime, but for beacons (and shorter)
  36
  37 our $dwelltime = 6;                     # the amount of time to wait for duplicates before issuing
  38                                 # a spot to the user (no doubt waiting with bated breath).
  39
  40 our $filterdef = $Spot::filterdef; # we use the same filter as the Spot system. Can't think why.
  41
  42
  43 sub new
  44 {
  45         my $self = DXChannel::alloc(@_);
  46
  47         # routing, this must go out here to prevent race condx
  48         my $pkg = shift;
  49         my $call = shift;
  50
  51         DXProt::_add_thingy($main::routeroot, [$call, 0, 0, 1, undef, undef, $self->hostname], );
  52         $self->{d} = {};
  53         $self->{spot} = {};
  54         $self->{last} = 0;
  55         $self->{noraw} = 0;
  56         $self->{nospot} = 0;
  57         $self->{norbn} = 0;
  58         $self->{sort} = 'N';
  59         $self->{lasttime} = $main::systime;
  60         $self->{minspottime} = $minspottime;
  61         $self->{beacontime} = $beacontime;
  62         $self->{showstats} = 0;
  63
  64         return $self;
  65 }
  66
  67 sub start
  68 {
  69         my ($self, $line, $sort) = @_;
  70         my $user = $self->{user};
  71         my $call = $self->{call};
  72         my $name = $user->{name};
  73         my $dref = $self->{d};
  74         my $spotref = $self->{spot};
  75
  76         # log it
  77         my $host = $self->{conn}->peerhost;
  78         $host ||= "unknown";
  79         $self->{hostname} = $host;
  80
  81         $self->{name} = $name ? $name : $call;
  82         $self->state('prompt');         # a bit of room for further expansion, passwords etc
  83         $self->{lang} = $user->lang || $main::lang || 'en';
  84         if ($line =~ /host=/) {
  85                 my ($h) = $line =~ /host=(\d+\.\d+\.\d+\.\d+)/;
  86                 $line =~ s/\s*host=\d+\.\d+\.\d+\.\d+// if $h;
  87                 unless ($h) {
  88                         ($h) = $line =~ /host=([\da..fA..F:]+)/;
  89                         $line =~ s/\s*host=[\da..fA..F:]+// if $h;
  90                 }
  91                 $self->{hostname} = $h if $h;
  92         }
  93         $self->{width} = 80 unless $self->{width} && $self->{width} > 80;
  94         $self->{consort} = $line;       # save the connection type
  95
  96         LogDbg('DXCommand', "$call connected from $self->{hostname}");
  97
  98         # set some necessary flags on the user if they are connecting
  99         $self->{registered} = 1;
 100         # sort out privilege reduction
 101         $self->{priv} = 0;
 102
 103         # get the filters
 104         my $nossid = $call;
 105         $nossid =~ s/-\d+$//;
 106
 107         $self->{spotsfilter} = Filter::read_in('spots', $call, 0)
 108                 || Filter::read_in('spots', $nossid, 0)
 109                         || Filter::read_in('spots', 'user_default', 0);
 110
 111         # clean up qra locators
 112         my $qra = $user->qra;
 113         $qra = undef if ($qra && !DXBearing::is_qra($qra));
 114         unless ($qra) {
 115                 my $lat = $user->lat;
 116                 my $long = $user->long;
 117                 $user->qra(DXBearing::lltoqra($lat, $long)) if (defined $lat && defined $long);
 118         }
 119
 120         # start inrush timer
 121         $self->{inrushpreventor} = $main::systime + $startup_delay;
 122 }
 123
 124 my @queue;                                              # the queue of spots ready to send
 125
 126 sub normal
 127 {
 128         my $self = shift;
 129         my $line = shift;
 130         my @ans;
 131         my $spots = $self->{spot};
 132
 133         # save this for them's that need it
 134         my $rawline = $line;
 135
 136         # remove leading and trailing spaces
 137         chomp $line;
 138         $line =~ s/^\s*//;
 139         $line =~ s/\s*$//;
 140
 141         # add base RBN
 142
 143         my $tim = $main::systime;
 144
 145         # parse line
 146         dbg "RBN:RAW,$line" if isdbg('rbnraw');
 147         return unless $line=~/^DX\s+de/;
 148
 149         my (undef, undef, $origin, $qrg, $call, $mode, $s, $m, $spd, $u, $sort, $t, $tx) = split /[:\s]+/, $line;
 150
 151         # fix up FT8 spots from 7001
 152         $t = $u, $u = '' if !$t && is_ztime($u);
 153         $t = $sort, $sort = '' if !$t && is_ztime($sort);
 154         my $qra = $spd, $spd = '' if is_qra($spd);
 155         $u = $qra if $qra;
 156
 157         $origin =~ s/\-(?:\d{1,2}\-)?\#$//; # get rid of all the crap we aren't interested in
 158
 159
 160         $sort ||= '';
 161         $tx ||= '';
 162         $qra ||= '';
 163     dbg qq{or:$origin qr:$qrg ca:$call mo:$mode s:$s m:$m sp:$spd u:$u sort:$sort t:$t tx:$tx qra:$qra} if isdbg('rbn');
 164
 165
 166         my $b;
 167
 168         if ($t || $tx) {
 169
 170                 # fix up times for things like 'NXDXF B' etc
 171                 if ($tx && is_ztime($t)) {
 172                         if (is_ztime($tx)) {
 173                                 $b = $t;
 174                                 $t = $tx;
 175                         } else {
 176                                 dbg "RBN:ERR,$line";
 177                                 return (0);
 178                         }
 179                 }
 180                 if ($sort && $sort eq 'NCDXF') {
 181                         $mode = 'DXF';
 182                         $t = $tx;
 183                 }
 184                 if ($sort && $sort eq 'BEACON') {
 185                         $mode = 'BCN';
 186                 }
 187                 if ($mode =~ /^PSK/) {
 188                         $mode = 'PSK';
 189                 }
 190                 if ($mode eq 'RTTY') {
 191                         $mode = 'RTT';
 192                 }
 193
 194                 # The main de-duping key is [call, $frequency], but we probe a bit around that frequency to find a
 195                 # range of concurrent frequencies that might be in play.
 196
 197                 # The key to this is deducing the true callsign by "majority voting" (the greater the number of spotters
 198         # the more effective this is) together with some lexical analsys probably in conjuction with DXSpider
 199                 # data sources (for singleton spots) to then generate a "centre" from and to zone (whatever that will mean if it isn't the usual one)
 200                 # and some heuristical "Kwalitee" rating given distance from the zone centres of spotter, recipient user
 201         # and spotted. A map can be generated once per user and spotter as they are essentially mostly static.
 202                 # The spotted will only get a coarse position unless other info is available. Programs that parse
 203                 # DX bulletins and the online data online databases could be be used and then cached.
 204
 205                 # Obviously users have to opt in to receiving RBN spots and other users will simply be passed over and
 206                 # ignored.
 207
 208                 # Clearly this will only work in the 'mojo' branch of DXSpider where it is possible to pass off external
 209                 # data requests to ephemeral or semi resident forked processes that do any grunt work and the main
 210                 # process to just the standard "message passing" which has been shown to be able to sustain over 5000
 211                 # per second (limited by the test program's output and network speed, rather than DXSpider's handling).
 212
 213                 my $nqrg = nearest(1, $qrg);  # normalised to nearest Khz
 214                 my $sp = "$call|$nqrg";           # hopefully the skimmers will be calibrated at least this well!
 215                 my $spp = sprintf("$call|%d", $nqrg+1); # but, clearly, my hopes are rudely dashed
 216                 my $spm = sprintf("$call|%d", $nqrg-1); # in BOTH directions!
 217
 218                 # do we have it?
 219                 my $spot = $spots->{$sp};
 220                 $spot = $spots->{$spp}, $sp = $spp, dbg(qq{RBN: SPP using $spp for $sp}) if !$spot && exists $spots->{$spp};
 221                 $spot = $spots->{$spm}, $sp = $spm, dbg(qq{RBN: SPM using $spm for $sp}) if !$spot && exists $spots->{$spm};
 222
 223
 224                 # if we have one and there is only one slot and that slot's time isn't expired for respot then return
 225                 my $respot = 0;
 226                 if ($spot && ref $spot) {
 227                         if (@$spot == 1) {
 228                                 unless ($self->{minspottime} > 0 && $tim - $spot->[0] >= $self->{minspottime}) {
 229                                         dbg("RBN: key: '$sp' call: $call qrg: $qrg DUPE \@ ". atime(int $spot->[0])) if isdbg('rbn');
 230                                         return;
 231                                 }
 232
 233                                 dbg("RBN: key: '$sp' RESPOTTING call: $call qrg: $qrg last seen \@ ". atime(int $spot->[0])) if isdbg('rbn');
 234                                 undef $spot;    # it's about to be recreated (in one place)
 235                                 ++$respot;
 236                         }
 237
 238                         # otherwise we have a spot being built up at the moment
 239                 } elsif ($spot) {
 240                         dbg("RBN: key '$sp' = '$spot' not ref");
 241                         return;
 242                 }
 243
 244                 # here we either have an existing spot record buildup on the go, or we need to create the first one
 245                 unless ($spot) {
 246                         $spots->{$sp} = $spot = [clock_gettime(CLOCK_REALTIME)];;
 247                         dbg("RBN: key: '$sp' call: $call qrg: $qrg NEW" . $respot ? ' RESPOT' : '') if isdbg('rbn');
 248                 }
 249
 250                 # add me to the display queue unless we are waiting for initial in rush to finish
 251                 return unless $self->{inrushpreventor} < $main::systime;
 252                 push @{$self->{queue}}, $sp if @$spot == 1; # queue the KEY (not the record)
 253
 254                 # build up a new record and store it in the buildup
 255                 # deal with the unix time
 256                 my ($hh,$mm) = $t =~ /(\d\d)(\d\d)Z$/;
 257                 my $utz = $hh*3600 + $mm*60 + $main::systime_daystart; # possible issue with late spot from previous day
 258                 $utz -= 86400 if $utz > $tim+3600;                                         # too far ahead, drag it back one day
 259
 260                 # create record and add into the buildup
 261                 my $r = [$origin, nearest(.1, $qrg), $call, $mode, $s, $t, $utz, $respot, $u];
 262                 dbg("RBN: key: '$sp' ADD RECORD call: $call qrg: $qrg origin: $origin") if isdbg('rbn');
 263
 264                 push @$spot, $r;
 265
 266                 # At this point we run the queue to see if anything can be sent onwards to the punter
 267                 my $now = clock_gettime(CLOCK_REALTIME);
 268
 269                 # now run the waiting queue which just contains KEYS ($call|$qrg)
 270                 foreach $sp (@{$self->{queue}}) {
 271                         my $cand = $spots->{$sp};
 272                         unless ($cand && $cand->[0]) {
 273                                 dbg "RBN Cand " . ($cand ? 'def' : 'undef') . " [0] " . ($cand->[0] ? 'def' : 'undef') . " dwell $dwelltime";
 274                                 next;
 275                         }
 276                         if ($now >= $cand->[0] + $dwelltime ) {
 277                                 # we have a candidate, create qualitee value(s);
 278                                 unless (@$cand > 1) {
 279                                         dbg "RBN: QUEUE key '$sp' MISSING RECORDS " . dd($cand) if isdbg 'rbn';
 280                                         shift @{$self->{queue}};
 281                                         next;
 282                                 }
 283                                 my $savedtime = shift @$cand; # save the start time
 284                                 my $r = $cand->[0];
 285                                 my $quality = @$cand;
 286                                 $quality = 9 if $quality > 9;
 287                                 $quality = "Q:$quality";
 288                                 if (isdbg('progress')) {
 289                                         my $s = "RBN: SPOT key: '$sp' = $r->[2] on $r->[1] \@ $r->[5] $quality";
 290                                         $s .=  " route: $self->{call}";
 291                                         dbg($s);
 292                                 }
 293
 294                                 send_dx_spot($self, $quality, $cand);
 295
 296                                 # clear out the data and make this now just "spotted", but no further action required until respot time
 297                                 dbg "RBN: QUEUE key '$sp' cleared" if isdbg 'rbn';
 298
 299                                 $spots->{$sp} = [$savedtime];
 300                                 shift @{$self->{queue}};
 301                         } else {
 302                                 dbg sprintf("RBN: QUEUE key: '$sp' SEND time not yet reached %.1f secs left", $spot->[0] + $dwelltime - $now) if isdbg 'rbnqueue';
 303                         }
 304                 }
 305
 306
 307         } else {
 308                 dbg "RBN:DATA,$line" if isdbg('rbn');
 309         }
 310
 311         #       # periodic clearing out of the two caches
 312         if (($tim % 60 == 0 && $tim > $self->{last}) || ($self->{last} && $tim >= $self->{last} + 60)) {
 313                 my $count = 0;
 314                 my $removed = 0;
 315                 while (my ($k,$v) = each %{$spots}) {
 316                         if ($tim - $v->[0] > $self->{minspottime}*2) {
 317                                 delete $spots->{$k};
 318                                 ++$removed;
 319                         }
 320                         else {
 321                                 ++$count;
 322                         }
 323                 }
 324                 dbg "RBN:ADMIN,$self->{call},spot cache remain: $count removed: $removed"; # if isdbg('rbn');
 325                 dbg "RBN:" . join(',', "STAT", $self->{noraw}, $self->{norbn}, $self->{nospot}) if $self->{showstats};
 326                 $self->{noraw} = $self->{norbn} = $self->{nospot} = 0;
 327                 $self->{last} = int($tim / 60) * 60;
 328         }
 329 }
 330
 331
 332
 333 #       }
 334 # }
 335
 336 # we should get the spot record minus the time, so just an array of record (arrays)
 337 sub send_dx_spot
 338 {
 339         my $self = shift;
 340         my $quality = shift;
 341         my $spot = shift;
 342
 343         # $r = [$origin, $qrg, $call, $mode, $s, $utz, $respot];
 344
 345         my $mode = $spot->[0]->[3]; # as all the modes will be the same;
 346
 347         my @dxchan = DXChannel::get_all();
 348
 349         foreach my $dxchan (@dxchan) {
 350                 next unless $dxchan->is_user;
 351                 my $user = $dxchan->{user};
 352                 next unless $user &&  $user->wantrbn;
 353
 354                 # does this user want this sort of spot at all?
 355                 my $want = 0;
 356                 ++$want if $user->wantbeacon && $mode =~ /^BCN|DXF/;
 357                 ++$want if $user->wantcw && $mode =~ /^CW/;
 358                 ++$want if $user->wantrtty && $mode =~ /^RTT/;
 359                 ++$want if $user->wantpsk && $mode =~ /^PSK/;
 360                 ++$want if $user->wantcw && $mode =~ /^CW/;
 361                 ++$want if $user->wantft && $mode =~ /^FT/;
 362                 ++$want unless $want;   # send everything if nothing is selected.
 363
 364                 next unless $want;
 365
 366                 # send one spot to one user out of the ones that we have
 367                 $self->dx_spot($dxchan, $quality, $spot) if $want;
 368         }
 369 }
 370
 371 sub dx_spot
 372 {
 373         my $self = shift;
 374         my $dxchan = shift;
 375         my $quality = shift;
 376         my $spot = shift;
 377
 378         my $strength = 100;             # because it could if we talk about FTx
 379         my $saver;
 380
 381         my %zone;
 382         my %qrg;
 383         my $respot;
 384         my $qra;
 385
 386         foreach my $r (@$spot) {
 387                 # $r = [$origin, $qrg, $call, $mode, $s, $t, $utz, $respot, $qra];
 388                 # Spot::prepare($qrg, $call, $utz, $comment, $origin);
 389
 390                 my $comment = sprintf "%-3s %2ddB $quality", $r->[3], $r->[4];
 391                 $respot = 1 if $r->[7];
 392                 $qra = $r->[8] if !$qra && $r->[8] && is_qra($r->[8]);
 393
 394                 my @s =  Spot::prepare($r->[1], $r->[2], $r->[6], $comment, $r->[0]);
 395
 396                 ++$zone{$s[11]};                # save the spotter's zone
 397                 ++$qrg{$s[0]};                  # and the qrg
 398
 399
 400                 my $filter = 0;
 401
 402                 if ($dxchan->{rbnfilter}) {
 403                         ($filter, undef) = $dxchan->{rbnfilter}->it(\@s);
 404                         next unless $filter;
 405                         $saver = \@s;
 406                         dbg("RBN: FILTERED call: $s[1] qrg: $s[0] origin: $s[4] dB: $r->[4]") if isdbg 'rbn';
 407                         last;
 408                 }
 409
 410                 # save the lowest strength one
 411                 if ($r->[4] < $strength) {
 412                         $strength = $r->[4];
 413                         $saver = \@s;
 414                         dbg("RBN: STRENGTH call: $s[1] qrg: $s[0] origin: $s[4] dB: $r->[4]") if isdbg 'rbn';
 415                 }
 416         }
 417
 418         if ($saver) {
 419                 my $buf;
 420                 # create a zone list of spotters
 421                 delete $zone{$saver->[11]};  # remove this spotter's zone (leaving all the other zones)
 422                 my $z = join ',', sort {$a <=> $b} keys %zone;
 423
 424                 # determine the most likely qrg and then set it
 425                 my $mv = 0;
 426                 my $fk;
 427                 my $c = 0;
 428                 while (my ($k, $v) = each %qrg) {
 429                         $fk = $k, $mv = $v if $v > $mv;
 430                         ++$c;
 431                 }
 432                 $saver->[0] = $fk;
 433                 $saver->[3] .= '*' if $c > 1;
 434                 $saver->[3] .= '+' if $respot;
 435                 $saver->[3] .= " Z:$z" if $z;
 436
 437                 dbg("RBN: SENDING call: $saver->[1] qrg: $saver->[0] origin: $saver->[4] $saver->[3]") if isdbg 'rbn';
 438                 if ($dxchan->{ve7cc}) {
 439                         my $call = $saver->[1];
 440                         $saver->[1] .= '-#';
 441                         $buf = VE7CC::dx_spot($dxchan, @$saver);
 442                         $saver->[1] = $call;
 443                 } else {
 444                         $buf = $dxchan->format_dx_spot(@$saver);
 445                 }
 446                 $buf =~ s/^DX/RB/;
 447                 $dxchan->local_send('N', $buf);
 448
 449                 if ($qra) {
 450                         my $user = DXUser::get_current($saver->[1]) || DXUser->new($saver->[1]);
 451                         unless ($user->qra && is_qra($user->qra)) {
 452                                 $user->qra($qra);
 453                                 dbg("RBN: update qra on $saver->[1] to $qra");
 454                                 $user->put;
 455                         }
 456                 }
 457         }
 458 }
 459
 460 1;