perl/Msg.pm

   1 #
   2 # This has been taken from the 'Advanced Perl Programming' book by Sriram Srinivasan
   3 #
   4 # I am presuming that the code is distributed on the same basis as perl itself.
   5 #
   6 # I have modified it to suit my devious purposes (Dirk Koopman G1TLH)
   7 #
   8 # $Id$
   9 #
  10
  11 package Msg;
  12
  13 use strict;
  14
  15 use vars qw($VERSION $BRANCH);
  16 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  17 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/ ) || 0;
  18 $main::build += $VERSION;
  19 $main::branch += $BRANCH;
  20
  21 use IO::Select;
  22 use IO::Socket;
  23 use DXDebug;
  24 use Timer;
  25
  26 use vars qw(%rd_callbacks %wt_callbacks %er_callbacks $rd_handles $wt_handles $er_handles $now %conns $noconns $blocking_supported $cnum);
  27
  28 %rd_callbacks = ();
  29 %wt_callbacks = ();
  30 %er_callbacks = ();
  31 $rd_handles   = IO::Select->new();
  32 $wt_handles   = IO::Select->new();
  33 $er_handles   = IO::Select->new();
  34
  35 $now = time;
  36
  37 BEGIN {
  38     # Checks if blocking is supported
  39     eval {
  40         require POSIX; POSIX->import(qw(O_NONBLOCK F_SETFL F_GETFL))
  41     };
  42         if ($@ || $main::is_win) {
  43 #               print STDERR "POSIX Blocking *** NOT *** supported $@\n";
  44                 $blocking_supported = 0;
  45         } else {
  46                 $blocking_supported = 1;
  47 #               print STDERR "POSIX Blocking enabled\n";
  48         }
  49
  50
  51         # import as many of these errno values as are available
  52         eval {
  53                 require Errno; Errno->import(qw(EAGAIN EINPROGRESS EWOULDBLOCK));
  54         };
  55         # http://support.microsoft.com/support/kb/articles/Q150/5/37.asp
  56         # defines EINPROGRESS as 10035.  We provide it here because some
  57         # Win32 users report POSIX::EINPROGRESS is not vendor-supported.
  58         if ($^O eq 'MSWin32') {
  59                 eval '*EINPROGRESS = sub { 10036 };';
  60                 eval '*EWOULDBLOCK = *EAGAIN = sub { 10035 };';
  61                 $blocking_supported = 1;
  62         }
  63 }
  64
  65 my $w = $^W;
  66 $^W = 0;
  67 my $eagain = eval {EAGAIN()};
  68 my $einprogress = eval {EINPROGRESS()};
  69 my $ewouldblock = eval {EWOULDBLOCK()};
  70 $^W = $w;
  71 $cnum = 0;
  72
  73
  74 #
  75 #-----------------------------------------------------------------
  76 # Generalised initializer
  77
  78 sub new
  79 {
  80     my ($pkg, $rproc) = @_;
  81         my $obj = ref($pkg);
  82         my $class = $obj || $pkg;
  83
  84     my $conn = {
  85         rproc => $rproc,
  86                 inqueue => [],
  87                 outqueue => [],
  88                 state => 0,
  89                 lineend => "\r\n",
  90                 csort => 'telnet',
  91                 timeval => 60,
  92                 blocking => 0,
  93                 cnum => (($cnum < 999) ? (++$cnum) : ($cnum = 1)),
  94     };
  95
  96         $noconns++;
  97
  98         dbg("Connection created ($noconns)") if isdbg('connll');
  99         return bless $conn, $class;
 100 }
 101
 102 sub set_error
 103 {
 104         my $conn = shift;
 105         my $callback = shift;
 106         $conn->{eproc} = $callback;
 107         set_event_handler($conn->{sock}, error => $callback) if exists $conn->{sock};
 108 }
 109
 110 sub set_rproc
 111 {
 112         my $conn = shift;
 113         my $callback = shift;
 114         $conn->{rproc} = $callback;
 115 }
 116
 117 sub blocking
 118 {
 119         return unless $blocking_supported;
 120
 121         # Make the handle stop blocking, the Windows way.
 122         if ($^O eq 'MSWin32') {
 123         my $set_it = $_[1];
 124
 125         # 126 is FIONBIO (some docs say 0x7F << 16)
 126         ioctl( $_[0],
 127                0x80000000 | (4 << 16) | (ord('f') << 8) | 126,
 128                $set_it
 129              ) or confess "Can't set the handle non-blocking: $!";
 130         }
 131
 132         my $flags = fcntl ($_[0], F_GETFL, 0);
 133         if ($_[1]) {
 134                 $flags &= ~O_NONBLOCK;
 135         } else {
 136                 $flags |= O_NONBLOCK;
 137         }
 138         fcntl ($_[0], F_SETFL, $flags);
 139 }
 140
 141 # save it
 142 sub conns
 143 {
 144         my $pkg = shift;
 145         my $call = shift;
 146         my $ref;
 147
 148         if (ref $pkg) {
 149                 $call = $pkg->{call} unless $call;
 150                 return undef unless $call;
 151                 dbg("changing $pkg->{call} to $call") if isdbg('connll') && exists $pkg->{call} && $call ne $pkg->{call};
 152                 delete $conns{$pkg->{call}} if exists $pkg->{call} && exists $conns{$pkg->{call}} && $pkg->{call} ne $call;
 153                 $pkg->{call} = $call;
 154                 $ref = $conns{$call} = $pkg;
 155                 dbg("Connection $pkg->{cnum} $call stored") if isdbg('connll');
 156         } else {
 157                 $ref = $conns{$call};
 158         }
 159         return $ref;
 160 }
 161
 162 # this is only called by any dependent processes going away unexpectedly
 163 sub pid_gone
 164 {
 165         my ($pkg, $pid) = @_;
 166
 167         my @pid = grep {$_->{pid} == $pid} values %conns;
 168         foreach my $p (@pid) {
 169                 &{$p->{eproc}}($p, "$pid has gorn") if exists $p->{eproc};
 170                 $p->disconnect;
 171         }
 172 }
 173
 174 #-----------------------------------------------------------------
 175 # Send side routines
 176 sub connect {
 177     my ($pkg, $to_host, $to_port, $rproc) = @_;
 178
 179     # Create a connection end-point object
 180     my $conn = $pkg;
 181         unless (ref $pkg) {
 182                 $conn = $pkg->new($rproc);
 183         }
 184         $conn->{peerhost} = $to_host;
 185         $conn->{peerport} = $to_port;
 186         $conn->{sort} = 'Outgoing';
 187
 188     # Create a new internet socket
 189     my $sock = IO::Socket::INET->new();
 190     return undef unless $sock;
 191
 192         my $proto = getprotobyname('tcp');
 193         $sock->socket(AF_INET, SOCK_STREAM, $proto) or return undef;
 194
 195         blocking($sock, 0);
 196         $conn->{blocking} = 0;
 197
 198         my $ip = gethostbyname($to_host);
 199 #       my $r = $sock->connect($to_port, $ip);
 200         my $r = connect($sock, pack_sockaddr_in($to_port, $ip));
 201         return undef unless $r || _err_will_block($!);
 202
 203         $conn->{sock} = $sock;
 204
 205     if ($conn->{rproc}) {
 206         my $callback = sub {$conn->_rcv};
 207         set_event_handler ($sock, read => $callback);
 208     }
 209     return $conn;
 210 }
 211
 212 sub disconnect {
 213     my $conn = shift;
 214         return if exists $conn->{disconnecting};
 215
 216         $conn->{disconnecting} = 1;
 217     my $sock = delete $conn->{sock};
 218         $conn->{state} = 'E';
 219         $conn->{timeout}->del if $conn->{timeout};
 220
 221         # be careful to delete the correct one
 222         my $call;
 223         if ($call = $conn->{call}) {
 224                 my $ref = $conns{$call};
 225                 delete $conns{$call} if $ref && $ref == $conn;
 226         }
 227         $call ||= 'unallocated';
 228         dbg("Connection $conn->{cnum} $call disconnected") if isdbg('connll');
 229
 230         # get rid of any references
 231         for (keys %$conn) {
 232                 if (ref($conn->{$_})) {
 233                         delete $conn->{$_};
 234                 }
 235         }
 236
 237         if (defined($sock)) {
 238                 set_event_handler ($sock, read => undef, write => undef, error => undef);
 239                 shutdown($sock, 3);
 240                 close($sock);
 241         }
 242
 243         unless ($main::is_win) {
 244                 kill 'TERM', $conn->{pid} if exists $conn->{pid};
 245         }
 246
 247 }
 248
 249 sub send_now {
 250     my ($conn, $msg) = @_;
 251     $conn->enqueue($msg);
 252     $conn->_send (1); # 1 ==> flush
 253 }
 254
 255 sub send_later {
 256     my ($conn, $msg) = @_;
 257     $conn->enqueue($msg);
 258     my $sock = $conn->{sock};
 259     return unless defined($sock);
 260     set_event_handler ($sock, write => sub {$conn->_send(0)});
 261 }
 262
 263 sub enqueue {
 264     my $conn = shift;
 265     push (@{$conn->{outqueue}}, defined $_[0] ? $_[0] : '');
 266 }
 267
 268 sub _send {
 269     my ($conn, $flush) = @_;
 270     my $sock = $conn->{sock};
 271     return unless defined($sock);
 272     my $rq = $conn->{outqueue};
 273
 274     # If $flush is set, set the socket to blocking, and send all
 275     # messages in the queue - return only if there's an error
 276     # If $flush is 0 (deferred mode) make the socket non-blocking, and
 277     # return to the event loop only after every message, or if it
 278     # is likely to block in the middle of a message.
 279
 280         if ($conn->{blocking} != $flush) {
 281                 blocking($sock, $flush);
 282                 $conn->{blocking} = $flush;
 283         }
 284     my $offset = (exists $conn->{send_offset}) ? $conn->{send_offset} : 0;
 285
 286     while (@$rq) {
 287         my $msg            = $rq->[0];
 288                 my $mlth           = length($msg);
 289         my $bytes_to_write = $mlth - $offset;
 290         my $bytes_written  = 0;
 291                 confess("Negative Length! msg: '$msg' lth: $mlth offset: $offset") if $bytes_to_write < 0;
 292         while ($bytes_to_write > 0) {
 293             $bytes_written = syswrite ($sock, $msg,
 294                                        $bytes_to_write, $offset);
 295             if (!defined($bytes_written)) {
 296                 if (_err_will_block($!)) {
 297                     # Should happen only in deferred mode. Record how
 298                     # much we have already sent.
 299                     $conn->{send_offset} = $offset;
 300                     # Event handler should already be set, so we will
 301                     # be called back eventually, and will resume sending
 302                     return 1;
 303                 } else {    # Uh, oh
 304                                         &{$conn->{eproc}}($conn, $!) if exists $conn->{eproc};
 305                                         $conn->disconnect;
 306                     return 0; # fail. Message remains in queue ..
 307                 }
 308             } elsif (isdbg('raw')) {
 309                                 my $call = $conn->{call} || 'none';
 310                                 dbgdump('raw', "$call send $bytes_written: ", $msg);
 311                         }
 312             $offset         += $bytes_written;
 313             $bytes_to_write -= $bytes_written;
 314         }
 315         delete $conn->{send_offset};
 316         $offset = 0;
 317         shift @$rq;
 318         #last unless $flush; # Go back to select and wait
 319                             # for it to fire again.
 320     }
 321     # Call me back if queue has not been drained.
 322     unless (@$rq) {
 323         set_event_handler ($sock, write => undef);
 324                 if (exists $conn->{close_on_empty}) {
 325                         &{$conn->{eproc}}($conn, undef) if exists $conn->{eproc};
 326                         $conn->disconnect;
 327                 }
 328     }
 329     1;  # Success
 330 }
 331
 332 sub dup_sock
 333 {
 334         my $conn = shift;
 335         my $oldsock = $conn->{sock};
 336         my $rc = $rd_callbacks{$oldsock};
 337         my $wc = $wt_callbacks{$oldsock};
 338         my $ec = $er_callbacks{$oldsock};
 339         my $sock = $oldsock->new_from_fd($oldsock, "w+");
 340         if ($sock) {
 341                 set_event_handler($oldsock, read=>undef, write=>undef, error=>undef);
 342                 $conn->{sock} = $sock;
 343                 set_event_handler($sock, read=>$rc, write=>$wc, error=>$ec);
 344                 $oldsock->close;
 345         }
 346 }
 347
 348 sub _err_will_block {
 349         return 0 unless $blocking_supported;
 350         return ($_[0] == $eagain || $_[0] == $ewouldblock || $_[0] == $einprogress);
 351 }
 352
 353 sub close_on_empty
 354 {
 355         my $conn = shift;
 356         $conn->{close_on_empty} = 1;
 357 }
 358
 359 #-----------------------------------------------------------------
 360 # Receive side routines
 361
 362 sub new_server {
 363     @_ == 4 || die "Msg->new_server (myhost, myport, login_proc\n";
 364     my ($pkg, $my_host, $my_port, $login_proc) = @_;
 365         my $self = $pkg->new($login_proc);
 366
 367     $self->{sock} = IO::Socket::INET->new (
 368                                           LocalAddr => "$my_host:$my_port",
 369 #                                          LocalPort => $my_port,
 370                                           Listen    => SOMAXCONN,
 371                                           Proto     => 'tcp',
 372                                           Reuse => 1);
 373     die "Could not create socket: $! \n" unless $self->{sock};
 374     set_event_handler ($self->{sock}, read => sub { $self->new_client }  );
 375         return $self;
 376 }
 377
 378 use Socket qw(IPPROTO_TCP TCP_NODELAY);
 379
 380 sub nolinger
 381 {
 382         my $conn = shift;
 383
 384         if (isdbg('sock')) {
 385                 my ($l, $t) = unpack "ll", getsockopt($conn->{sock}, SOL_SOCKET, SO_LINGER);
 386                 my $k = unpack 'l', getsockopt($conn->{sock}, SOL_SOCKET, SO_KEEPALIVE);
 387                 my $n = unpack "l", getsockopt($conn->{sock}, IPPROTO_TCP, TCP_NODELAY);
 388                 dbg("Linger is: $l $t, keepalive: $k, nagle: $n");
 389         }
 390
 391         setsockopt($conn->{sock}, SOL_SOCKET, SO_LINGER, pack("ll", 0, 0)) or confess "setsockopt linger: $!";
 392         setsockopt($conn->{sock}, SOL_SOCKET, SO_KEEPALIVE, 1) or confess "setsockopt keepalive: $!";
 393         setsockopt($conn->{sock}, IPPROTO_TCP, TCP_NODELAY, 1) or confess "setsockopt: $!";
 394         $conn->{sock}->autoflush(0);
 395
 396         if (isdbg('sock')) {
 397                 my ($l, $t) = unpack "ll", getsockopt($conn->{sock}, SOL_SOCKET, SO_LINGER);
 398                 my $k = unpack 'l', getsockopt($conn->{sock}, SOL_SOCKET, SO_KEEPALIVE);
 399                 my $n = unpack "l", getsockopt($conn->{sock}, IPPROTO_TCP, TCP_NODELAY);
 400                 dbg("Linger is: $l $t, keepalive: $k, nagle: $n");
 401         }
 402 }
 403
 404 sub dequeue
 405 {
 406         my $conn = shift;
 407
 408         if ($conn->{msg} =~ /\n/) {
 409                 my @lines = split /\r?\n/, $conn->{msg};
 410                 if ($conn->{msg} =~ /\n$/) {
 411                         delete $conn->{msg};
 412                 } else {
 413                         $conn->{msg} = pop @lines;
 414                 }
 415                 for (@lines) {
 416                         &{$conn->{rproc}}($conn, defined $_ ? $_ : '');
 417                 }
 418         }
 419 }
 420
 421 sub _rcv {                     # Complement to _send
 422     my $conn = shift; # $rcv_now complement of $flush
 423     # Find out how much has already been received, if at all
 424     my ($msg, $offset, $bytes_to_read, $bytes_read);
 425     my $sock = $conn->{sock};
 426     return unless defined($sock);
 427
 428         my @lines;
 429         if ($conn->{blocking}) {
 430                 blocking($sock, 0);
 431                 $conn->{blocking} = 0;
 432         }
 433         $bytes_read = sysread ($sock, $msg, 1024, 0);
 434         if (defined ($bytes_read)) {
 435                 if ($bytes_read > 0) {
 436                         if (isdbg('raw')) {
 437                                 my $call = $conn->{call} || 'none';
 438                                 dbgdump('raw', "$call read $bytes_read: ", $msg);
 439                         }
 440                         if ($conn->{echo}) {
 441                                 my @ch = split //, $msg;
 442                                 my $out;
 443                                 for (@ch) {
 444                                         if (/[\cH\x7f]/) {
 445                                                 $out .= "\cH \cH";
 446                                                 $conn->{msg} =~ s/.$//;
 447                                         } else {
 448                                                 $out .= $_;
 449                                                 $conn->{msg} .= $_;
 450                                         }
 451                                 }
 452                                 if (defined $out) {
 453                                         set_event_handler ($sock, write => sub{$conn->_send(0)});
 454                                         push @{$conn->{outqueue}}, $out;
 455                                 }
 456                         } else {
 457                                 $conn->{msg} .= $msg;
 458                         }
 459                 }
 460         } else {
 461                 if (_err_will_block($!)) {
 462                         return ;
 463                 } else {
 464                         $bytes_read = 0;
 465                 }
 466     }
 467
 468 FINISH:
 469     if (defined $bytes_read && $bytes_read == 0) {
 470                 &{$conn->{eproc}}($conn, $!) if exists $conn->{eproc};
 471                 $conn->disconnect;
 472     } else {
 473                 unless ($conn->{disable_read}) {
 474                         $conn->dequeue if exists $conn->{msg};
 475                 }
 476         }
 477 }
 478
 479 sub new_client {
 480         my $server_conn = shift;
 481     my $sock = $server_conn->{sock}->accept();
 482         if ($sock) {
 483                 my $conn = $server_conn->new($server_conn->{rproc});
 484                 $conn->{sock} = $sock;
 485                 blocking($sock, 0);
 486                 $conn->nolinger;
 487                 $conn->{blocking} = 0;
 488                 my ($rproc, $eproc) = &{$server_conn->{rproc}} ($conn, $conn->{peerhost} = $sock->peerhost(), $conn->{peerport} = $sock->peerport());
 489                 $conn->{sort} = 'Incoming';
 490                 if ($eproc) {
 491                         $conn->{eproc} = $eproc;
 492                         set_event_handler ($sock, error => $eproc);
 493                 }
 494                 if ($rproc) {
 495                         $conn->{rproc} = $rproc;
 496                         my $callback = sub {$conn->_rcv};
 497                         set_event_handler ($sock, read => $callback);
 498                 } else {  # Login failed
 499                         &{$conn->{eproc}}($conn, undef) if exists $conn->{eproc};
 500                         $conn->disconnect();
 501                 }
 502         } else {
 503                 dbg("Msg: error on accept ($!)") if isdbg('err');
 504         }
 505 }
 506
 507 sub close_server
 508 {
 509         my $conn = shift;
 510         set_event_handler ($conn->{sock}, read => undef, write => undef, error => undef );
 511         $conn->{sock}->close;
 512 }
 513
 514 # close all clients (this is for forking really)
 515 sub close_all_clients
 516 {
 517         foreach my $conn (values %conns) {
 518                 $conn->disconnect;
 519         }
 520 }
 521
 522 sub disable_read
 523 {
 524         my $conn = shift;
 525         set_event_handler ($conn->{sock}, read => undef);
 526         return $_[0] ? $conn->{disable_read} = $_[0] : $_[0];
 527 }
 528
 529 #
 530 #----------------------------------------------------
 531 # Event loop routines used by both client and server
 532
 533 sub set_event_handler {
 534     shift unless ref($_[0]); # shift if first arg is package name
 535     my ($handle, %args) = @_;
 536     my $callback;
 537     if (exists $args{'write'}) {
 538         $callback = $args{'write'};
 539         if ($callback) {
 540             $wt_callbacks{$handle} = $callback;
 541             $wt_handles->add($handle);
 542         } else {
 543             delete $wt_callbacks{$handle};
 544             $wt_handles->remove($handle);
 545         }
 546     }
 547     if (exists $args{'read'}) {
 548         $callback = $args{'read'};
 549         if ($callback) {
 550             $rd_callbacks{$handle} = $callback;
 551             $rd_handles->add($handle);
 552         } else {
 553             delete $rd_callbacks{$handle};
 554             $rd_handles->remove($handle);
 555        }
 556     }
 557     if (exists $args{'error'}) {
 558         $callback = $args{'error'};
 559         if ($callback) {
 560             $er_callbacks{$handle} = $callback;
 561             $er_handles->add($handle);
 562         } else {
 563             delete $er_callbacks{$handle};
 564             $er_handles->remove($handle);
 565        }
 566     }
 567 }
 568
 569 sub event_loop {
 570     my ($pkg, $loop_count, $timeout) = @_; # event_loop(1) to process events once
 571     my ($conn, $r, $w, $e, $rset, $wset, $eset);
 572     while (1) {
 573
 574        # Quit the loop if no handles left to process
 575         last unless ($rd_handles->count() || $wt_handles->count());
 576
 577                 ($rset, $wset, $eset) = IO::Select->select($rd_handles, $wt_handles, $er_handles, $timeout);
 578
 579         foreach $e (@$eset) {
 580             &{$er_callbacks{$e}}($e) if exists $er_callbacks{$e};
 581         }
 582         foreach $r (@$rset) {
 583             &{$rd_callbacks{$r}}($r) if exists $rd_callbacks{$r};
 584         }
 585         foreach $w (@$wset) {
 586             &{$wt_callbacks{$w}}($w) if exists $wt_callbacks{$w};
 587         }
 588
 589                 Timer::handler;
 590
 591         if (defined($loop_count)) {
 592             last unless --$loop_count;
 593         }
 594     }
 595 }
 596
 597 sub sleep
 598 {
 599         my ($pkg, $interval) = @_;
 600         my $now = time;
 601         while (time - $now < $interval) {
 602                 $pkg->event_loop(10, 0.01);
 603         }
 604 }
 605
 606 sub DESTROY
 607 {
 608         my $conn = shift;
 609         my $call = $conn->{call} || 'unallocated';
 610         my $host = $conn->{peerhost} || '';
 611         my $port = $conn->{peerport} || '';
 612         dbg("Connection $conn->{cnum} $call [$host $port] being destroyed") if isdbg('connll');
 613         $noconns--;
 614 }
 615
 616 1;
 617
 618 __END__
 619