perl/ExtMsg.pm

   1 #
   2 # This class is the internal subclass that deals with the external port
   3 # communications for Msg.pm
   4 #
   5 # This is where the cluster handles direct connections coming both in
   6 # and out
   7 #
   8 # $Id$
   9 #
  10 # Copyright (c) 2001 - Dirk Koopman G1TLH
  11 #
  12
  13 package ExtMsg;
  14
  15 use strict;
  16 use Msg;
  17 use DXVars;
  18 use DXUtil;
  19 use DXDebug;
  20 use IO::File;
  21 use IO::Socket;
  22 use IPC::Open3;
  23
  24 use vars qw(@ISA $deftimeout);
  25
  26 @ISA = qw(Msg);
  27 $deftimeout = 60;
  28
  29 sub enqueue
  30 {
  31         my ($conn, $msg) = @_;
  32         unless ($msg =~ /^[ABZ]/) {
  33                 if ($msg =~ /^E[-\w]+\|([01])/ && $conn->{csort} eq 'telnet') {
  34                         $conn->{echo} = $1;
  35                         if ($1) {
  36 #                               $conn->send_raw("\xFF\xFC\x01");
  37                         } else {
  38 #                               $conn->send_raw("\xFF\xFB\x01");
  39                         }
  40                 } else {
  41                         $msg =~ s/^[-\w]+\|//;
  42                         push (@{$conn->{outqueue}}, $msg . $conn->{lineend});
  43                 }
  44         }
  45 }
  46
  47 sub send_raw
  48 {
  49         my ($conn, $msg) = @_;
  50     my $sock = $conn->{sock};
  51     return unless defined($sock);
  52         push (@{$conn->{outqueue}}, $msg);
  53         dbg('connect', $msg) unless $conn->{state} eq 'C';
  54     Msg::set_event_handler ($sock, "write" => sub {$conn->_send(0)});
  55 }
  56
  57 sub dequeue
  58 {
  59         my $conn = shift;
  60         my $msg;
  61
  62         if ($conn->{csort} eq 'ax25' && exists $conn->{msg}) {
  63                 $conn->{msg} =~ s/\cM/\cJ/g;
  64         }
  65         if ($conn->{state} eq 'WC') {
  66                 if (exists $conn->{cmd}) {
  67                         if (@{$conn->{cmd}}) {
  68                                 dbg('connect', $conn->{msg});
  69                                 $conn->_docmd($conn->{msg});
  70                         }
  71                 }
  72                 if ($conn->{state} eq 'WC' && exists $conn->{cmd} && @{$conn->{cmd}} == 0) {
  73                         $conn->to_connected($conn->{call}, 'O', $conn->{csort});
  74                 }
  75         } elsif ($conn->{msg} =~ /\cJ/) {
  76                 my @lines =  $conn->{msg} =~ /([^\cM\cJ]*)\cM?\cJ/g;
  77                 if ($conn->{msg} =~ /\cJ$/) {
  78                         delete $conn->{msg};
  79                 } else {
  80                         $conn->{msg} = pop @lines;
  81                 }
  82                 while (defined ($msg = shift @lines)) {
  83                         dbg('connect', $msg) unless $conn->{state} eq 'C';
  84
  85                         $msg =~ s/\xff\xfa.*\xff\xf0|\xff[\xf0-\xfe].//g; # remove telnet options
  86                         $msg =~ s/[\x00-\x08\x0a-\x19\x1b-\x1f\x80-\x9f]/./g;         # immutable CSI sequence + control characters
  87
  88                         if ($conn->{state} eq 'C') {
  89                                 &{$conn->{rproc}}($conn, "I$conn->{call}|$msg");
  90                         } elsif ($conn->{state} eq 'WL' ) {
  91                                 $msg = uc $msg;
  92                                 if (is_callsign($msg)) {
  93                                         $conn->to_connected($msg, 'A', $conn->{csort});
  94                                 } else {
  95                                         $conn->send_now("Sorry $msg is an invalid callsign");
  96                                         $conn->disconnect;
  97                                 }
  98                         } elsif ($conn->{state} eq 'WC') {
  99                                 if (exists $conn->{cmd} && @{$conn->{cmd}}) {
 100                                         $conn->_docmd($msg);
 101                                         if ($conn->{state} eq 'WC' && exists $conn->{cmd} &&  @{$conn->{cmd}} == 0) {
 102                                                 $conn->to_connected($conn->{call}, 'O', $conn->{csort});
 103                                         }
 104                                 }
 105                         }
 106                 }
 107         }
 108 }
 109
 110 sub to_connected
 111 {
 112         my ($conn, $call, $dir, $sort) = @_;
 113         $conn->{state} = 'C';
 114         $conn->conns($call);
 115         delete $conn->{cmd};
 116         $conn->{timeout}->del if $conn->{timeout};
 117         delete $conn->{timeout};
 118         $conn->_send_file("$main::data/connected");
 119         &{$conn->{rproc}}($conn, "$dir$call|$sort");
 120 }
 121
 122 sub new_client {
 123         my $server_conn = shift;
 124     my $sock = $server_conn->{sock}->accept();
 125         if ($sock) {
 126                 my $conn = $server_conn->new($server_conn->{rproc});
 127                 $conn->{sock} = $sock;
 128
 129                 my ($rproc, $eproc) = &{$server_conn->{rproc}} ($conn, $conn->{peerhost} = $sock->peerhost(), $conn->{peerport} = $sock->peerport());
 130                 if ($eproc) {
 131                         $conn->{eproc} = $eproc;
 132                         Msg::set_event_handler ($sock, "error" => $eproc);
 133                 }
 134                 if ($rproc) {
 135                         $conn->{rproc} = $rproc;
 136                         my $callback = sub {$conn->_rcv};
 137                         Msg::set_event_handler ($sock, "read" => $callback);
 138                         # send login prompt
 139                         $conn->{state} = 'WL';
 140                         #               $conn->send_raw("\xff\xfe\x01\xff\xfc\x01\ff\fd\x22");
 141                         #               $conn->send_raw("\xff\xfa\x22\x01\x01\xff\xf0");
 142                         #               $conn->send_raw("\xFF\xFC\x01");
 143                         $conn->_send_file("$main::data/issue");
 144                         $conn->send_raw("login: ");
 145                         $conn->_dotimeout(60);
 146                 } else {
 147                         &{$conn->{eproc}}() if $conn->{eproc};
 148                         $conn->disconnect();
 149                 }
 150         } else {
 151                 dbg('err', "ExtMsg: error on accept ($!)");
 152         }
 153 }
 154
 155 sub start_connect
 156 {
 157         my $call = shift;
 158         my $fn = shift;
 159         my $conn = ExtMsg->new(\&main::new_channel);
 160         $conn->conns($call);
 161
 162         my $f = new IO::File $fn;
 163         push @{$conn->{cmd}}, <$f>;
 164         $f->close;
 165         $conn->{state} = 'WC';
 166         $conn->_dotimeout($deftimeout);
 167         $conn->_docmd;
 168 }
 169
 170 sub _docmd
 171 {
 172         my $conn = shift;
 173         my $msg = shift;
 174         my $cmd;
 175
 176         while ($cmd = shift @{$conn->{cmd}}) {
 177                 chomp $cmd;
 178                 next if $cmd =~ /^\s*\#/o;
 179                 next if $cmd =~ /^\s*$/o;
 180                 $conn->_doabort($1) if $cmd =~ /^\s*a\w*\s+(.*)/i;
 181                 $conn->_dotimeout($1) if $cmd =~ /^\s*t\w*\s+(\d+)/i;
 182                 $conn->_dolineend($1) if $cmd =~ /^\s*[Ll]\w*\s+\'((?:\\[rn])+)\'/i;
 183                 if ($cmd =~ /^\s*co\w*\s+(\w+)\s+(.*)$/i) {
 184                         unless ($conn->_doconnect($1, $2)) {
 185                                 $conn->disconnect;
 186                                 @{$conn->{cmd}} = [];    # empty any further commands
 187                                 last;
 188                         }
 189                 }
 190                 if ($cmd =~ /^\s*\'.*\'\s+\'.*\'/i) {
 191                         $conn->_dochat($cmd, $msg);
 192                         last;
 193                 }
 194                 if ($cmd =~ /^\s*cl\w+\s+(.*)/i) {
 195                         $conn->_doclient($1);
 196                         last;
 197                 }
 198                 last if $conn->{state} eq 'E';
 199         }
 200 }
 201
 202 sub _doconnect
 203 {
 204         my ($conn, $sort, $line) = @_;
 205         my $r;
 206
 207         $sort = lc $sort;
 208         dbg('connect', "CONNECT sort: $sort command: $line");
 209         if ($sort eq 'telnet') {
 210                 # this is a straight network connect
 211                 my ($host, $port) = split /\s+/, $line;
 212                 $port = 23 if !$port;
 213                 $r = $conn->connect($host, $port);
 214                 if ($r) {
 215                         dbg('connect', "Connected to $host $port");
 216                 } else {
 217                         dbg('connect', "***Connect Failed to $host $port $!");
 218                 }
 219         } elsif ($sort eq 'agw') {
 220                 # turn it into an AGW object
 221                 bless $conn, 'AGWMsg';
 222                 $r = $conn->connect($line);
 223         } elsif ($sort eq 'ax25' || $sort eq 'prog') {
 224                 local $^F = 10000;              # make sure it ain't closed on exec
 225                 my ($a, $b) = IO::Socket->socketpair(AF_UNIX, SOCK_STREAM, PF_UNSPEC);
 226                 if ($a && $b) {
 227                         $r = 1;
 228                         $a->autoflush(1);
 229                         $b->autoflush(1);
 230                         my $pid = fork;
 231                         if (defined $pid) {
 232                                 if ($pid) {
 233                                         close $b;
 234                                         $conn->{sock} = $a;
 235                                         $conn->{csort} = $sort;
 236                                         $conn->{lineend} = "\cM" if $sort eq 'ax25';
 237                                         $conn->{pid} = $pid;
 238                                         if ($conn->{rproc}) {
 239                                                 my $callback = sub {$conn->_rcv};
 240                                                 Msg::set_event_handler ($a, read => $callback);
 241                                         }
 242                                         dbg('connect', "started pid: $conn->{pid} as $line");
 243                                 } else {
 244                                         $^W = 0;
 245                                         dbgclose();
 246                                         STDIN->close;
 247                                         STDOUT->close;
 248                                         STDOUT->close;
 249                                         *STDIN = IO::File->new_from_fd($b, 'r') or die;
 250                                         *STDOUT = IO::File->new_from_fd($b, 'w') or die;
 251                                         *STDERR = IO::File->new_from_fd($b, 'w') or die;
 252                                         close $a;
 253                                         unless ($^O =~ /^MS/) {
 254 #                                               $SIG{HUP} = 'IGNORE';
 255                                                 $SIG{HUP} = $SIG{CHLD} = $SIG{TERM} = $SIG{INT} = 'DEFAULT';
 256                                                 alarm(0);
 257                                         }
 258                                         exec "$line" or dbg('err', "exec '$line' failed $!");
 259                                 }
 260                         } else {
 261                                 dbg('err', "cannot fork");
 262                                 $r = undef;
 263                         }
 264                 } else {
 265                         dbg('err', "no socket pair $!");
 266                 }
 267         } else {
 268                 dbg('err', "invalid type of connection ($sort)");
 269         }
 270         $conn->disconnect unless $r;
 271         return $r;
 272 }
 273
 274 sub _doabort
 275 {
 276         my $conn = shift;
 277         my $string = shift;
 278         dbg('connect', "abort $string");
 279         $conn->{abort} = $string;
 280 }
 281
 282 sub _dotimeout
 283 {
 284         my $conn = shift;
 285         my $val = shift;
 286         dbg('connect', "timeout set to $val");
 287         $conn->{timeout}->del if $conn->{timeout};
 288         $conn->{timeval} = $val;
 289         $conn->{timeout} = Timer->new($val, sub{ &_timedout($conn) });
 290 }
 291
 292 sub _dolineend
 293 {
 294         my $conn = shift;
 295         my $val = shift;
 296         dbg('connect', "lineend set to $val ");
 297         $val =~ s/\\r/\r/g;
 298         $val =~ s/\\n/\n/g;
 299         $conn->{lineend} = $val;
 300 }
 301
 302 sub _dochat
 303 {
 304         my $conn = shift;
 305         my $cmd = shift;
 306         my $line = shift;
 307
 308         if ($line) {
 309                 my ($expect, $send) = $cmd =~ /^\s*\'(.*)\'\s+\'(.*)\'/;
 310                 if ($expect) {
 311                         dbg('connect', "expecting: \"$expect\" received: \"$line\"");
 312                         if ($conn->{abort} && $line =~ /\Q$conn->{abort}/i) {
 313                                 dbg('connect', "aborted on /$conn->{abort}/");
 314                                 $conn->disconnect;
 315                                 delete $conn->{cmd};
 316                                 return;
 317                         }
 318                         if ($line =~ /\Q$expect/i) {
 319                                 dbg('connect', "got: \"$expect\" sending: \"$send\"");
 320                                 $conn->send_later("D$conn->{call}|$send");
 321                                 delete $conn->{msg}; # get rid any input if a match
 322                                 return;
 323                         }
 324                 }
 325         }
 326         $conn->{state} = 'WC';
 327         unshift @{$conn->{cmd}}, $cmd;
 328 }
 329
 330 sub _timedout
 331 {
 332         my $conn = shift;
 333         dbg('connect', "timed out after $conn->{timeval} seconds");
 334         $conn->{timeout}->del;
 335         delete $conn->{timeout};
 336         $conn->disconnect;
 337 }
 338
 339 # handle callsign and connection type firtling
 340 sub _doclient
 341 {
 342         my $conn = shift;
 343         my $line = shift;
 344         my @f = split /\s+/, $line;
 345         my $call = uc $f[0] if $f[0];
 346         $conn->conns($call);
 347         $conn->{csort} = $f[1] if $f[1];
 348         $conn->{state} = 'C';
 349         &{$conn->{rproc}}($conn, "O$call|$conn->{csort}");
 350         delete $conn->{cmd};
 351         $conn->{timeout}->del if $conn->{timeout};
 352 }
 353
 354 sub _send_file
 355 {
 356         my $conn = shift;
 357         my $fn = shift;
 358
 359         if (-e $fn) {
 360                 my $f = new IO::File $fn;
 361                 if ($f) {
 362                         while (<$f>) {
 363                                 chomp;
 364                                 $conn->send_raw($_ . $conn->{lineend});
 365                         }
 366                         $f->close;
 367                 }
 368         }
 369 }