perl/RBN.pm

   1 #
   2 # The RBN connection system
   3 #
   4 # Copyright (c) 2020 Dirk Koopman G1TLH
   5 #
   6
   7 use warnings;
   8 use strict;
   9
  10 package RBN;
  11
  12 use 5.10.1;
  13
  14 use DXUtil;
  15 use DXDebug;
  16 use DXLog;
  17 use DXUser;
  18 use DXChannel;
  19 use Math::Round qw(nearest);
  20 use Date::Parse;
  21 use Time::HiRes qw(clock_gettime CLOCK_REALTIME);
  22
  23 our @ISA = qw(DXChannel);
  24
  25 our $startup_delay =0;#3*60;            # don't send anything out until this timer has expired
  26                                 # this is to allow the feed to "warm up" with duplicates
  27                                 # so that the "big rush" doesn't happen.
  28
  29 our $minspottime = 60*60;               # the time between respots of a callsign - if a call is
  30                                 # still being spotted (on the same freq) and it has been
  31                                 # spotted before, it's spotted again after this time
  32                                 # until the next minspottime has passed.
  33
  34 our $dwelltime = 6;                     # the amount of time to wait for duplicates before issuing
  35                                 # a spot to the user (no doubt waiting with bated breath).
  36
  37
  38 sub new
  39 {
  40         my $self = DXChannel::alloc(@_);
  41
  42         # routing, this must go out here to prevent race condx
  43         my $pkg = shift;
  44         my $call = shift;
  45
  46         DXProt::_add_thingy($main::routeroot, [$call, 0, 0, 1, undef, undef, $self->hostname], );
  47         $self->{d} = {};
  48         $self->{spot} = {};
  49         $self->{last} = 0;
  50         $self->{noraw} = 0;
  51         $self->{nospot} = 0;
  52         $self->{norbn} = 0;
  53         $self->{sort} = 'N';
  54         $self->{lasttime} = $main::systime;
  55         $self->{minspottime} = $minspottime;
  56         $self->{showstats} = 0;
  57
  58         return $self;
  59 }
  60
  61 sub start
  62 {
  63         my ($self, $line, $sort) = @_;
  64         my $user = $self->{user};
  65         my $call = $self->{call};
  66         my $name = $user->{name};
  67         my $dref = $self->{d};
  68         my $spotref = $self->{spot};
  69
  70         # log it
  71         my $host = $self->{conn}->peerhost;
  72         $host ||= "unknown";
  73         $self->{hostname} = $host;
  74
  75         $self->{name} = $name ? $name : $call;
  76         $self->state('prompt');         # a bit of room for further expansion, passwords etc
  77         $self->{lang} = $user->lang || $main::lang || 'en';
  78         if ($line =~ /host=/) {
  79                 my ($h) = $line =~ /host=(\d+\.\d+\.\d+\.\d+)/;
  80                 $line =~ s/\s*host=\d+\.\d+\.\d+\.\d+// if $h;
  81                 unless ($h) {
  82                         ($h) = $line =~ /host=([\da..fA..F:]+)/;
  83                         $line =~ s/\s*host=[\da..fA..F:]+// if $h;
  84                 }
  85                 $self->{hostname} = $h if $h;
  86         }
  87         $self->{width} = 80 unless $self->{width} && $self->{width} > 80;
  88         $self->{consort} = $line;       # save the connection type
  89
  90         LogDbg('DXCommand', "$call connected from $self->{hostname}");
  91
  92         # set some necessary flags on the user if they are connecting
  93         $self->{registered} = 1;
  94         # sort out privilege reduction
  95         $self->{priv} = 0;
  96
  97         # get the filters
  98         my $nossid = $call;
  99         $nossid =~ s/-\d+$//;
 100
 101         $self->{spotsfilter} = Filter::read_in('spots', $call, 0)
 102                 || Filter::read_in('spots', $nossid, 0)
 103                         || Filter::read_in('spots', 'user_default', 0);
 104
 105         # clean up qra locators
 106         my $qra = $user->qra;
 107         $qra = undef if ($qra && !DXBearing::is_qra($qra));
 108         unless ($qra) {
 109                 my $lat = $user->lat;
 110                 my $long = $user->long;
 111                 $user->qra(DXBearing::lltoqra($lat, $long)) if (defined $lat && defined $long);
 112         }
 113
 114         # start inrush timer
 115         $self->{inrushpreventor} = $main::systime + $startup_delay;
 116 }
 117
 118 my @queue;                                              # the queue of spots ready to send
 119
 120 sub normal
 121 {
 122         my $self = shift;
 123         my $line = shift;
 124         my @ans;
 125         my $spots = $self->{spot};
 126
 127         # save this for them's that need it
 128         my $rawline = $line;
 129
 130         # remove leading and trailing spaces
 131         chomp $line;
 132         $line =~ s/^\s*//;
 133         $line =~ s/\s*$//;
 134
 135         # add base RBN
 136
 137         my $tim = $main::systime;
 138
 139         # parse line
 140         dbg "RBN:RAW,$line" if isdbg('rbnraw');
 141         return unless $line=~/^DX\s+de/;
 142
 143         my (undef, undef, $origin, $qrg, $call, $mode, $s, $m, $spd, $u, $sort, $t, $tx) = split /[:\s]+/, $line;
 144
 145         # fix up FT8 spots from 7001
 146         $t = $u, $u = '' if !$t && is_ztime($u);
 147         $t = $sort, $sort = '' if !$t && is_ztime($sort);
 148         my $qra = $spd, $spd = '' if is_qra($spd);
 149         $u = $qra if $qra;
 150
 151         $origin =~ s/\-(?:\d{1,2}\-)?\#$//; # get rid of all the crap we aren't interested in
 152
 153
 154         $sort ||= '';
 155         $tx ||= '';
 156         $qra ||= '';
 157     dbg qq{or:$origin qr:$qrg ca:$call mo:$mode s:$s m:$m sp:$spd u:$u sort:$sort t:$t tx:$tx qra:$qra} if isdbg('rbn');
 158
 159
 160         my $b;
 161
 162         if ($t || $tx) {
 163
 164                 # fix up times for things like 'NXDXF B' etc
 165                 if ($tx && is_ztime($t)) {
 166                         if (is_ztime($tx)) {
 167                                 $b = $t;
 168                                 $t = $tx;
 169                         } else {
 170                                 dbg "RBN:ERR,$line";
 171                                 return (0);
 172                         }
 173                 }
 174                 if ($sort && $sort eq 'NCDXF') {
 175                         $mode = 'DXF';
 176                         $t = $tx;
 177                 }
 178                 if ($sort && $sort eq 'BEACON') {
 179                         $mode = 'BCN';
 180                 }
 181                 if ($mode =~ /^PSK/) {
 182                         $mode = 'PSK';
 183                 }
 184                 if ($mode eq 'RTTY') {
 185                         $mode = 'RTT';
 186                 }
 187
 188                 # The main de-duping key is [call, $frequency], but we probe a bit around that frequency to find a
 189                 # range of concurrent frequencies that might be in play.
 190
 191                 # The key to this is deducing the true callsign by "majority voting" (the greater the number of spotters
 192         # the more effective this is) together with some lexical analsys probably in conjuction with DXSpider
 193                 # data sources (for singleton spots) to then generate a "centre" from and to zone (whatever that will mean if it isn't the usual one)
 194                 # and some heuristical "Kwalitee" rating given distance from the zone centres of spotter, recipient user
 195         # and spotted. A map can be generated once per user and spotter as they are essentially mostly static.
 196                 # The spotted will only get a coarse position unless other info is available. Programs that parse
 197                 # DX bulletins and the online data online databases could be be used and then cached.
 198
 199                 # Obviously users have to opt in to receiving RBN spots and other users will simply be passed over and
 200                 # ignored.
 201
 202                 # Clearly this will only work in the 'mojo' branch of DXSpider where it is possible to pass off external
 203                 # data requests to ephemeral or semi resident forked processes that do any grunt work and the main
 204                 # process to just the standard "message passing" which has been shown to be able to sustain over 5000
 205                 # per second (limited by the test program's output and network speed, rather than DXSpider's handling).
 206
 207                 my $nqrg = nearest(1, $qrg);  # normalised to nearest Khz
 208                 my $sp = "$call|$nqrg";           # hopefully the skimmers will be calibrated at least this well!
 209                 my $spp = sprintf("$call|%d", $nqrg+1); # but, clearly, my hopes are rudely dashed
 210                 my $spm = sprintf("$call|%d", $nqrg-1); # in BOTH directions!
 211
 212                 # do we have it?
 213                 my $spot = $spots->{$sp};
 214                 $spot = $spots->{$spp} if !$spot && exists $spots->{$spp};
 215                 $spot = $spots->{$spm} if !$spot && exists $spots->{$spm};
 216
 217
 218                 # if we have one and there is only one slot and that slot's time isn't expired for respot then return
 219                 my $respot = 0;
 220                 if ($spot && @$spot == 1) {
 221                         unless ($self->{minspottime} > 0 && $tim - $spot->[0] >= $self->{minspottime}) {
 222                                 dbg("RBN: key: '$sp' call: $call qrg: $qrg DUPE \@ ". atime(int $spot->[0])) if isdbg('rbn');
 223                                 return;
 224                         }
 225                         dbg("RBN: key: '$sp' RESPOTTING call: $call qrg: $qrg last seen \@ ". atime(int $spot->[0])) if isdbg('rbn');
 226                         ++$respot;
 227                 }
 228
 229                 # here we either have an existing spot record buildup on the go, or we need to create the first one
 230                 unless ($spot) {
 231                         $spot = [clock_gettime(CLOCK_REALTIME)];
 232                         $spots->{$sp} = $spot;
 233                         dbg("RBN: key: '$sp' call: $call qrg: $qrg NEW") if isdbg('rbn');
 234                 }
 235
 236                 # add me to the display queue unless we are waiting for initial in rush to finish
 237                 return unless $self->{inrushpreventor} < $main::systime;
 238                 push @queue, $sp if @$spot == 1; # queue the KEY (not the record)
 239
 240                 # build up a new record and store it in the buildup
 241                 # deal with the unix time
 242                 my ($hh,$mm) = $t =~ /(\d\d)(\d\d)Z$/;
 243                 my $utz = $hh*3600 + $mm*60 + $main::systime_daystart; # possible issue with late spot from previous day
 244                 $utz -= 86400 if $utz > $tim+3600;                                         # too far ahead, drag it back one day
 245
 246                 # create record and add into the buildup
 247                 my $r = [$origin, nearest(.1, $qrg), $call, $mode, $s, $t, $utz, $respot];
 248                 dbg("RBN: key: '$sp' ADD RECORD call: $call qrg: $qrg origin: $origin") if isdbg('rbn');
 249
 250                 push @$spot, $r;
 251
 252                 # At this point we run the queue to see if anything can be sent onwards to the punter
 253                 my $now = clock_gettime(CLOCK_REALTIME);
 254
 255                 # now run the waiting queue which just contains KEYS ($call|$qrg)
 256                 foreach $sp (@queue) {
 257                         my $cand = $spots->{$sp};
 258                         if ($now >= $cand->[0]+$dwelltime ) {
 259                                 # we have a candidate, create qualitee value(s);
 260                                 unless (@$cand > 1) {
 261                                         dbg "RBN: QUEUE key '$sp' MISSING RECORDS " . dd($cand) if isdbg 'rbn';
 262                                         shift @queue;
 263                                         next;
 264                                 }
 265                                 my $savedtime = shift @$cand; # save the start time
 266                                 my $r = $cand->[0];
 267                                 my $quality = @$cand;
 268                                 $quality = 9 if $quality > 9;
 269                                 $quality = "Q:$quality";
 270                                 if (isdbg('progress')) {
 271                                         my $s = "RBN: SPOT key: '$sp' = $r->[2] on $r->[1] \@ $r->[5] $quality";
 272                                         $s .=  " route: $self->{call}";
 273                                         dbg($s);
 274                                 }
 275
 276                                 send_dx_spot($self, $quality, $cand);
 277
 278                                 # clear out the data and make this now just "spotted", but no further action required until respot time
 279                                 dbg "RBN: QUEUE key '$sp' cleared" if isdbg 'rbn';
 280
 281                                 $spots->{$sp} = [$savedtime];
 282                                 shift @queue;
 283                         } else {
 284                                 dbg sprintf("RBN: QUEUE key: '$sp' SEND time not yet reached %.1f secs left", $spot->[0] + $dwelltime - $now) if isdbg 'rbnqueue';
 285                         }
 286                 }
 287
 288
 289         } else {
 290                 dbg "RBN:DATA,$line" if isdbg('rbn');
 291         }
 292
 293         #       # periodic clearing out of the two caches
 294         if (($tim % 60 == 0 && $tim > $self->{last}) || ($self->{last} && $tim >= $self->{last} + 60)) {
 295                 my $count = 0;
 296                 my $removed = 0;
 297                 while (my ($k,$v) = each %{$spots}) {
 298                         if ($tim - $v->[0] > $self->{minspottime}*2) {
 299                                 delete $spots->{$k};
 300                                 ++$removed;
 301                         }
 302                         else {
 303                                 ++$count;
 304                         }
 305                 }
 306                 dbg "RBN:ADMIN,spot cache: $removed removed $count remain"; # if isdbg('rbn');
 307                 dbg "RBN:" . join(',', "STAT", $self->{noraw}, $self->{norbn}, $self->{nospot}) if $self->{showstats};
 308                 $self->{noraw} = $self->{norbn} = $self->{nospot} = 0;
 309                 $self->{last} = int($tim / 60) * 60;
 310         }
 311 }
 312
 313
 314
 315 #       }
 316 # }
 317
 318 # we should get the spot record minus the time, so just an array of record (arrays)
 319 sub send_dx_spot
 320 {
 321         my $self = shift;
 322         my $quality = shift;
 323         my $spot = shift;
 324
 325         # $r = [$origin, $qrg, $call, $mode, $s, $utz, $respot];
 326
 327         my $mode = $spot->[0]->[3]; # as all the modes will be the same;
 328
 329         my @dxchan = DXChannel::get_all();
 330
 331         foreach my $dxchan (@dxchan) {
 332                 next unless $dxchan->is_user;
 333                 my $user = $dxchan->{user};
 334                 next unless $user &&  $user->wantrbn;
 335
 336                 # does this user want this sort of spot at all?
 337                 my $want = 0;
 338                 ++$want if $user->wantbeacon && $mode =~ /^BCN|DXF/;
 339                 ++$want if $user->wantcw && $mode =~ /^CW/;
 340                 ++$want if $user->wantrtty && $mode =~ /^RTT/;
 341                 ++$want if $user->wantpsk && $mode =~ /^PSK/;
 342                 ++$want if $user->wantcw && $mode =~ /^CW/;
 343                 ++$want if $user->wantft && $mode =~ /^FT/;
 344                 ++$want unless $want;   # send everything if nothing is selected.
 345
 346                 next unless $want;
 347
 348                 # send one spot to one user out of the ones that we have
 349                 $self->dx_spot($dxchan, $quality, $spot) if $want;
 350         }
 351 }
 352
 353 sub dx_spot
 354 {
 355         my $self = shift;
 356         my $dxchan = shift;
 357         my $quality = shift;
 358         my $spot = shift;
 359
 360         my $strength = 100;             # because it could if we talk about FTx
 361         my $saver;
 362
 363         my %zone;
 364         my %qrg;
 365         my $respot;
 366
 367
 368         foreach my $r (@$spot) {
 369                 # $r = [$origin, $qrg, $call, $mode, $s, $t, $utz, $respot];
 370                 # Spot::prepare($qrg, $call, $utz, $comment, $origin);
 371
 372                 my $comment = sprintf "%-3s %2ddB $quality", $r->[3], $r->[4];
 373                 my @s =  Spot::prepare($r->[1], $r->[2], $r->[6], $comment, $r->[0]);
 374                 $respot = 1 if $r->[7];
 375                 ++$zone{$s[11]};                # save the spotter's zone
 376                 ++$qrg{$s[0]};                  # and the qrg
 377
 378
 379                 # save the highest strength one
 380                 if ($r->[4] < $strength) {
 381                         $strength = $r->[4];
 382                         $saver = \@s;
 383                         dbg("RBN: STRENGTH call: $s[1] qrg: $s[0] origin: $s[4] dB: $r->[4]") if isdbg 'rbn';
 384                 }
 385
 386                 my $filter = 0;
 387
 388                 if ($dxchan->{rbnfilter}) {
 389                         ($filter, undef) = $dxchan->{rbnfilter}->it(\@s);
 390                         next unless $filter;
 391                         $saver = \@s;
 392                         dbg("RBN: FILTERED call: $s[1] qrg: $s[0] origin: $s[4] dB: $r->[4]") if isdbg 'rbn';
 393                         last;
 394                 }
 395
 396         }
 397
 398         if ($saver) {
 399                 my $buf;
 400                 # create a zone list of spotters
 401                 delete $zone{$saver->[11]};  # remove this spotter's zone (leaving all the other zones)
 402                 my $z = join ',', sort {$a <=> $b} keys %zone;
 403
 404                 # determine the most likely qrg and then set it
 405                 my $mv = 0;
 406                 my $fk;
 407                 my $c = 0;
 408                 while (my ($k, $v) = each %qrg) {
 409                         $fk = $k, $mv = $v if $v > $mv;
 410                         ++$c;
 411                 }
 412                 $saver->[0] = $fk;
 413                 $saver->[3] .= '*' if $c > 1;
 414                 $saver->[3] .= '+' if $respot;
 415                 $saver->[3] .= " Z:$z" if $z;
 416
 417                 dbg("RBN: SENDING call: $saver->[1] qrg: $saver->[0] origin: $saver->[4] $saver->[3]") if isdbg 'rbn';
 418                 if ($dxchan->{ve7cc}) {
 419                         $buf = VE7CC::dx_spot($dxchan, @$saver);
 420                 } else {
 421                         $buf = $dxchan->format_dx_spot(@$saver);
 422                 }
 423                 $buf =~ s/^DX/RB/;
 424                 $dxchan->local_send('N', $buf);
 425         }
 426 }
 427
 428 1;