perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35 use DXCIDR;
  36
  37 use strict;
  38 use warnings qw(all);
  39 no warnings qw(uninitialized);
  40
  41
  42
  43 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  44                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  45                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  46                         $investigation_int $pc19_version $myprot_version
  47                         %nodehops $baddx $badspotter $badnode $censorpc
  48                         $allowzero $decode_dk0wcy $send_opernam @checklist
  49                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  50                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  51                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  52                         $pc92filterdef $senderverify $pc11_dwell_time $pc11_extract_route $pc92_ad_enabled $pc92c_ipaddr_enabled
  53                    );
  54
  55 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  56 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  57 $pc92_slug_changes = 60*1;              # slug any changes going outward for this long
  58 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  59 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  60 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  61 $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  62                                 # this is actually the partition between "yesterday" and "today" but old.
  63 $senderverify = 0;                              # 1 - check for forged PC11 or PC61.
  64                                 # 2 - if forged, dump them.
  65 $pc11_dwell_time = 2;                   # number of seconds to wait for a PC61 to come to substitute the PC11
  66 $pc11_extract_route = 1;                # generate missing  user route entry and IP address from passing PC61s
  67
  68
  69 $pc92filterdef = bless ([
  70                           # tag, sort, field, priv, special parser
  71                           ['call', 'c', 0],
  72                           ['by', 'c', 0],
  73                           ['dxcc', 'nc', 1],
  74                           ['itu', 'ni', 2],
  75                           ['zone', 'nz', 3],
  76                          ], 'Filter::Cmd');
  77
  78 our %pc11q;
  79 # this is a place to park an incoming PC11 in the sure and certain hope that
  80 # a PC61 will be along soon. This has the side benefit that it will delay a
  81 # a PC11 for one second - assuming that it is not removed by a PC61 version
  82
  83 # incoming talk commands
  84 sub handle_10
  85 {
  86         my $self = shift;
  87         my $pcno = shift;
  88         my $line = shift;
  89         my $origin = shift;
  90         my $pc = shift;
  91
  92         # this is to catch loops caused by bad software ...
  93         if (eph_dup($line, $pc10_dupe_age)) {
  94                 return;
  95         }
  96
  97
  98         # is it for me or one of mine?
  99         my ($from, $to, $via, $call, $dxchan);
 100         $from = $pc->[1];
 101         if ($pc->[5] gt ' ') {
 102                 $via = $pc->[2];
 103                 $to = $pc->[5];
 104         } else {
 105                 $to = $pc->[2];
 106         }
 107
 108         # if this is a 'nodx' node then ignore it
 109         if ($badnode->in($pc->[6]) || ($via && $badnode->in($via))) {
 110                 dbg($line) if isdbg('nologchan');
 111                 dbg("PCPROT: Bad Node, dropped");
 112                 return;
 113         }
 114
 115
 116         my $nossid = $from;
 117         $nossid =~ s/-\d+$//;
 118         if ($badspotter->in($nossid)) {
 119                 dbg($line) if isdbg('nologchan');
 120                 dbg("PCPROT: Bad Spotter, dropped");
 121                 return;
 122         }
 123
 124         # if we are converting announces to talk is it a dup?
 125         if ($ann_to_talk) {
 126                 if (AnnTalk::is_talk_candidate($from, $pc->[3]) && AnnTalk::dup($from, $to, $pc->[3])) {
 127                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 128                         return;
 129                 }
 130         }
 131
 132         # will we allow it at all?
 133         if ($censorpc) {
 134                 my @bad;
 135                 if (@bad = BadWords::check($pc->[3])) {
 136                         my $bw = join ', ', @bad;
 137                         dbg($line) if isdbg('nologchan');
 138                         dbg("PCPROT: Badwords: '$bw', dropped");
 139                         return;
 140                 }
 141         }
 142
 143         # convert this to a PC93, coming from mycall with origin set and process it as such
 144         my $ref = Route::get($pc->[6]);
 145         my $ip = $ref->ip;
 146         $main::me->normal(pc93($to, $from, $via, $pc->[3], $pc->[6]), $ip);
 147 }
 148
 149 my %pc11_saved;                                 # delayed PC11s
 150 my $pc11_rx;                                    # no of pc11 rxed
 151 my $pc61_rx;                                    # no of pc61 rxed
 152 my $pc11_to_61;                                 # no of 'better' pc61, that replaced stored waiting pc11
 153 my $rpc11_to_61;                                # no of pc11s 'promoted' to pc61 by IP captured in routing table
 154
 155 # DX Spot handling
 156 sub handle_11
 157 {
 158         my $self = shift;
 159         my $pcno = shift;
 160         my $line = shift;
 161         my $origin = shift;
 162         my $pc = shift;
 163         my $recurse = shift || 0;
 164
 165         # route 'foreign' pc26s
 166         if ($pcno == 26) {
 167                 if ($pc->[7] ne $main::mycall) {
 168                         $self->route($pc->[7], $line);
 169                         return;
 170                 }
 171         }
 172
 173         dbg("---") if isdbg("pc11") || isdbg("pc61");
 174         dbg("INPUT $self->{call}: $line via: $origin recurse: $recurse") if isdbg("pc11") || isdbg("pc61");
 175
 176 #       my ($hops) = $pc->[8] =~ /^H(\d+)/;
 177
 178         # is the spotted callsign blank? This should really be trapped earlier but it
 179         # could break other protocol sentences. Also check for lower case characters.
 180         if ($pc->[2] =~ /^\s*$/) {
 181                 dbg($line) if isdbg('nologchan');
 182                 dbg("PCPROT: blank callsign, dropped");
 183                 return;
 184         }
 185         if ($pc->[2] =~ /[a-z]/) {
 186                 dbg($line) if isdbg('nologchan');
 187                 dbg("PCPROT: lowercase characters, dropped");
 188                 return;
 189         }
 190
 191
 192         # if this is a 'nodx' node then ignore it
 193         if ($badnode->in($pc->[7])) {
 194                 dbg($line) if isdbg('nologchan');
 195                 dbg("PCPROT: Bad Node $pc->[7], dropped");
 196                 return;
 197         }
 198
 199         # convert the date to a unix date
 200         my $d = cltounix($pc->[3], $pc->[4]);
 201         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 202         if (!$d || (($pcno == 11 || $pcno == 61) && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 203                 dbg($line) if isdbg('nologchan');
 204                 dbg("PCPROT: Spot ignored, invalid date or out of range ($pc->[3] $pc->[4])\n");
 205                 return;
 206         }
 207
 208         # is it 'baddx'
 209         if ($baddx->in($pc->[2])) {
 210                 dbg("PCPROT: Bad DX spot '$pc->[2]', ignored");
 211                 dbg($line) if isdbg('nologchan');
 212                 return;
 213         }
 214
 215         # is it claiming to be BUST(ed)
 216         $pc->[5] =~ s/^\s+//;                   # take any leading blanks off
 217         $pc->[2] = unpad($pc->[2]);             # take off leading and trailing blanks from spotted callsign
 218         if ($pc->[2] =~ /BUST\w*$/) {
 219                 dbg($line) if isdbg('nologchan');
 220                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 221                 return;
 222         }
 223
 224         my $nossid = $pc->[6];
 225     $nossid =~ s/-\d+$//;
 226
 227         my @spot = Spot::prepare($pc->[1], $pc->[2], $d, $pc->[5], $nossid, $pc->[7], $pc->[8]);
 228
 229         #   $f0 = frequency
 230         #   $f1 = call
 231         #   $f2 = date in unix format
 232         #   $f3 = comment
 233         #   $f4 = spotter
 234         #   $f5 = spotted dxcc country
 235         #   $f6 = spotter dxcc country
 236         #   $f7 = origin
 237         #   $f8 = spotted itu
 238         #   $f9 = spotted cq zone
 239         #   $f10 = spotter itu
 240         #   $f11 = spotter cq zone
 241         #   $f12 = spotted us state
 242         #   $f13 = spotter us state
 243         #   $f14 = ip address
 244
 245
 246         # is this is a 'bad spotter' or an unknown user then ignore it.
 247         if ($badspotter->in($nossid)) {
 248                 dbg($line) if isdbg('nologchan');
 249                 dbg("PCPROT: Bad Spotter $pc->[6], dropped");
 250                 return;
 251         }
 252
 253         # global spot filtering on INPUT
 254         if ($self->{inspotsfilter}) {
 255                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 256                 unless ($filter) {
 257                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 258                         return;
 259                 }
 260         }
 261
 262         # Populate the routing table
 263         $self->populate_routing_table($pc->[7], $pc->[6], $pc->[8]);
 264         my $r = Route::User::get($pc->[6]);
 265         if ($pcno == 61) {
 266                 unless ($pc->[8] && is_ipaddr($pc->[8])) {
 267                         dbg("PCPROT: ROUTE $self->{call} NO IP ADDRESS in '$line'!");
 268                 }
 269         }
 270
 271         # this is where we decide to delay PC11s in the hope that a PC61 will be along soon.
 272         my $key = join '|', @spot[0..2,4,7]; # not including text
 273
 274         unless ($recurse) {
 275
 276                 if ($pcno == 61) {
 277
 278                         if ($pc11_saved{$key}) {
 279                                 # before we promote  because it's a better pc61, check that it's not a dupe (but don't insert it).
 280                                 if (Spot::dup_find(@spot[0..4,7])) {
 281                                         dbg("PCPROT: Duplicate Spot  $self->{call}: $pc->[0] $key ignored\n") if isdbg('chanerr') || isdbg('dupespot') || isdbg('pc11');
 282                                         delete $pc11_saved{$key};
 283                                         return;
 284                                 }
 285
 286                                 ++$pc11_to_61;
 287
 288                                 my $percent = $pc11_rx ? $pc11_to_61 * 100 / $pc11_rx : 0;
 289                                 dbg(sprintf("PROMOTED $self->{call}: BETTER $pc->[0] $key, using pc61, WAITING pc11 DUMPED: $pc61_rx pc11: $pc11_rx better pc61: $pc11_to_61 (%0.1f%%)", $percent)) if isdbg("pc11");
 290
 291                                 delete $pc11_saved{$key}; # because we have promoted it, no longer needed.
 292
 293                                 # so unlike the promotion by route, there is a stored, but uncounted PC11
 294                                 # which have discarded. But we have chosen to use better PC61 that's just come in
 295                                 # so we allow the PC61 to be counted later, but count the now discarded PC11
 296                                 # because it *did* come in.
 297                                 ++$pc11_rx;
 298                         }
 299                 }
 300
 301                 if ($pcno == 11) {
 302
 303                         # if this fires then we have already had one or more PC11s but no PC61 for this spot
 304                         if ($pc11_saved{$key}) {
 305                                 dbg("DUPE $self->{call} $pc->[0] key: $key is saved, ignored") if isdbg("pc11");
 306                                 return;         # because it's a dup
 307                         }
 308
 309                         # before we promote by route, check that it's not been preceded by a previous PC61
 310                         if (Spot::dup_find(@spot[0..4,7])) {
 311                                 my $s = exists $pc11_saved{$key} ? " stored $key removed" : "";
 312                                 dbg("PCPROT: Duplicate Spot $self->{call}: PC11$s, recurse: $recurse, ignored\n") if isdbg('chanerr') || isdbg('dupespot') || isdbg('pc11');
 313                                 delete $pc11_saved{$key};
 314                                 return;
 315                         }
 316
 317
 318                         # If we have an ip address we can promote by route
 319                         if ($r && $r->ip) {
 320                                 $pcno = 61;
 321                                 $pc->[0] = 'PC61';
 322                                 my $hops = $pc->[8];
 323                                 $pc->[8] = $spot[14] = $r->ip;
 324                                 ++$rpc11_to_61;
 325                                 my $percent = $pc11_rx ? $rpc11_to_61 * 100 / $pc11_rx : 0;
 326                                 dbg(sprintf("PROMOTED $self->{call}: ROUTE pc11 $key PROMOTED to pc61 with IP $spot[14] pc61: $pc61_rx pc11: $pc11_rx route->pc61 $rpc11_to_61 (%0.1f%%)", $percent)) if isdbg("pc11");
 327                                 $line = join '^', @$pc, $hops, '~';
 328
 329                                 # update the stats (NOTE, thie record was a PC11, it has now become a PC61
 330                                 # this is NOT the same choosing a better PC61, that is a separate record.
 331                                 ++$pc11_rx;             # 'cos we received as a PC11 it and it won't be a pc11 anymore
 332                                 --$pc61_rx;             # 'cos we'll increment it later as it's now a pc61, no double counting
 333
 334 #                               dbg("CHANGED saved key: $key PC11 line to $line") if isdbg('pc11');
 335                                 delete $pc11_saved{$key};
 336                         }
 337
 338                         # if it is STILL (despite all efforts to change it) a PC11
 339                         # save it and wait - it will be called from pc11_process
 340                         if ($pcno == 11) {
 341                                 $pc11_saved{$key} = [$main::systime, $self, $pcno, $line, $origin, $pc];
 342                                 dbg("WAITING $self->{call}: NEW $pc->[0] spot $key waiting for a better offer") if isdbg("pc11");
 343                                 return;
 344                         }
 345                 }
 346         }
 347
 348         # this goes after the input filtering, but before the add
 349         # so that if it is input filtered, it isn't added to the dup
 350         # list. This allows it to come in from a "legitimate" source
 351         #
 352         ## NOTE: this is where we insert the spot into the DXDupe cache
 353         #
 354         if (Spot::dup(@spot[0..4,7])) {
 355                 dbg("PCPROT: Duplicate Spot  $self->{call}: $pc->[0] $key ignored\n") if isdbg('chanerr') || isdbg('dupespot') || isdbg('pc11');
 356                 return;
 357         }
 358
 359         dbg("PROCESSING $self->{call}: $pc->[0] key: $key") if isdbg('pc11');
 360
 361         if ($pcno == 11) {
 362                 ++$pc11_rx;
 363         } else {
 364                 ++$pc61_rx;
 365         }
 366
 367         # we check IP addresses for PC61 - this will also dedupe PC11 promotions
 368         if (@$pc > 8 && is_ipaddr($pc->[8])) {
 369                 my $ip = $pc->[8];
 370                 $ip =~ s/,/:/g;
 371                 $ip =~ s/^::ffff://;
 372                 if (DXCIDR::find($ip)) {
 373                         dbg($line) if isdbg('nologchan');
 374                         dbg("PCPROT: PC61 $ip in badip list, dropped");
 375                         return;
 376                 }
 377         }
 378
 379         # here we verify the spotter is currently connected to the node it says it is one. AKA email sender verify
 380         # but without the explicit probe to the node. We are relying on "historical" information, but it very likely
 381         # to be current once we have seen the first PC92C from that node.
 382         #
 383         # As for spots generated from non-PC92 nodes, we'll see after about  do_pc9x3h20m...
 384         #
 385         if ($senderverify) {
 386                 my $nroute = Route::Node::get($pc->[7]);
 387                 my $uroute = Route::Node::get($pc->[6]);
 388                 my $local = DXChannel::get($pc->[7]);
 389
 390                 if ($nroute && ($nroute->last_PC92C || ($local && !$local->do_pc9x))) {
 391                         my $s = '';
 392                         my $ip = $pcno == 61 ?  $pc->[8] : '';
 393 #                       $s .= "User $pc->[6] not logged in, " unless $uroute;
 394                         $s .= "User $pc->[6] not on node $pc->[7], " unless $nroute->is_user($pc->[6]);
 395 #                       $s .= "Node $pc->[7] at '$ip' not on Node's IP " . $nroute->ip if $ip && $nroute && $nroute->ip && $nroute->ip ne $ip;
 396                         if ($s) {
 397                                 my $action = $senderverify > 1 ? ", DUMPED" : '';
 398                                 $s =~ s/, $//;
 399                                 dbg("PCPROT: Suspicious Spot $pc->[2] on $pc->[1] by $pc->[6]($ip)\@$pc->[7] $s$action");
 400                                 return unless $senderverify < 2;
 401                         }
 402                 }
 403         }
 404
 405         # we until here to do any censorship to try and reduce the amount of noise that repeated copies
 406         # from other connected nodes cause
 407         if ($censorpc) {
 408                 my @bad;
 409                 if (@bad = BadWords::check($pc->[5])) {
 410                         my $bw = join ', ', @bad;
 411                         dbg($line) if isdbg('nologchan');
 412                         dbg("PCPROT: Badwords: '$bw', dropped");
 413                         return;
 414                 }
 415         }
 416
 417
 418         # add it
 419         Spot::add(@spot);
 420
 421         my $ip = '';
 422         $ip ||= $spot[14] if exists $spot[14];
 423         if (isdbg('progress')) {
 424                 my $sip = $ip ? sprintf "($ip)" : '' unless $ip =~ m|[\(\)\*]|;
 425                 $sip ||= '';
 426                 my $d = ztime($spot[2]);
 427                 my $s = "SPOT: $spot[1] on $spot[0] \@ $d by $spot[4]$sip\@$spot[7]";
 428                 $s .= $spot[3] ? " '$spot[3]'" : q{ ''};
 429                 $s .=  " route: $origin";
 430                 dbg($s);
 431         }
 432
 433         #
 434         # @spot at this point contains:-
 435         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 436         # then  spotted itu, spotted cq, spotters itu, spotters cq
 437         # you should be able to route on any of these
 438         #
 439
 440         # fix up qra locators of known users
 441         my $user = DXUser::get_current($spot[4]);
 442         if ($user) {
 443                 my $qra = $user->qra;
 444                 unless ($qra && is_qra($qra)) {
 445                         my $lat = $user->lat;
 446                         my $long = $user->long;
 447                         if (defined $lat && defined $long) {
 448                                 $user->qra(DXBearing::lltoqra($lat, $long));
 449                                 $user->put;
 450                         }
 451                 }
 452
 453                 # send a remote command to a distant cluster if it is visible and there is no
 454                 # qra locator and we havn't done it for a month.
 455
 456                 unless ($user->qra) {
 457                         my $node;
 458                         my $to = $user->homenode;
 459                         my $last = $user->lastoper || 0;
 460                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 461                                 my $cmd = "forward/opernam $spot[4]";
 462                                 # send the rcmd but we aren't interested in the replies...
 463                                 my $dxchan = $node->dxchan;
 464                                 if ($dxchan && $dxchan->is_clx) {
 465                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 466                                 } else {
 467                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 468                                 }
 469                                 if ($to ne $origin) {
 470                                         $to = $origin;
 471                                         $node = Route::Node::get($to);
 472                                         if ($node) {
 473                                                 $dxchan = $node->dxchan;
 474                                                 if ($dxchan && $dxchan->is_clx) {
 475                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 476                                                 } else {
 477                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 478                                                 }
 479                                         }
 480                                 }
 481                                 $user->lastoper($main::systime);
 482                                 $user->put;
 483                         }
 484                 }
 485         }
 486
 487         # local processing
 488         if (defined &Local::spot) {
 489                 my $r;
 490                 eval {
 491                         $r = Local::spot($self, @spot);
 492                 };
 493                 return if $r;
 494         }
 495
 496         # DON'T be silly and send on PC26s!
 497         return if $pcno == 26;
 498
 499         # send out the filtered spots
 500         send_dx_spot($self, $line, @spot) if @spot;
 501
 502         # cancel any recursion as we have now processed it
 503         my $count =  $pc11_to_61+$rpc11_to_61;
 504         my $percent = ($pc11_rx + $pc61_rx) ? ($pc11_rx * 100) / ($pc11_rx + $pc61_rx) : 0;
 505         my $pc11_61 = $pc11_rx ? ($count * 100) / $pc11_rx : 0;
 506         my $data = "$pc->[0] key: $key";
 507         my $stats = sprintf "pc11: $pc11_rx pc61: $pc61_rx pc11%%: %0.1f%% pc11->pc61: $count(%0.1f%%)", $percent, $pc11_61;
 508         if ($recurse) {
 509                 if ($pc11_saved{$key}) {
 510                         dbg("END $self->{call}: RECURSED $data removed and finished $stats") if isdbg('pc11');
 511                         delete $pc11_saved{$key};
 512                 } else {
 513                         dbg("END $self->{call}: RECURSED NO KEY finished $stats") if isdbg('pc11');
 514                 }
 515                 $recurse = 0;
 516         } else {
 517                 dbg("END $self->{call}: NORMAL $data finished $stats") if isdbg('pc11');
 518         }
 519 }
 520
 521 # used to kick outstanding PC11 if required
 522 sub pc11_process
 523 {
 524         foreach my $key (keys %pc11_saved) {
 525                 my $r = $pc11_saved{$key};
 526                 if ($main::systime > $r->[0] + $pc11_dwell_time) {
 527                         dbg("---") if isdbg("pc11");
 528                         dbg("RECURSE $r->[1]->{call}: PC11 spot $key timed out waiting, resend") if isdbg("pc11");
 529                         my $self = $r->[1];
 530                         delete $pc11_saved{$key};
 531                         $self->handle_11(@$r[2..5], 1);
 532                 }
 533         }
 534 }
 535
 536 # return the pc11 / pc61 / promotions data
 537 sub get_pc11_61_stats
 538 {
 539         my $promotions =  $pc11_to_61+$rpc11_to_61;
 540         my $percent = ($pc11_rx + $pc61_rx) ? ($pc11_rx * 100) / ($pc11_rx + $pc61_rx) : 0;
 541         my $pc11_61p = $pc11_rx ? ($promotions * 100) / $pc11_rx : 0;
 542         return {
 543                         pc11_rx => $pc11_rx+0,
 544                         pc61_rx => $pc61_rx+0,
 545                         pc11_to_61 => $pc11_to_61+0,
 546                         rpc11_to_61 => $rpc11_to_61+0,
 547                         promotions => $promotions+0,
 548                         pc11_percent => $percent+0,
 549                         promotions_percent => $pc11_61p+0,
 550                    };
 551 }
 552
 553 # announces
 554 sub handle_12
 555 {
 556         my $self = shift;
 557         my $pcno = shift;
 558         my $line = shift;
 559         my $origin = shift;
 560         my $pc = shift;
 561
 562         # announce duplicate checking
 563         $pc->[3] =~ s/^\s+//;                   # remove leading blanks
 564
 565         # if this is a 'nodx' node then ignore it
 566         if ($badnode->in($pc->[5])) {
 567                 dbg($line) if isdbg('nologchan');
 568                 dbg("PCPROT: Bad Node, dropped");
 569                 return;
 570         }
 571
 572         # if this is a 'bad spotter' user then ignore it
 573         my $nossid = $pc->[1];
 574         $nossid =~ s/-\d+$//;
 575         if ($badspotter->in($nossid)) {
 576                 dbg($line) if isdbg('nologchan');
 577                 dbg("PCPROT: Bad Spotter, dropped");
 578                 return;
 579         }
 580
 581         # ignore PC12s from origins that use PCxx protocol
 582         my $oref = Route::get($origin);
 583         if ($oref->do_pc9x) {
 584                 dbg("PCPROT: PC12 rxed from PC9x node, ignored") if isdbg('chanerr');
 585                 return;
 586         }
 587
 588         if ($censorpc) {
 589                 my @bad;
 590                 if (@bad = BadWords::check($pc->[3])) {
 591                         my $bw = join ', ', @bad;
 592                         dbg($line) if isdbg('nologchan');
 593                         dbg("PCPROT: Badwords: '$bw', dropped");
 594                         return;
 595                 }
 596         }
 597
 598
 599         my $dxchan;
 600
 601         if ((($dxchan = DXChannel::get($pc->[2])) && $dxchan->is_user) || $pc->[4] =~ /^[\#\w.]+$/){
 602                 $self->send_chat(0, $line, @$pc[1..6]);
 603         } elsif ($pc->[2] eq '*' || $pc->[2] eq $main::mycall) {
 604
 605                 # ignore something that looks like a chat line coming in with sysop
 606                 # flag - this is a kludge...
 607                 if ($pc->[3] =~ /^\#\d+ / && $pc->[4] eq '*') {
 608                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 609                         return;
 610                 }
 611
 612                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 613                 # or one saying 'to <call>' to a talk if we can route to the recipient
 614                 if ($ann_to_talk) {
 615                         my $call = AnnTalk::is_talk_candidate($pc->[1], $pc->[3]);
 616                         if ($call) {
 617                                 my $ref = Route::get($call);
 618                                 if ($ref) {
 619                                         $dxchan = $ref->dxchan;
 620                                         $dxchan->talk($pc->[1], $call, undef, $pc->[3], $pc->[5]) if $dxchan != $self;
 621                                         return;
 622                                 }
 623                         }
 624                 }
 625
 626                 # send it
 627                 $self->send_announce(0, $line, @$pc[1..6]);
 628         } else {
 629                 $self->route($pc->[2], $line);
 630         }
 631
 632         # local processing
 633         if (defined &Local::ann) {
 634                 my $r;
 635                 eval {
 636                         $r = Local::ann($self, $line, @$pc[1..6]);
 637                 };
 638                 return if $r;
 639         }
 640 }
 641
 642 sub handle_15
 643 {
 644         my $self = shift;
 645         my $pcno = shift;
 646         my $line = shift;
 647         my $origin = shift;
 648         my $pc = shift;
 649
 650         if (eph_dup($line, $eph_pc15_restime)) {
 651                 return;
 652         } else {
 653                 unless ($self->{isolate}) {
 654                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 655                 }
 656         }
 657 }
 658
 659 # incoming user
 660 sub handle_16
 661 {
 662         my $self = shift;
 663         my $pcno = shift;
 664         my $line = shift;
 665         my $origin = shift;
 666         my $pc = shift;
 667
 668         # general checks
 669         my $dxchan;
 670         my $ncall = $pc->[1];
 671         my $newline = "PC16^";
 672
 673         # dos I want users from this channel?
 674         unless ($self->user->wantpc16) {
 675                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 676                 return;
 677         }
 678
 679         # is it me?
 680         if ($ncall eq $main::mycall) {
 681                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 682                 return;
 683         }
 684
 685         my $h;
 686         $h = 1 if DXChannel::get($ncall);
 687         if ($h && $self->{call} ne $ncall) {
 688                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 689                 return;
 690         }
 691
 692         if (eph_dup($line)) {
 693                 return;
 694         }
 695
 696         # isolate now means only accept stuff from this call only
 697         if ($self->{isolate} && $ncall ne $self->{call}) {
 698                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 699                 return;
 700         }
 701
 702         my $parent = Route::Node::get($ncall);
 703
 704         if ($parent) {
 705                 $dxchan = $parent->dxchan;
 706                 if ($dxchan && $dxchan ne $self) {
 707                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 708                         return;
 709                 }
 710
 711                 # input filter if required
 712                 return unless $self->in_filter_route($parent);
 713         } else {
 714                 $parent = Route::Node->new($ncall);
 715         }
 716
 717         unless ($h) {
 718                 if ($parent->via_pc92) {
 719                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 720                         return;
 721                 }
 722         }
 723
 724         my $i;
 725         my @rout;
 726         for ($i = 2; $i < $#$pc; $i++) {
 727                 my ($call, $conf, $here) = $pc->[$i] =~ /^(\S+) (\S) (\d)/o;
 728                 next unless $call && $conf && defined $here && is_callsign($call);
 729                 next if $call eq $main::mycall;
 730
 731                 eph_del_regex("^PC17\\^$call\\^$ncall");
 732
 733                 $conf = $conf eq '*';
 734
 735                 # reject this if we think it is a node already
 736                 my $r = Route::Node::get($call);
 737                 my $u = DXUser::get_current($call) unless $r;
 738                 if ($r || ($u && $u->is_node)) {
 739                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 740                         next;
 741                 }
 742
 743                 $r = Route::User::get($call);
 744                 my $flags = Route::here($here)|Route::conf($conf);
 745
 746                 if ($r) {
 747                         my $au = $r->addparent($parent);
 748                         if ($r->flags != $flags) {
 749                                 $r->flags($flags);
 750                                 $au = $r;
 751                         }
 752                         push @rout, $r if $h && $au;
 753                 } else {
 754                         my @ans = $parent->add_user($call, $flags);
 755                         push @rout, @ans if $h && @ans;
 756                 }
 757
 758                 # add this station to the user database, if required
 759                 my $user = DXUser::get_current($ncall);
 760                 $user = DXUser->new($call) unless $user;
 761                 $user->homenode($parent->call) if !$user->homenode;
 762                 $user->node($parent->call);
 763                 $user->lastin($main::systime) unless DXChannel::get($call);
 764                 $user->put;
 765
 766                 # send info to all logged in thingies
 767                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 768                 $self->tell_buddies('loginb', $call, $ncall);
 769         }
 770         if (@rout) {
 771                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 772 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 773         }
 774 }
 775
 776 # remove a user
 777 sub handle_17
 778 {
 779         my $self = shift;
 780         my $pcno = shift;
 781         my $line = shift;
 782         my $origin = shift;
 783         my $pc = shift;
 784
 785         my $dxchan;
 786         my $ncall = $pc->[2];
 787         my $ucall = $pc->[1];
 788
 789         eph_del_regex("^PC16\\^$ncall.*$ucall");
 790
 791         # do I want users from this channel?
 792         unless ($self->user->wantpc16) {
 793                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 794                 return;
 795         }
 796
 797         if ($ncall eq $main::mycall) {
 798                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 799                 return;
 800         }
 801
 802         # isolate now means only accept stuff from this call only
 803         if ($self->{isolate} && $ncall ne $self->{call}) {
 804                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 805                 return;
 806         }
 807
 808         my $uref = Route::User::get($ucall);
 809         unless ($uref) {
 810                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 811                 return;
 812         }
 813         my $parent = Route::Node::get($ncall);
 814         unless ($parent) {
 815                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 816                 return;
 817         }
 818
 819         $dxchan = DXChannel::get($ncall);
 820         if ($dxchan && $dxchan ne $self) {
 821                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 822                 return;
 823         }
 824
 825         unless ($dxchan) {
 826                 if ($parent->via_pc92) {
 827                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 828                         return;
 829                 }
 830         }
 831
 832         if (DXChannel::get($ucall)) {
 833                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 834                 return;
 835         }
 836
 837         # input filter if required and then remove user if present
 838 #               return unless $self->in_filter_route($parent);
 839         $parent->del_user($uref);
 840
 841         # send info to all logged in thingies
 842         my $user = DXUser::get_current($ncall);
 843         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 844         $self->tell_buddies('logoutb', $ucall, $ncall);
 845
 846         if (eph_dup($line)) {
 847                 return;
 848         }
 849
 850         $self->route_pc17($origin, $line, $parent, $uref);
 851 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 852 }
 853
 854 # link request
 855 sub handle_18
 856 {
 857         my $self = shift;
 858         my $pcno = shift;
 859         my $line = shift;
 860         my $origin = shift;
 861         my $pc = shift;
 862
 863         $self->state('init');
 864
 865         my $parent = Route::Node::get($self->{call});
 866
 867         my ($software, $version, $build) = (undef, 0, 0);
 868
 869         # record the type and version offered
 870         if (($software, $version) = $pc->[1] =~ /(DXSpider|CC\s*Cluster)\s+Version: (\d+(?:\.\d+)?)/i) {
 871                 $version += 0;
 872                 $version += 53 if $version < 6;
 873                 $self->{version} = $version;
 874                 $self->user->version($version);
 875                 $parent->version($version);
 876                 my ($build) = $pc->[1] =~ /Build: (\d+(?:\.\d+)?)/;
 877                 $build += 0;
 878                 $build = 0 unless $build > 1;
 879                 $self->{build} = $build;
 880                 $self->user->build($build);
 881                 $parent->build($build);
 882                 dbg("$self->{call} = $software version $version build $build");
 883                 unless ($self->is_spider) {
 884                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 885                         $self->user->sort('S');
 886                         $self->user->put;
 887                         $self->sort('S');
 888                 }
 889 #               $self->{handle_xml}++ if DXXml::available() && $pc->[1] =~ /\bxml/;
 890         } elsif (($software, $version, $build) = $pc->[1] =~ /(AR-Cluster)\s+Version:\s+(\d+\.\d+).?(\d+\.\d+)?/) {
 891                 dbg("$self->{call} = $software version $version build $build");
 892                 $self->{version} = $version;
 893                 $self->user->version($version);
 894                 $parent->version($version);
 895                 $self->{build} = $build;
 896                 $self->user->build($build);
 897                 $parent->build($build);
 898                 unless ($self->is_arcluster) {
 899                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> R");
 900                         $self->user->sort('R');
 901                         $self->user->put;
 902                         $self->sort('R');
 903                 }
 904         } else {
 905                 dbg("$self->{call} = Unknown software ($pc->[1] $pc->[2])");
 906                 $self->version(50.0);
 907                 $self->version($pc->[2] / 100) if $pc->[2] && $pc->[2] =~ /^\d+$/;
 908                 $self->user->version($self->version);
 909         }
 910
 911         if ($pc->[1] =~ /CC\s*Cluster/i || $pc->[1] =~ /\bpc9x/i) {
 912                 if ($self->{isolate}) {
 913                         dbg("$self->{call} pc9x recognised, but node is isolated, using old protocol");
 914                 } elsif (!$self->user->wantpc9x) {
 915                         dbg("$self->{call} pc9x explicitly switched off, using old protocol");
 916                 } else {
 917                         $self->{do_pc9x} = 1;
 918                         dbg("$self->{call} Set do PC9x");
 919                 }
 920         }
 921
 922         # first clear out any nodes on this dxchannel
 923         my @rout = $parent->del_nodes;
 924         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 925         $self->send_local_config();
 926         $self->send(pc20());
 927 }
 928
 929 sub check_add_user
 930 {
 931         my $call = shift;
 932         my $type = shift;
 933         my $homenode = shift;
 934
 935         # add this station to the user database, if required (don't remove SSID from nodes)
 936         my $user = DXUser::get_current($call);
 937         unless ($user) {
 938                 $user = DXUser->new($call);
 939                 $user->sort($type || 'U');
 940                 if ($user->is_node) {
 941                         $user->priv(1);         # I have relented and defaulted nodes
 942                         $user->lockout(1) if $user->is_node;
 943                 } else {
 944                         $user->homenode($homenode) if $homenode;
 945                         $user->node($homenode);
 946                         $user->priv(0);
 947                 }
 948                 $user->lastin($main::systime); # this makes it last longer than just this invocation
 949                 $user->put;                             # just to make sure it gets written away!!!
 950                 dbg("DXProt: PC92 new user record for $call created");
 951         }
 952
 953         # this is to fix a problem I introduced some build ago by using this function for users
 954         # whereas it was only being used for nodes.
 955         if ($user->is_user && $user->lockout && ($user->priv // 0) == 1) {
 956                 $user->priv(0);
 957                 $user->lockout(0);
 958                 dbg("DXProt: PC92 user record for $call depriv'd and unlocked");
 959                 $user->put;
 960         }
 961         return $user;
 962 }
 963
 964 # incoming cluster list
 965 sub handle_19
 966 {
 967         my $self = shift;
 968         my $pcno = shift;
 969         my $line = shift;
 970         my $origin = shift;
 971         my $pc = shift;
 972
 973         my $i;
 974         my $newline = "PC19^";
 975
 976         # new routing list
 977         my (@rout, @pc92out);
 978
 979         # first get the INTERFACE node
 980         my $parent = Route::Node::get($self->{call});
 981         unless ($parent) {
 982                 dbg("PCPROT: my parent $self->{call} has disappeared");
 983                 $self->disconnect;
 984                 return;
 985         }
 986
 987         my $h;
 988
 989         # parse the PC19
 990         #
 991         # We are making a major change from now on. We are only going to accept
 992         # PC19s from directly connected nodes.  This means that we are probably
 993         # going to throw away most of the data that we are being sent.
 994         #
 995         # The justification for this is that most of it is wrong or out of date
 996         # anyway.
 997         #
 998         # From now on we are only going to believe PC92 data and locally connected
 999         # non-pc92 nodes.
1000         #
1001         for ($i = 1; $i < $#$pc-1; $i += 4) {
1002                 my $here = $pc->[$i];
1003                 my $call = uc $pc->[$i+1];
1004                 my $conf = $pc->[$i+2];
1005                 my $ver = $pc->[$i+3];
1006                 next unless defined $here && defined $conf && is_callsign($call);
1007
1008                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
1009
1010                 # check for sane parameters
1011                 #                               $ver = 5000 if $ver eq '0000';
1012                 next unless $ver && $ver =~ /^\d+$/;
1013                 next if $ver < 5000;    # only works with version 5 software
1014                 next if length $call < 3; # min 3 letter callsigns
1015                 next if $call eq $main::mycall || $call eq $main::myalias;
1016
1017                 # check that this PC19 isn't trying to alter the wrong dxchan
1018                 $h = 0;
1019                 my $dxchan = DXChannel::get($call);
1020                 if ($dxchan) {
1021                         if ($dxchan == $self) {
1022                                 $h = 1;
1023                         } else {
1024                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
1025                                 next;
1026                         }
1027                 }
1028
1029                 # isolate now means only accept stuff from this call only
1030                 if ($self->{isolate} && $call ne $self->{call}) {
1031                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
1032                         next;
1033                 }
1034
1035                 if ($call eq $main::myalias) {
1036                         LogDbg('err', "ROUTE: $call eq \$myalias from $self->{call}, ignored!!!");
1037                         dbgprintring(3) if isdbg('nologchan');
1038                         next;
1039                 }
1040
1041                 my $user = check_add_user($call, 'A');
1042
1043 #               if (eph_dup($genline)) {
1044 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
1045 #                       next;
1046 #               }
1047
1048
1049                 unless ($h) {
1050                         if ($parent->via_pc92) {
1051                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
1052                                 next;
1053                         }
1054                 }
1055
1056                 my $r = Route::Node::get($call);
1057                 my $flags = Route::here($here)|Route::conf($conf);
1058
1059                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
1060                 if ($r) {
1061                         my $ar;
1062                         if ($call ne $parent->call) {
1063                                 if ($self->in_filter_route($r)) {
1064                                         $ar = $parent->add($call, $ver, $flags);
1065 #                                       push @rout, $ar if $ar;
1066                                 } else {
1067                                         next;
1068                                 }
1069                         }
1070                         if ($r->version ne $ver || $r->flags != $flags) {
1071                                 $r->version($ver);
1072                                 $r->flags($flags);
1073                         }
1074                         push @rout, $r;
1075                 } else {
1076                         if ($call eq $self->{call} || $user->wantroutepc19) {
1077                                 my $new = Route->new($call); # throw away
1078                                 if ($self->in_filter_route($new)) {
1079                                         my $ar = $parent->add($call, $ver, $flags);
1080                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
1081                                         push @rout, $ar if $ar;
1082                                         push @pc92out, $r if $h;
1083                                 } else {
1084                                         next;
1085                                 }
1086                         }
1087                 }
1088
1089                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
1090                 my $mref = DXMsg::get_busy($call);
1091                 $mref->stop_msg($call) if $mref;
1092
1093                 $user->lastin($main::systime) unless DXChannel::get($call);
1094                 $user->put;
1095         }
1096
1097         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
1098         # but remember there will only be one (pair) these because any extras will be
1099         # thrown away.
1100         if (@rout) {
1101 #               $self->route_pc21($self->{call}, $line, @rout);
1102                 $self->route_pc19($self->{call}, $line, @rout);
1103         }
1104         if (@pc92out && !$pc92_slug_changes) {
1105                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
1106         }
1107 }
1108
1109 # send local configuration
1110 sub handle_20
1111 {
1112         my $self = shift;
1113         my $pcno = shift;
1114         my $line = shift;
1115         my $origin = shift;
1116         my $pc = shift;
1117
1118         if ($self->{do_pc9x} && $self->{state} ne 'init92' && $self->{state} ne 'normal') {
1119                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
1120                 $self->{do_pc9x} = 0;
1121         }
1122         $self->send_local_config;
1123         $self->send(pc22());
1124         $self->state('normal');
1125         $self->{lastping} = 0;
1126         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
1127 }
1128
1129 # delete a cluster from the list
1130 #
1131 # This should never occur for directly connected nodes.
1132 #
1133 sub handle_21
1134 {
1135         my $self = shift;
1136         my $pcno = shift;
1137         my $line = shift;
1138         my $origin = shift;
1139         my $pc = shift;
1140
1141         my $call = uc $pc->[1];
1142
1143         eph_del_regex("^PC1[679].*$call");
1144
1145         # if I get a PC21 from the same callsign as self then ignore it
1146         if ($call eq $self->{call}) {
1147                 dbg("PCPROT: self referencing PC21 from $self->{call}");
1148                 return;
1149         }
1150
1151         # for the above reason and also because of the check for PC21s coming
1152         # in for self->call from outside being ignored further down
1153         # we don't need any isolation code here, because we will never
1154         # act on a PC21 with self->call in it.
1155
1156         my $parent = Route::Node::get($self->{call});
1157         unless ($parent) {
1158                 dbg("PCPROT: my parent $self->{call} has disappeared");
1159                 $self->disconnect;
1160                 return;
1161         }
1162
1163         my @rout;
1164
1165         if ($call ne $main::mycall && $call ne $main::myalias) { # don't allow malicious buggers to disconnect me!
1166                 my $node = Route::Node::get($call);
1167                 if ($node) {
1168
1169                         if ($node->via_pc92) {
1170                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
1171                                 return;
1172                         }
1173
1174                         my $dxchan = DXChannel::get($call);
1175                         if ($dxchan && $dxchan != $self) {
1176                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chan');
1177                                 return;
1178                         }
1179
1180                         # input filter it
1181                         return unless $self->in_filter_route($node);
1182
1183                         # routing objects, force a PC21 if it is local
1184                         push @rout, $node->del($parent);
1185                         push @rout, $call if $dxchan && @rout == 0;
1186                 }
1187         } else {
1188                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chan');
1189                 return;
1190         }
1191
1192         if (eph_dup($line)) {
1193                 return;
1194         }
1195
1196         if (@rout) {
1197                 $self->route_pc21($origin, $line, @rout);
1198 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
1199         }
1200 }
1201
1202
1203 sub handle_22
1204 {
1205         my $self = shift;
1206         my $pcno = shift;
1207         my $line = shift;
1208         my $origin = shift;
1209         my $pc = shift;
1210
1211         if ($self->{do_pc9x}) {
1212                 if ($self->{state} ne 'init92' && $self->{state} ne 'normal') {
1213                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
1214                         $self->{do_pc9x} = 0;
1215                 }
1216         }
1217         $self->{lastping} = 0;
1218         $self->state('normal');
1219         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
1220 }
1221
1222 # WWV info
1223 sub handle_23
1224 {
1225         my $self = shift;
1226         my $pcno = shift;
1227         my $line = shift;
1228         my $origin = shift;
1229         my $pc = shift;
1230
1231         # route foreign' pc27s
1232         if ($pcno == 27) {
1233                 if ($pc->[8] ne $main::mycall) {
1234                         $self->route($pc->[8], $line);
1235                         return;
1236                 }
1237         }
1238
1239
1240         # do some de-duping
1241         my $d = cltounix($pc->[1], sprintf("%02d18Z", $pc->[2]));
1242         my $sfi = unpad($pc->[3]);
1243         my $k = unpad($pc->[4]);
1244         my $i = unpad($pc->[5]);
1245         my ($r) = $pc->[6] =~ /R=(\d+)/;
1246         $r = 0 unless $r;
1247         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1248                 dbg("PCPROT: WWV Date ($pc->[1] $pc->[2]) out of range") if isdbg('chanerr');
1249                 return;
1250         }
1251
1252         # global wwv filtering on INPUT
1253         my @dxcc = ((Prefix::cty_data($pc->[7]))[0..2], (Prefix::cty_data($pc->[8]))[0..2]);
1254         if ($self->{inwwvfilter}) {
1255                 my ($filter, $hops) = $self->{inwwvfilter}->it(@$pc[7,8], $origin, @dxcc);
1256                 unless ($filter) {
1257                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
1258                         return;
1259                 }
1260         }
1261         $pc->[7] =~ s/-\d+$//o;         # remove spotter's ssid
1262         if (Geomag::dup($d,$sfi,$k,$i,$pc->[6],$pc->[7])) {
1263                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
1264                 return;
1265         }
1266
1267         # note this only takes the first one it gets
1268         Geomag::update($d, $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
1269         dbg("WWV: <$pc->[2]>, sfi=$sfi k=$k info=$i '$pc->[6]' $pc->[7]\@$pc->[8] $r route: $origin") if isdbg('progress');
1270
1271         if (defined &Local::wwv) {
1272                 my $rep;
1273                 eval {
1274                         $rep = Local::wwv($self, $pc->[1], $pc->[2], $sfi, $k, $i, @$pc[6..8], $r);
1275                 };
1276                 return if $rep;
1277         }
1278
1279         # DON'T be silly and send on PC27s!
1280         return if $pcno == 27;
1281
1282         # broadcast to the eager world
1283         send_wwv_spot($self, $line, $d, $pc->[2], $sfi, $k, $i, @$pc[6..8]);
1284 }
1285
1286 # set here status
1287 sub handle_24
1288 {
1289         my $self = shift;
1290         my $pcno = shift;
1291         my $line = shift;
1292         my $origin = shift;
1293         my $pc = shift;
1294
1295         my $call = uc $pc->[1];
1296         my ($nref, $uref);
1297         $nref = Route::Node::get($call);
1298         $uref = Route::User::get($call);
1299         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
1300
1301         if (eph_dup($line)) {
1302                 return;
1303         }
1304
1305         $nref->here($pc->[2]) if $nref;
1306         $uref->here($pc->[2]) if $uref;
1307         my $ref = $nref || $uref;
1308         return unless $self->in_filter_route($ref);
1309
1310         $self->route_pc24($origin, $line, $ref, $pc->[3]);
1311 }
1312
1313 # merge request
1314 sub handle_25
1315 {
1316         my $self = shift;
1317         my $pcno = shift;
1318         my $line = shift;
1319         my $origin = shift;
1320         my $pc = shift;
1321
1322         if ($pc->[1] ne $main::mycall) {
1323                 $self->route($pc->[1], $line);
1324                 return;
1325         }
1326         if ($pc->[2] eq $main::mycall) {
1327                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chan');
1328                 return;
1329         }
1330
1331         Log('DXProt', "Merge request for $pc->[3] spots and $pc->[4] WWV from $pc->[2]");
1332
1333         # spots
1334         if ($pc->[3] > 0) {
1335                 my @in = reverse Spot::search(1, undef, undef, 0, $pc->[3]);
1336                 my $in;
1337                 foreach $in (@in) {
1338                         $self->send(pc26(@{$in}[0..4], $pc->[2]));
1339                 }
1340         }
1341
1342         # wwv
1343         if ($pc->[4] > 0) {
1344                 my @in = reverse Geomag::search(0, $pc->[4], time, 1);
1345                 my $in;
1346                 foreach $in (@in) {
1347                         $self->send(pc27(@{$in}[0..5], $pc->[2]));
1348                 }
1349         }
1350 }
1351
1352 sub handle_26 {goto &handle_11}
1353 sub handle_27 {goto &handle_23}
1354
1355 # mail/file handling
1356 sub handle_28
1357 {
1358         my $self = shift;
1359         my $pcno = shift;
1360         my $line = shift;
1361         my $origin = shift;
1362         my $pc = shift;
1363
1364         if ($pc->[1] eq $main::mycall) {
1365                 no strict 'refs';
1366                 my $sub = "DXMsg::handle_$pcno";
1367                 &$sub($self, @$pc);
1368         } else {
1369                 $self->route($pc->[1], $line) unless $self->is_clx;
1370         }
1371 }
1372
1373 sub handle_29 {goto &handle_28}
1374 sub handle_30 {goto &handle_28}
1375 sub handle_31 {goto &handle_28}
1376 sub handle_32 {goto &handle_28}
1377 sub handle_33 {goto &handle_28}
1378
1379 sub handle_34
1380 {
1381         my $self = shift;
1382         my $pcno = shift;
1383         my $line = shift;
1384         my $origin = shift;
1385         my $pc = shift;
1386
1387         if (eph_dup($line, $eph_pc34_restime)) {
1388                 return;
1389         } else {
1390                 $self->process_rcmd($pc->[1], $pc->[2], $pc->[2], $pc->[3]);
1391         }
1392 }
1393
1394 # remote command replies
1395 sub handle_35
1396 {
1397         my $self = shift;
1398         my $pcno = shift;
1399         my $line = shift;
1400         my $origin = shift;
1401         my $pc = shift;
1402
1403         eph_del_regex("^PC35\\^$pc->[2]\\^$pc->[1]\\^");
1404         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[1], $pc->[3]);
1405 }
1406
1407 sub handle_36 {goto &handle_34}
1408
1409 # database stuff
1410 sub handle_37
1411 {
1412         my $self = shift;
1413         my $pcno = shift;
1414         my $line = shift;
1415         my $origin = shift;
1416         my $pc = shift;
1417
1418         if ($pc->[1] eq $main::mycall) {
1419                 no strict 'refs';
1420                 my $sub = "DXDb::handle_$pcno";
1421                 &$sub($self, @$pc);
1422         } else {
1423                 $self->route($pc->[1], $line) unless $self->is_clx;
1424         }
1425 }
1426
1427 # node connected list from neighbour
1428 sub handle_38
1429 {
1430         my $self = shift;
1431         my $pcno = shift;
1432         my $line = shift;
1433         my $origin = shift;
1434         my $pc = shift;
1435 }
1436
1437 # incoming disconnect
1438 sub handle_39
1439 {
1440         my $self = shift;
1441         my $pcno = shift;
1442         my $line = shift;
1443         my $origin = shift;
1444         my $pc = shift;
1445
1446         if ($pc->[1] eq $self->{call}) {
1447                 $self->disconnect(1);
1448         } else {
1449                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1450         }
1451 }
1452
1453 sub handle_40 {goto &handle_28}
1454
1455 # user info
1456 sub handle_41
1457 {
1458         my $self = shift;
1459         my $pcno = shift;
1460         my $line = shift;
1461         my $origin = shift;
1462         my $pc = shift;
1463
1464         my $call = $pc->[1];
1465         my $sort = $pc->[2];
1466         my $val = $pc->[3];
1467
1468         my $l = "PC41^$call^$sort";
1469         if (eph_dup($l, $eph_info_restime)) {
1470                 return;
1471         }
1472
1473         # input filter if required
1474         #                       my $ref = Route::get($call) || Route->new($call);
1475         #                       return unless $self->in_filter_route($ref);
1476
1477         if ($val eq $sort || $val =~ /^\s*$/) {
1478                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1479                 return;
1480         }
1481
1482         if ($call eq $main::mycall || $call eq $main::myalias) {
1483                 dbg "DXPROT: PC41 trying to update $call from outside via $origin, ignored";
1484                 return;
1485         }
1486         my $chan = DXChannel::get($call);
1487         if ($chan) {
1488                 dbg "DXPROT: PC41 trying to update online $call from outside via $origin, ignored";
1489                 return;
1490         }
1491
1492         # add this station to the user database, if required
1493         my $user = DXUser::get_current($call);
1494         $user = DXUser->new($call) unless $user;
1495
1496         if ($sort == 1) {
1497                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1498                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1499                         return;
1500                 }
1501                 $user->name($val);
1502         } elsif ($sort == 2) {
1503                 $user->qth($val);
1504         } elsif ($sort == 3) {
1505                 if (is_latlong($val)) {
1506                         my ($lat, $long) = DXBearing::stoll($val);
1507                         $user->lat($lat) if $lat;
1508                         $user->long($long) if $long;
1509                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1510                 } else {
1511                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1512                         return;
1513                 }
1514         } elsif ($sort == 4) {
1515                 $user->homenode($val);
1516         } elsif ($sort == 5) {
1517                 if (is_qra(uc $val)) {
1518                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1519                         $user->lat($lat) if $lat && !$user->lat;
1520                         $user->long($long) if $long && !$user->long;
1521                         $user->qra(uc $val);
1522                 } else {
1523                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1524                         return;
1525                 }
1526         }
1527         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1528         $user->put;
1529
1530         unless ($self->{isolate}) {
1531                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1532         }
1533
1534         #  perhaps this IS what we want after all
1535         #                       $self->route_pc41($ref, $call, $sort, $val, $pc->[4]);
1536 }
1537
1538 sub handle_42 {goto &handle_28}
1539
1540
1541 # database
1542 sub handle_44 {goto &handle_37}
1543 sub handle_45 {goto &handle_37}
1544 sub handle_46 {goto &handle_37}
1545 sub handle_47 {goto &handle_37}
1546 sub handle_48 {goto &handle_37}
1547
1548 # message and database
1549 sub handle_49
1550 {
1551         my $self = shift;
1552         my $pcno = shift;
1553         my $line = shift;
1554         my $origin = shift;
1555         my $pc = shift;
1556
1557         if (eph_dup($line)) {
1558                 return;
1559         }
1560
1561         if ($pc->[1] eq $main::mycall) {
1562                 DXMsg::handle_49($self, @$pc);
1563         } else {
1564                 $self->route($pc->[1], $line) unless $self->is_clx;
1565         }
1566 }
1567
1568 # keep alive/user list
1569 sub handle_50
1570 {
1571         my $self = shift;
1572         my $pcno = shift;
1573         my $line = shift;
1574         my $origin = shift;
1575         my $pc = shift;
1576
1577         return if (eph_dup($line));
1578
1579         my $call = $pc->[1];
1580
1581         my $node = Route::Node::get($call);
1582         if ($node) {
1583                 return unless $node->call eq $self->{call};
1584                 $node->usercount($pc->[2]) unless $node->users;
1585                 $node->reset_obs;
1586                 $node->PC92C_dxchan($self->call, $pc->[-1]);
1587
1588                 # input filter if required
1589 #               return unless $self->in_filter_route($node);
1590
1591                 unless ($self->{isolate}) {
1592                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1593                 }
1594 #               $self->route_pc50($origin, $line, $node, $pc->[2], $pc->[3]) unless eph_dup($line);
1595         }
1596 }
1597
1598 # incoming ping requests/answers
1599 sub handle_51
1600 {
1601         my $self = shift;
1602         my $pcno = shift;
1603         my $line = shift;
1604         my $origin = shift;
1605         my $pc = shift;
1606
1607         my $to = $pc->[1];
1608         my $from = $pc->[2];
1609         my $flag = $pc->[3];
1610
1611         if ($to eq $main::myalias) {
1612                 dbg("DXPROT: Ping addressed to \$myalias ($main::myalias), ignored") if isdbg('chan');
1613                 return;
1614         }
1615
1616         # is it for us?
1617         if ($to eq $main::mycall) {
1618                 if ($flag == 1) {
1619                         $self->send(pc51($from, $to, '0'));
1620                 } else {
1621                         DXXml::Ping::handle_ping_reply($self, $from);
1622                 }
1623         } else {
1624                 if (eph_dup($line)) {
1625                         return;
1626                 }
1627                 # route down an appropriate thingy
1628                 $self->route($to, $line);
1629         }
1630 }
1631
1632 sub handle_61 { goto &handle_11; }
1633
1634 # dunno but route it
1635 sub handle_75
1636 {
1637         my $self = shift;
1638         my $pcno = shift;
1639         my $line = shift;
1640         my $origin = shift;
1641         my $pc = shift;
1642
1643         my $call = $pc->[1];
1644         if ($call ne $main::mycall) {
1645                 $self->route($call, $line);
1646         }
1647 }
1648
1649 # WCY broadcasts
1650 sub handle_73
1651 {
1652         my $self = shift;
1653         my $pcno = shift;
1654         my $line = shift;
1655         my $origin = shift;
1656         my $pc = shift;
1657
1658         my $call = $pc->[1];
1659
1660         # do some de-duping
1661         my $d = cltounix($call, sprintf("%02d18Z", $pc->[2]));
1662         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $pc->[2] < 0 || $pc->[2] > 23) {
1663                 dbg("PCPROT: WCY Date ($call $pc->[2]) out of range") if isdbg('chanerr');
1664                 return;
1665         }
1666         $pc = [ map { unpad($_) } @$pc ];
1667         if (WCY::dup($d)) {
1668                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1669                 return;
1670         }
1671
1672         my $wcy = WCY::update($d, @$pc[2..12]);
1673         dbg("WCY: <$pc->[2]> K=$pc->[5] expK=$pc->[6] A=$pc->[4] R=$pc->[7] SFI=$pc->[3] SA=$pc->[8] GMF=$pc->[9] Au=$pc->[10] $pc->[11]\@$pc->[12] route: $origin") if isdbg('progress');
1674
1675         if (defined &Local::wcy) {
1676                 my $rep;
1677                 eval {
1678                         $rep = Local::wcy($self, @$pc[1..12]);
1679                 };
1680                 return if $rep;
1681         }
1682
1683         # broadcast to the eager world
1684         send_wcy_spot($self, $line, $d, @$pc[2..12]);
1685 }
1686
1687 # remote commands (incoming)
1688 sub handle_84
1689 {
1690         my $self = shift;
1691         my $pcno = shift;
1692         my $line = shift;
1693         my $origin = shift;
1694         my $pc = shift;
1695
1696         $self->process_rcmd($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1697 }
1698
1699 # remote command replies
1700 sub handle_85
1701 {
1702         my $self = shift;
1703         my $pcno = shift;
1704         my $line = shift;
1705         my $origin = shift;
1706         my $pc = shift;
1707
1708         $self->process_rcmd_reply($pc->[1], $pc->[2], $pc->[3], $pc->[4]);
1709 }
1710
1711 # decode a pc92 call: flag call : version : build
1712 sub _decode_pc92_call
1713 {
1714         my $icall = shift;
1715         my @part = split /:/, $icall;
1716         my ($flag, $call) = unpack "A A*", $part[0];
1717         unless (defined $flag && $flag ge '0' && $flag le '7') {
1718                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1719                 return ();
1720         }
1721         unless ($call && is_callsign($call)) {
1722                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1723                 return ();
1724         }
1725         my $is_node = $flag & 4;
1726         my $is_extnode = $flag & 2;
1727         my $here = $flag & 1;
1728         my $version = $part[1] || 0;
1729         my $build = $part[2] || 0;
1730         my $ip = $part[3] || '';
1731
1732         # remember that, at this stage, IPV6 addresses have : replaced by ,
1733         if (length $version > 4 && $version =~ /[,\.][\da-f]{1,4}/i) {
1734                 $ip = $version;
1735                 $version = 0;
1736         }
1737         $version =~ s/\D//g;
1738         $version = 0 unless $version && $version =~ /^[0-9]+$/;
1739         $build =~ s/^0\.//;
1740         $build =~ s/\D//g;
1741         $build = 0 unless $build &&  $build =~ /^[0-9]+$/;
1742         if ($ip) {
1743         $ip =~ s/,/:/g;
1744         $ip =~ s/^::ffff://i;
1745                 $ip = '' unless is_ipaddr($ip);
1746     }
1747         dbg("'$icall' = '" . join("', '", $call, $is_node, $is_extnode, $here, $version, $build, $ip) . "'") if isdbg('pc92');
1748         return ($call, $is_node, $is_extnode, $here, $version+0, $build+0, $ip);
1749 }
1750
1751 # decode a pc92 call: flag call : version : build
1752 sub _encode_pc92_call
1753 {
1754         my $ref = shift;
1755
1756         # plain call or value
1757         return $ref unless ref $ref;
1758
1759         my $ext = shift || 0;
1760         my $flag = 0;
1761         my $call = $ref->call;
1762         my $extra = '';
1763         $flag |= $ref->here ? 1 : 0;
1764         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1765                 $flag |= 4;
1766                 my $dxchan = DXChannel::get($call);
1767                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1768                 if (($ext & 1) && $ref->version) {
1769                         my $version = $ref->version || 1.0;
1770                         $version =  $version * 100 + 5300 if $version < 50;
1771                         $extra .= ":" . $version;
1772                 }
1773         }
1774         if (($ext & 2) && $ref->ip) {
1775                 my $ip = $ref->ip;
1776                 $ip =~ s/:/,/g;
1777                 $extra .= ':' . $ip;
1778         }
1779
1780         return "$flag$call$extra";
1781 }
1782
1783 my %things_add;
1784 my %things_del;
1785
1786 sub _add_thingy
1787 {
1788         my $parent = shift;
1789         my $s = shift;
1790         my $dxchan = shift;
1791         my $hops = shift;
1792
1793         my ($call, $is_node, $is_extnode, $here, $version, $build, $ip) = @$s;
1794         my @rout;
1795
1796         # remove spurious IPV6 prefix on IPV4 addresses
1797         $build ||= 0;
1798         $version ||= 0;
1799
1800         if ($call) {
1801                 my $ncall = $parent->call;
1802                 if ($ncall ne $call) {
1803                         my $user;
1804                         my $r;
1805
1806                         # normalise call, delete any unnormalised calls in the users file.
1807                         # then ignore this thingy
1808                         my $normcall = normalise_call($call);
1809                         if ($normcall ne $call) {
1810                                 next if DXChannel::get($call);
1811                                 $user = DXUser::get($call);
1812                                 dbg("DXProt::_add_thingy call $call normalised to $normcall, deleting spurious user $call");
1813                                 $user->del if $user;
1814                             $call = $normcall; # this is safe because a route add will ignore duplicates
1815                         }
1816
1817                         if ($call eq $main::myalias && $is_node) {
1818                                 LogDbg('err', "ROUTE: $call eq \$myalias from $ncall - downgraded to user!!!");
1819                                 dbgprintring(3) if isdbg('nologchan');
1820                                 $is_node = 0;
1821                         }
1822                         if ($is_node) {
1823                                 dbg("ROUTE: added node $call to $ncall") if isdbg('routelow');
1824                                 $user = check_add_user($call, 'A');
1825                                 @rout = $parent->add($call, $version, Route::here($here), $ip);
1826                                 $r = Route::Node::get($call);
1827                                 $r->PC92C_dxchan($dxchan->call, $hops) if $r;
1828                                 if ($version && is_numeric($version) && !$r->K && !$user->K) {
1829                                         my $old = $user->sort;
1830                                         if ($user->is_ak1a && (($version >= 5455 &&  $build > 0) || ($version >= 3000 && $version <= 3500)) ) {
1831                                                 $user->sort('S');
1832                                                 dbg("PCPROT::_add_thingy node $call v: $version b: $build sort ($old) updated to " . $user->sort);
1833                                         } elsif ($user->is_spider && ($version < 3000 || ($version > 4000 && $version < 5455))) {
1834                                                 unless ($version > 0  && $build == 0) {
1835                                                         $user->sort('A');
1836                                                         $build ||= 0;
1837                                                         dbg("PCPROT::_add_thingy node $call v: $version b: $build sort ($old) downgraded to " . $user->sort);
1838                                                 }
1839                                         }
1840                                 }
1841                                 $r->version($user->version) if $user->version;
1842                                 $r->build($user->build) if $user->build;
1843                                 $r->K(1) if $user->K;
1844                         } else {
1845                                 dbg("ROUTE: added user $call to $ncall") if isdbg('routelow');
1846                                 $user = check_add_user($call, 'U', $parent->call);
1847                                 @rout = $parent->add_user($call, Route::here($here), $ip);
1848                                 $dxchan->tell_buddies('loginb', $call, $ncall) if $dxchan;
1849                                 $r = Route::User::get($call);
1850                         }
1851                         if ($ip) {
1852                                 $r->ip($ip);
1853                                 Log('DXProt', "PC92A $call -> $ip on $ncall");
1854                         }
1855                         if ($pc92_slug_changes && $parent == $main::routeroot) {
1856                                 $things_add{$call} = Route::get($call);
1857                                 delete $things_del{$call};
1858                         }
1859                         $user->close($main::systime, $ip) if $user;             # this just updates lastseen and the connlist list containing the IP address
1860                 } else {
1861                         dbgprintring(10) if isdbg('nologchan');
1862                         dbg("DXProt::add_thingy: Trying to add parent $call to itself $ncall, ignored");
1863                 }
1864         }
1865
1866         return @rout;
1867 }
1868
1869 sub _del_thingy
1870 {
1871         my $parent = shift;
1872         my $s = shift;
1873         my $dxchan = shift;
1874         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1875         my @rout;
1876         if ($call) {
1877                 my $ref;
1878                 if ($is_node) {
1879                         $ref = Route::Node::get($call);
1880                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1881                         @rout = $ref->del($parent) if $ref;
1882                 } else {
1883                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1884                         $ref = Route::User::get($call);
1885                         if ($ref) {
1886                                 $dxchan->tell_buddies('logoutb', $call, $parent->call) if $dxchan;
1887                                 @rout = $parent->del_user($ref);
1888                         }
1889                 }
1890                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1891                         $things_del{$call} = $ref unless exists $things_add{$call};
1892                         delete $things_add{$call};
1893                 }
1894         }
1895         return @rout;
1896 }
1897
1898 # this will only happen if we are slugging changes and
1899 # there are some changes to be sent, it will create an add or a delete
1900 # or both
1901 sub gen_pc92_changes
1902 {
1903         my @add = values %things_add;
1904         my @del = values %things_del;
1905         return (\@add, \@del);
1906 }
1907
1908 sub clear_pc92_changes
1909 {
1910         %things_add = %things_del = ();
1911         $last_pc92_slug = $main::systime;
1912 }
1913
1914 my $_last_time;
1915 my $_last_occurs;
1916 my $_last_pc9x_id;
1917
1918 sub last_pc9x_id
1919 {
1920         return $_last_pc9x_id;
1921 }
1922
1923 sub gen_pc9x_t
1924 {
1925         if (!$_last_time || $_last_time != $main::systime) {
1926                 $_last_time = $main::systime;
1927                 $_last_occurs = 0;
1928                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1929         } else {
1930                 $_last_occurs++;
1931                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1932         }
1933 }
1934
1935 sub check_pc9x_t
1936 {
1937         my $call = shift;
1938         my $t = shift;
1939         my $pc = shift;
1940         my $create = shift;
1941
1942         # check that the time is between 0 >= $t < 86400
1943         unless ($t >= 0 && $t < 86400) {
1944                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1945                 return undef;
1946         }
1947
1948         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1949         my $now = $main::systime - $main::systime_daystart ;
1950         my $diff = abs($now - $t);
1951         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1952                 my $c = ref $call ? $call->call : $call;
1953                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1954                 return undef;
1955         }
1956
1957         my $parent = ref $call ? $call : Route::Node::get($call);
1958         if ($parent) {
1959                 # we only do this for external calls whose routing table
1960                 # record come and go. The reference for mycall is permanent
1961                 # and not that frequently used, it also never times out, so
1962                 # the id on it is completely unreliable. Besides, only commands
1963                 # originating on this box will go through this code...
1964                 if ($parent->call ne $main::mycall) {
1965                         my $lastid = $parent->lastid;
1966                         if (defined $lastid) {
1967                                 if ($t < $lastid) {
1968                                         # note that this is where we determine whether this pc9x has come in yesterday
1969                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1970                                         # duplicate sentence. To determine this we need to do some module 86400
1971                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1972                                         # low numbers that it is a new sentence.
1973                                         #
1974                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1975                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1976                                         # 86378 respectively in the calculation below).
1977                                         #
1978                                         if ($t+86400-$lastid > $pc9x_past_age) {
1979                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1980                                                 return undef;
1981                                         }
1982                                 } elsif ($t == $lastid) {
1983                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1984                                         return undef;
1985                                 } else {
1986                                         # check that if we have a low number in lastid that yesterday's numbers
1987                                         # (likely in the 85000+ area) don't override them, thus causing flip flopping
1988                                         if ($lastid+86400-$t < $pc9x_past_age) {
1989                                                 dbg("PCPROT: dup id on $t in yesterday, lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1990                                                 return undef;
1991                                         }
1992                                 }
1993                         }
1994                 }
1995         } elsif ($create) {
1996                 $parent = Route::Node->new($call);
1997         } else {
1998                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1999                 return undef;
2000         }
2001         if (isdbg('pc92dedupe')) {
2002                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
2003                 my $val = $parent->{lastid};
2004                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
2005                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
2006         }
2007         $parent->lastid($t);
2008
2009         return $parent;
2010 }
2011
2012 sub pc92_handle_first_slot
2013 {
2014         my $self = shift;
2015         my $slot = shift;
2016         my $parent = shift;
2017         my $t = shift;
2018         my $hops = shift;
2019         my $oparent = $parent;
2020
2021         my @radd;
2022
2023         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
2024         if ($call && $is_node) {
2025                 if ($call eq $main::mycall) {
2026                         LogDbg('err', "PCPROT: $self->{call} : $call looped back onto \$main::mycall ($main::mycall), ignored");
2027                         return;
2028                 }
2029                 if ($call eq $main::myalias) {
2030                         LogDbg('err', "PCPROT: $self->{call} : $call looped back onto \$main::myalias ($main::myalias), ignored");
2031                         return;
2032                 }
2033                 # this is only accepted from my "self".
2034                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
2035                 # locally connected. Local nodes always take precedence. But we remember the lastid
2036                 # to try to reduce the number of dupe PC92s for this external node.
2037                 if (DXChannel::get($call) && $call ne $self->{call}) {
2038                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
2039                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
2040                         return;
2041                 }
2042                 if ($is_extnode) {
2043                         # reparent to external node (note that we must have received a 'C' or 'A' record
2044                         # from the true parent node for this external before we get one for the this node
2045                         unless ($parent = Route::Node::get($call)) {
2046                                 if ($is_extnode && $oparent) {
2047                                         @radd = _add_thingy($oparent, $slot, $self, $hops);
2048                                         $parent = $radd[0];
2049                                 } else {
2050                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
2051                                         return;
2052                                 }
2053                         }
2054                         $parent = check_pc9x_t($call, $t, 92) || return;
2055                         $parent->via_pc92(1);
2056                         $parent->PC92C_dxchan($self->{call}, $hops);
2057                 }
2058         } else {
2059                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
2060                 return;
2061         }
2062         $parent->here(Route::here($here));
2063         $parent->version($version || $pc19_version) if $version;
2064     $parent->build($build) if $build;
2065         $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
2066         return ($parent, @radd);
2067 }
2068
2069 # DXSpider routing entries
2070 sub handle_92
2071 {
2072         my $self = shift;
2073         my $pcno = shift;
2074         my $line = shift;
2075         my $origin = shift;
2076         my $pc = shift;
2077
2078         my (@radd, @rdel);
2079
2080         my $pcall = $pc->[1];
2081         my $t = $pc->[2];
2082         my $sort = $pc->[3];
2083         my $hops = $pc->[-1];
2084
2085         # this catches loops of A/Ds
2086 #       if (eph_dup($line, $pc9x_dupe_age)) {
2087 #               return;
2088 #       }
2089
2090         if ($pcall eq $main::mycall) {
2091                 LogDbg('err', "PCPROT: looped back, ignored");
2092                 return;
2093         }
2094
2095         if ($pcall eq $main::myalias) {
2096                 LogDbg('err', "PCPROT: looped back to \$myalias ($main::myalias), misconfiguration ignored");
2097                 return;
2098         }
2099
2100         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
2101                 if ($self->{isolate}) {
2102                         dbg("DXPROT: PC9x received, but $pcall is isolated, ignored");
2103                         return;
2104                 } elsif (!$self->user->wantpc9x) {
2105                         dbg("DXPROT: PC9x explicitly switched off on $pcall, ignored");
2106                         return;
2107                 } else {
2108                         $self->state('init92');
2109                         $self->{do_pc9x} = 1;
2110                         dbg("DXPROT: Do pc9x set on $pcall");
2111                 }
2112         }
2113         unless ($self->{do_pc9x}) {
2114                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2115                 return;
2116         }
2117
2118         # don't create routing entries for D records that don't already exist
2119         # this is what causes all those PC92 loops!
2120         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
2121         my $oparent = $parent;
2122
2123         $parent->do_pc9x(1);
2124         $parent->via_pc92(1);
2125
2126         if ($sort eq 'F' || $sort eq 'R') {
2127
2128                 # this is the route finding section
2129                 # here is where the consequences of the 'find' command
2130                 # are dealt with
2131
2132                 my $from = $pc->[4];
2133                 my $target = $pc->[5];
2134
2135                 if ($sort eq 'F') {
2136                         my $flag;
2137                         my $ref;
2138                         my $dxchan;
2139                         if ($ref = DXChannel::get($target)) {
2140                                 $flag = 1;              # we are directly connected
2141                         } else {
2142                                 $ref = Route::get($target);
2143                                 $dxchan = $ref->dxchan;
2144                                 $flag = 2;
2145                         }
2146                         if ($ref && $flag && $dxchan) {
2147                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
2148                                 return;
2149                         }
2150                 } elsif ($sort eq 'R') {
2151                         if (my $dxchan = DXChannel::get($from)) {
2152                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @$pc[6,7]);
2153                         } else {
2154                                 my $ref = Route::get($from);
2155                                 if ($ref) {
2156                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
2157                                         if (@dxchan) {
2158                                                 $_->send($line) for @dxchan;
2159                                         } else {
2160                                                 dbg("PCPROT: $self->{call} : type R no return route, ignored") if isdbg('chanerr') || isdbg('route');
2161                                         }
2162                                 } else {
2163                                         dbg("PCPROT: $self->{call} : type R no return route, ignored") if isdbg('chanerr') || isdbg('route');
2164                                 }
2165                         }
2166                         return;
2167                 }
2168
2169         } elsif ($sort eq 'K') {
2170                 $pc92Kin += length $line;
2171
2172                 # remember the last channel we arrived on
2173                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
2174
2175                 my @ent = _decode_pc92_call($pc->[4]);
2176
2177                 if (@ent) {
2178                         my $add;
2179
2180                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t, $hops);
2181                         return unless $parent; # dupe
2182
2183                         push @radd, $add if $add;
2184                         $parent->reset_obs;
2185                         my $call = $parent->call;
2186                         my $version = $ent[4] || 0;
2187                         my $build = $ent[5] ||  0;
2188                         $build =~ s/^0\.//;
2189                         my $oldbuild = $parent->build || 0;
2190                         my $oldversion = $parent->version || 0;
2191                         my $user = check_add_user($parent->call, 'S');
2192                         my $oldsort = $user->sort // '';
2193
2194                         dbg("PCPROT: PC92 K v: $version ov: $oldversion b: $build ob: $oldbuild pk: " . ($parent->K || '0') . " uk: " . ($user->K || 0)) if isdbg('pc92k');
2195
2196                         if (is_numeric($version) || is_numeric($build)) {
2197                                 my $changed = 0;
2198                                 if (($oldversion ne $version || $build ne $oldbuild)) {
2199                                         dbg("PCPROT: PC92 K node $call updated version: $version (was $oldversion) build: $build (was $oldbuild)");
2200                                         $user->version($parent->version($version));
2201                                         $user->build($parent->build($build));
2202                                         ++$changed;
2203                                 }
2204                                 if ($oldsort ne 'S') {
2205                                         dbg("PCPROT: PC92 K node $call updated sort: $sort (was $oldsort)");
2206                                         $user->sort('S');
2207                                         ++$changed;
2208                                 }
2209                                 unless ($user->K) {
2210                                         dbg("PCPROT: PC92 K node $call updated - marked as PC92 K user");
2211                                         $user->K(1);
2212                                         ++$changed;
2213                                 }
2214                                 $user->put if $changed;
2215                                 $parent->K(1); # mark this as come in on a K
2216                         } else {
2217                                 dbg("DXProt PC92 K version call $call: invalid version: '$version' or build: '$version', ignored");
2218                         }
2219                         dbg("ROUTE: reset obscount on $call now " . $parent->obscount) if isdbg('obscount');
2220                 }
2221         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
2222
2223                 $pc92Ain += length $line if $sort eq 'A';
2224                 $pc92Cin += length $line if $sort eq 'C';
2225                 $pc92Din += length $line if $sort eq 'D';
2226
2227                 # remember the last channel we arrived on
2228                 $parent->PC92C_dxchan($self->{call}, $hops) unless $self->{call} eq $parent->call;
2229
2230                 # this is the main route section
2231                 # here is where all the routes are created and destroyed
2232
2233                 # cope with missing duplicate node calls in the first slot
2234                 my $me = $pc->[4] || '';
2235                 $me ||= _encode_pc92_call($parent) unless $me ;
2236
2237                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @$pc[5 .. $#$pc];
2238
2239                 if (@ent) {
2240
2241                         # look at the first one which will always be a node of some sort
2242                         # except in the case of 'A' or 'D' in which the $pcall is used
2243                         # otherwise use the node call and update any information
2244                         # that needs to be done.
2245                         my $add;
2246
2247                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t, $hops);
2248                         return unless $parent; # dupe
2249
2250                         shift @ent;
2251                         push @radd, $add if $add;
2252                 }
2253
2254                 # do a pass through removing any references to either mycall
2255                 my @nent;
2256                 for (@ent) {
2257                         my $dxc;
2258                         next unless $_ && @$_;
2259                         if ($_->[0] eq $main::mycall) {
2260                                 dbg("PCPROT: $self->{call} : type $sort $_->[0] refers to me, ignored") if isdbg('route');
2261                                 next;
2262                         }
2263
2264                         my $isnode = ($_->[1] | $_->[2]);
2265                         if (($_->[0] eq $main::myalias && $isnode) || ($_->[0] eq $main::mycall && !$isnode)) {
2266                                 LogDbg('err',"PCPROT: $self->{call} : type $sort $_->[0] trying to change type to " . $_->[1]?"Node":"User" . ", ignored");
2267                                 next;
2268                         }
2269
2270                         push @nent, $_;
2271                 }
2272
2273                 if ($sort eq 'A') {
2274                         for (@nent) {
2275                                 push @radd, _add_thingy($parent, $_, $self, $hops);
2276                         }
2277                 } elsif ($sort eq 'D') {
2278                         for (@nent) {
2279                                 push @rdel, _del_thingy($parent, $_, $self);
2280                         }
2281                 } elsif ($sort eq 'C') {
2282                         my (@nodes, @users);
2283
2284                         # we reset obscounts on config records as well as K records
2285                         $parent->reset_obs;
2286                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
2287
2288                         #
2289                         foreach my $r (@nent) {
2290                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
2291                                 if ($r->[0]) {
2292                                         if ($r->[1]) {
2293                                                 push @nodes, $r->[0];
2294                                         } else {
2295                                                 push @users, $r->[0];
2296                                         }
2297                                 } else {
2298                                         dbg("PCPROT: $self->{call} :  pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr') || isdbg('route');
2299                                 }
2300                         }
2301
2302                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
2303
2304                         # add users here
2305                         foreach my $r (@nent) {
2306                                 my $call = $r->[0];
2307                                 if ($call) {
2308                                         push @radd,_add_thingy($parent, $r, $self, $hops) if grep $call eq $_, (@$nnodes, @$nusers);
2309                                 }
2310                         }
2311                         # del users here
2312                         foreach my $r (@$dnodes) {
2313                                 push @rdel,_del_thingy($parent, [$r, 1], $self);
2314                         }
2315                         foreach my $r (@$dusers) {
2316                                 push @rdel,_del_thingy($parent, [$r, 0], $self);
2317                         }
2318
2319                         # remember this last PC92C for rebroadcast on demand
2320                         $parent->last_PC92C($line);
2321                 } else {
2322                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
2323                         return;
2324                 }
2325
2326                 foreach my $r (@rdel) {
2327                         next unless $r;
2328
2329                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
2330                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
2331                 }
2332                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
2333                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
2334                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
2335                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
2336                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
2337         }
2338
2339         # broadcast it if we get here (but not if it's an A or D record and pc92_ad_enabled isn't set;
2340         if ($sort eq 'A' || $sort eq 'D') {
2341                 return unless $pc92_ad_enabled;
2342         }
2343         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2344 }
2345
2346 # get all the routes for a thing, bearing in mind that the thing (e.g. a user)
2347 # might be on two or more nodes at the same time or that there may be more than
2348 # one equal distance neighbour to a node.
2349 #
2350 # What this means that if sh/route g1tlh shows that he is on (say) two nodes, then
2351 # a Route::findroutes is done on each of those two nodes, the best route(s) taken from
2352 # each and then combined to give a set of dxchans to send the PC9x record down
2353 #
2354 sub find_pc9x_routes
2355 {
2356         my $to = shift;
2357         my $ref = Route::get($to);
2358         my @parent;
2359         my %cand;
2360
2361         if ($ref->isa('Route::User')) {
2362                 my $dxchan = DXChannel::get($to);
2363                 push @parent, $to if $dxchan;
2364                 push @parent, $ref->parents;
2365         } else {
2366                 @parent = $to;
2367         }
2368         foreach my $p (@parent) {
2369                 my $lasthops;
2370                 my @routes = Route::findroutes($p);
2371                 foreach my $r (@routes) {
2372                         $lasthops = $r->[0] unless defined $lasthops;
2373                         if ($r->[0] == $lasthops) {
2374                                 $cand{$r->[1]->call} = $r->[1];
2375                         } else {
2376                                 last;
2377                         }
2378                 }
2379         }
2380         return values %cand;
2381 }
2382
2383 sub handle_93
2384 {
2385         my $self = shift;
2386         my $pcno = shift;
2387         my $line = shift;
2388         my $origin = shift;
2389         my $pc = shift;
2390
2391 #       $self->{do_pc9x} ||= 1;
2392
2393         my $pcall = $pc->[1];                   # this is now checked earlier
2394
2395         # remember that we are converting PC10->PC93 and self will be $main::me if it
2396         # comes from us
2397         unless ($self->{do_pc9x}) {
2398                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
2399                 return;
2400         }
2401
2402         my $t = $pc->[2];
2403         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
2404
2405         my $to = uc $pc->[3];
2406         my $from = uc $pc->[4];
2407         my $via = uc $pc->[5];
2408         my $text = $pc->[6];
2409         my $onode = uc $pc->[7];
2410         my $ipaddr = $pc->[8];
2411
2412         $onode = undef unless $onode && is_callsign($onode);
2413         $onode //= $pcall;
2414         $ipaddr = undef unless $ipaddr && is_ipaddr($ipaddr);
2415
2416         # this is catch loops caused by bad software ...
2417         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
2418                 return;
2419         }
2420
2421         if (isdbg('progress')) {
2422                 my $vs = $via ne '*' ? " via $via" : '';
2423                 my $s = "ANNTALK: $from\@$onode$vs -> $to '$text' route: $origin";
2424                 dbg($s);
2425         }
2426
2427         # if this is a 'bad spotter' user then ignore it
2428         my $nossid = $from;
2429         $nossid =~ s/-\d+$//;
2430         if ($badspotter->in($nossid)) {
2431                 dbg($line) if isdbg('nologchan');
2432                 dbg("PCPROT: Bad Spotter, dropped");
2433                 return;
2434         }
2435
2436         # ignore PC93 coming in from outside this node with a target of local
2437         if ($to eq 'LOCAL' && $self != $main::me) {
2438                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
2439                 return;
2440         }
2441
2442         # will we allow it at all?
2443         if ($censorpc) {
2444                 my @bad;
2445                 if (@bad = BadWords::check($text)) {
2446                         my $bw = join ', ', @bad;
2447                         dbg($line) if isdbg('nologchan');
2448                         dbg("PCPROT: Badwords: '$bw', dropped");
2449                         return;
2450                 }
2451         }
2452
2453         $self->populate_routing_table($onode, $from, $ipaddr);
2454
2455         # if it is routeable then then treat it like a talk
2456         my $ref = Route::get($to);
2457         if ($ref) {
2458                 my $dxchan;
2459
2460                 # convert to PC10 or local talks where appropriate
2461                 # PC93 capable nodes of the same hop count all get a copy
2462                 # if there is a PC10 node then it will get a copy and that
2463                 # will be it. Hopefully such a node will not figure highly
2464                 # in the route list, unless it is local, 'cos it don't issue PC92s!
2465                 # note that both local and PC93s at the same time are possible if the
2466                 # user on more than one node.
2467                 my @routes = find_pc9x_routes($to);
2468                 my $lasthops;
2469                 foreach $dxchan (@routes) {
2470                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
2471                                 if ($dxchan->{do_pc9x}) {
2472                                         $dxchan->send($line);
2473                                 } else {
2474                                         $dxchan->talk($from, $to, $via, $text, $onode);
2475                                 }
2476                         } else {
2477                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
2478                         }
2479                 }
2480                 return;
2481
2482         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
2483                 # announces
2484                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
2485                 my $wx = $to eq 'WX' ? '1' : '0';
2486                 my $local = $via eq 'LOCAL' ? '*' : $via;
2487
2488                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
2489                 return if $via eq 'LOCAL';
2490         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
2491                 # chat messages really only locally connected users
2492                 $self->send_chat(1, $line, $from, '*', $text, $to, $pcall, '0');
2493         }
2494
2495         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
2496         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
2497 }
2498
2499 # if get here then rebroadcast the thing with its Hop count decremented (if
2500 # there is one). If it has a hop count and it decrements to zero then don't
2501 # rebroadcast it.
2502 #
2503 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
2504 #        REBROADCAST!!!!
2505 #
2506
2507 sub handle_default
2508 {
2509         my $self = shift;
2510         my $pcno = shift;
2511         my $line = shift;
2512         my $origin = shift;
2513         my $pc = shift;
2514
2515         unless (eph_dup($line)) {
2516                 if ($pcno >= 90) {
2517                         my $pcall = $pc->[1];
2518                         unless (is_callsign($pcall)) {
2519                                 dbg("PCPROT: invalid callsign string '$pc->[1]', ignored") if isdbg('chanerr');
2520                                 return;
2521                         }
2522                         my $t = $pc->[2];
2523                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
2524                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
2525                 } else {
2526                         unless ($self->{isolate}) {
2527                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
2528                         }
2529                 }
2530         }
2531 }
2532
2533 # does what it says on the tin..
2534 sub populate_routing_table
2535 {
2536         my ($self, $node, $user, $ip) = @_;
2537
2538         my $rn = Route::Node::get($node);
2539         unless ($rn) {
2540                 $rn = Route::Node->new($node);
2541                 dbg("ROUTE $self->{call}: ADD NEW node: $node") if isdbg('pc11');
2542         }
2543
2544         my $ru;
2545         if ($user ne $node) {
2546                 $ru = Route::User::get($user);
2547                 unless ($ru) {
2548                         $rn->add_user($user, 0, undef);
2549                         dbg("ROUTE $self->{call}: ADD NEW user: $user -> $node") if isdbg('pc11');
2550                 }
2551                 $ru = Route::User::get($user);
2552         }
2553
2554         # Add/Change any IP address info
2555
2556         # as we have a route to a user, if it (or the node) does not exist then create them
2557         # link the user to the node if not already done.
2558         # then add or alter the IP address
2559         if ($ip && is_ipaddr($ip)) {
2560                 my $new = $ip;
2561                 if ($ru) {
2562                         if ($ru->ip ne $new) {
2563                                 if ($ru->ip) {
2564                                         my $old = $ru->ip;
2565                                         $ru->ip($new);
2566                                         dbg("ROUTE $self->{call}: ALTER IP node: $node user: $user old IP: '$old'-> new IP: '$new'") if isdbg('pc11');
2567                                 } else{
2568                                         $ru->ip($new);
2569                                         dbg("ROUTE $self->{call}: NEW IP node: $node user: $user IP: '$new'") if isdbg('pc11');
2570                                 }
2571                         }
2572                 } else {
2573                         dbg("ROUTE $self->{call}: ADD Failed for node $node user $user") if isdbg('pc11');
2574                 }
2575         }
2576 }
2577
2578 1;