perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   inqueue => '9,Input Queue,parray',
 123                  );
 124
 125 use vars qw($VERSION $BRANCH);
 126 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 127 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 128 $main::build += $VERSION;
 129 $main::branch += $BRANCH;
 130
 131 # object destruction
 132 sub DESTROY
 133 {
 134         my $self = shift;
 135         for (keys %$self) {
 136                 if (ref($self->{$_})) {
 137                         delete $self->{$_};
 138                 }
 139         }
 140         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 141         $count--;
 142 }
 143
 144 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 145 sub alloc
 146 {
 147         my ($pkg, $call, $conn, $user) = @_;
 148         my $self = {};
 149
 150         die "trying to create a duplicate channel for $call" if $channels{$call};
 151         $self->{call} = $call;
 152         $self->{priv} = 0;
 153         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 154         if (defined $user) {
 155                 $self->{user} = $user;
 156                 $self->{lang} = $user->lang;
 157                 $user->new_group unless $user->group;
 158                 $user->new_buddies unless $user->buddies;
 159                 $self->{group} = $user->group;
 160                 $self->{sort} = $user->sort;
 161         }
 162         $self->{startt} = $self->{t} = time;
 163         $self->{state} = 0;
 164         $self->{oldstate} = 0;
 165         $self->{lang} = $main::lang if !$self->{lang};
 166         $self->{func} = "";
 167
 168         # add in all the dxcc, itu, zone info
 169         my @dxcc = Prefix::extract($call);
 170         if (@dxcc > 0) {
 171                 $self->{dxcc} = $dxcc[1]->dxcc;
 172                 $self->{itu} = $dxcc[1]->itu;
 173                 $self->{cq} = $dxcc[1]->cq;
 174         }
 175         $self->{inqueue} = [];
 176
 177         $count++;
 178         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 179         bless $self, $pkg;
 180         return $channels{$call} = $self;
 181 }
 182
 183 # rebless this channel as something else
 184 sub rebless
 185 {
 186         my $self = shift;
 187         my $class = shift;
 188         return $channels{$self->{call}} = bless $self, $class;
 189 }
 190
 191 sub rec
 192 {
 193         my ($self, $msg) = @_;
 194
 195         # queue the message and the channel object for later processing
 196         if (defined $msg) {
 197                 push @{$self->{inqueue}}, $msg;
 198         }
 199 }
 200
 201 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 202 sub get
 203 {
 204         my $call = shift;
 205         return $channels{$call};
 206 }
 207
 208 # obtain all the channel objects
 209 sub get_all
 210 {
 211         return values(%channels);
 212 }
 213
 214 #
 215 # gimme all the ak1a nodes
 216 #
 217 sub get_all_nodes
 218 {
 219         my $ref;
 220         my @out;
 221         foreach $ref (values %channels) {
 222                 push @out, $ref if $ref->is_node;
 223         }
 224         return @out;
 225 }
 226
 227 # return a list of all users
 228 sub get_all_users
 229 {
 230         my $ref;
 231         my @out;
 232         foreach $ref (values %channels) {
 233                 push @out, $ref if $ref->is_user;
 234         }
 235         return @out;
 236 }
 237
 238 # return a list of all user callsigns
 239 sub get_all_user_calls
 240 {
 241         my $ref;
 242         my @out;
 243         foreach $ref (values %channels) {
 244                 push @out, $ref->{call} if $ref->is_user;
 245         }
 246         return @out;
 247 }
 248
 249 # obtain a channel object by searching for its connection reference
 250 sub get_by_cnum
 251 {
 252         my ($pkg, $conn) = @_;
 253         my $self;
 254
 255         foreach $self (values(%channels)) {
 256                 return $self if ($self->{conn} == $conn);
 257         }
 258         return undef;
 259 }
 260
 261 # get rid of a channel object [$obj->del()]
 262 sub del
 263 {
 264         my $self = shift;
 265
 266         $self->{group} = undef;         # belt and braces
 267         delete $channels{$self->{call}};
 268 }
 269
 270 # is it a bbs
 271 sub is_bbs
 272 {
 273         my $self = shift;
 274         return $self->{'sort'} eq 'B';
 275 }
 276
 277 sub is_node
 278 {
 279         my $self = shift;
 280         return $self->{'sort'} =~ /[ACRSXW]/;
 281 }
 282 # is it an ak1a node ?
 283 sub is_ak1a
 284 {
 285         my $self = shift;
 286         return $self->{'sort'} eq 'A';
 287 }
 288
 289 # is it a user?
 290 sub is_user
 291 {
 292         my $self = shift;
 293         return $self->{'sort'} eq 'U';
 294 }
 295
 296 # is it a clx node
 297 sub is_clx
 298 {
 299         my $self = shift;
 300         return $self->{'sort'} eq 'C';
 301 }
 302
 303 # it is Aranea
 304 sub is_aranea
 305 {
 306         my $self = shift;
 307         return $self->{'sort'} eq 'W';
 308 }
 309
 310 # is it a spider node
 311 sub is_spider
 312 {
 313         my $self = shift;
 314         return $self->{'sort'} eq 'S';
 315 }
 316
 317 # is it a DXNet node
 318 sub is_dxnet
 319 {
 320         my $self = shift;
 321         return $self->{'sort'} eq 'X';
 322 }
 323
 324 # is it a ar-cluster node
 325 sub is_arcluster
 326 {
 327         my $self = shift;
 328         return $self->{'sort'} eq 'R';
 329 }
 330
 331 # for perl 5.004's benefit
 332 sub sort
 333 {
 334         my $self = shift;
 335         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 336 }
 337
 338 # find out whether we are prepared to believe this callsign on this interface
 339 sub is_believed
 340 {
 341         my $self = shift;
 342         my $call = shift;
 343
 344         return grep $call eq $_, $self->user->believe;
 345 }
 346
 347 # handle out going messages, immediately without waiting for the select to drop
 348 # this could, in theory, block
 349 sub send_now
 350 {
 351         my $self = shift;
 352         my $conn = $self->{conn};
 353         return unless $conn;
 354         my $sort = shift;
 355         my $call = $self->{call};
 356
 357         for (@_) {
 358 #               chomp;
 359         my @lines = split /\n/;
 360                 for (@lines) {
 361                         $conn->send_now("$sort$call|$_");
 362                         dbg("-> $sort $call $_") if isdbg('chan');
 363                 }
 364         }
 365         $self->{t} = time;
 366 }
 367
 368 #
 369 # send later with letter (more control)
 370 #
 371
 372 sub send_later
 373 {
 374         my $self = shift;
 375         my $conn = $self->{conn};
 376         return unless $conn;
 377         my $sort = shift;
 378         my $call = $self->{call};
 379
 380         for (@_) {
 381 #               chomp;
 382         my @lines = split /\n/;
 383                 for (@lines) {
 384                         $conn->send_later("$sort$call|$_");
 385                         dbg("-> $sort $call $_") if isdbg('chan');
 386                 }
 387         }
 388         $self->{t} = time;
 389 }
 390
 391 #
 392 # the normal output routine
 393 #
 394 sub send                                                # this is always later and always data
 395 {
 396         my $self = shift;
 397         my $conn = $self->{conn};
 398         return unless $conn;
 399         my $call = $self->{call};
 400
 401         foreach my $l (@_) {
 402                 for (ref $l ? @$l : $l) {
 403                         my @lines = split /\n/;
 404                         for (@lines) {
 405                                 $conn->send_later("D$call|$_");
 406                                 dbg("-> D $call $_") if isdbg('chan');
 407                         }
 408                 }
 409         }
 410         $self->{t} = $main::systime;
 411 }
 412
 413 # send a file (always later)
 414 sub send_file
 415 {
 416         my ($self, $fn) = @_;
 417         my $call = $self->{call};
 418         my $conn = $self->{conn};
 419         my @buf;
 420
 421         open(F, $fn) or die "can't open $fn for sending file ($!)";
 422         @buf = <F>;
 423         close(F);
 424         $self->send(@buf);
 425 }
 426
 427 # this will implement language independence (in time)
 428 sub msg
 429 {
 430         my $self = shift;
 431         return DXM::msg($self->{lang}, @_);
 432 }
 433
 434 # stick a broadcast on the delayed queue (but only up to 20 items)
 435 sub delay
 436 {
 437         my $self = shift;
 438         my $s = shift;
 439
 440         $self->{delayed} = [] unless $self->{delayed};
 441         push @{$self->{delayed}}, $s;
 442         if (@{$self->{delayed}} >= 20) {
 443                 shift @{$self->{delayed}};   # lose oldest one
 444         }
 445 }
 446
 447 # change the state of the channel - lots of scope for debugging here :-)
 448 sub state
 449 {
 450         my $self = shift;
 451         if (@_) {
 452                 $self->{oldstate} = $self->{state};
 453                 $self->{state} = shift;
 454                 $self->{func} = '' unless defined $self->{func};
 455                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 456
 457                 # if there is any queued up broadcasts then splurge them out here
 458                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 459                         $self->send (@{$self->{delayed}});
 460                         delete $self->{delayed};
 461                 }
 462         }
 463         return $self->{state};
 464 }
 465
 466 # disconnect this channel
 467 sub disconnect
 468 {
 469         my $self = shift;
 470         my $user = $self->{user};
 471
 472         $user->close() if defined $user;
 473         $self->{conn}->disconnect;
 474         $self->del();
 475 }
 476
 477 #
 478 # just close all the socket connections down without any fiddling about, cleaning, being
 479 # nice to other processes and otherwise telling them what is going on.
 480 #
 481 # This is for the benefit of forked processes to prepare for starting new programs, they
 482 # don't want or need all this baggage.
 483 #
 484
 485 sub closeall
 486 {
 487         my $ref;
 488         foreach $ref (values %channels) {
 489                 $ref->{conn}->disconnect() if $ref->{conn};
 490         }
 491 }
 492
 493 #
 494 # Tell all the users that we have come in or out (if they want to know)
 495 #
 496 sub tell_login
 497 {
 498         my ($self, $m, $call) = @_;
 499
 500         $call ||= $self->{call};
 501
 502         # send info to all logged in thingies
 503         my @dxchan = get_all_users();
 504         my $dxchan;
 505         foreach $dxchan (@dxchan) {
 506                 next if $dxchan == $self;
 507                 next if $dxchan->{call} eq $main::mycall;
 508                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 509         }
 510 }
 511
 512 #
 513 # Tell all the users if a buddy is logged or out
 514 #
 515 sub tell_buddies
 516 {
 517         my ($self, $m, $call, $node) = @_;
 518
 519         $call ||= $self->{call};
 520         $call =~ s/-\d+$//;
 521         $m .= 'n' if $node;
 522
 523         # send info to all logged in thingies
 524         my @dxchan = get_all_users();
 525         my $dxchan;
 526         foreach $dxchan (@dxchan) {
 527                 next if $dxchan == $self;
 528                 next if $dxchan->{call} eq $main::mycall;
 529                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 530         }
 531 }
 532
 533 # various access routines
 534
 535 #
 536 # return a list of valid elements
 537 #
 538
 539 sub fields
 540 {
 541         return keys(%valid);
 542 }
 543
 544 #
 545 # return a prompt for a field
 546 #
 547
 548 sub field_prompt
 549 {
 550         my ($self, $ele) = @_;
 551         return $valid{$ele};
 552 }
 553
 554 # take a standard input message and decode it into its standard parts
 555 sub decode_input
 556 {
 557         my $dxchan = shift;
 558         my $data = shift;
 559         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 560
 561         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 562
 563         # the above regexp must work
 564         unless (defined $sort && defined $call && defined $line) {
 565 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 566                 dbg("DUFF Line on $chcall: $data");
 567                 return ();
 568         }
 569
 570         if(ref($dxchan) && $call ne $chcall) {
 571                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 572                 return();
 573         }
 574
 575         return ($sort, $call, $line);
 576 }
 577
 578 sub rspfcheck
 579 {
 580         my ($self, $flag, $node, $user) = @_;
 581         my $nref = Route::Node::get($node);
 582         my $dxchan = $nref->dxchan if $nref;
 583         if ($nref && $dxchan) {
 584             if ($dxchan == $self) {
 585                         return 1 unless $user;
 586                         return 1 if $user eq $node;
 587                         my @users = $nref->users;
 588                         return 1 if @users == 0 || grep $user eq $_, @users;
 589                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 590                 } else {
 591                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 592                 }
 593         } else {
 594                 return 1 if $flag;
 595                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 596         }
 597         return 0;
 598 }
 599
 600 # broadcast a message to all clusters taking into account isolation
 601 # [except those mentioned after buffer]
 602 sub broadcast_nodes
 603 {
 604         my $s = shift;                          # the line to be rebroadcast
 605         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 606         my @dxchan = get_all_nodes();
 607         my $dxchan;
 608
 609         # send it if it isn't the except list and isn't isolated and still has a hop count
 610         foreach $dxchan (@dxchan) {
 611                 next if grep $dxchan == $_, @except;
 612                 next if $dxchan == $main::me;
 613
 614                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 615
 616                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 617         }
 618 }
 619
 620 # broadcast a message to all clusters ignoring isolation
 621 # [except those mentioned after buffer]
 622 sub broadcast_all_nodes
 623 {
 624         my $s = shift;                          # the line to be rebroadcast
 625         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 626         my @dxchan = get_all_nodes();
 627         my $dxchan;
 628
 629         # send it if it isn't the except list and isn't isolated and still has a hop count
 630         foreach $dxchan (@dxchan) {
 631                 next if grep $dxchan == $_, @except;
 632                 next if $dxchan == $main::me;
 633
 634                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 635                 $dxchan->send($routeit);
 636         }
 637 }
 638
 639 # broadcast to all users
 640 # storing the spot or whatever until it is in a state to receive it
 641 sub broadcast_users
 642 {
 643         my $s = shift;                          # the line to be rebroadcast
 644         my $sort = shift;           # the type of transmission
 645         my $fref = shift;           # a reference to an object to filter on
 646         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 647         my @dxchan = get_all_users();
 648         my $dxchan;
 649         my @out;
 650
 651         foreach $dxchan (@dxchan) {
 652                 next if grep $dxchan == $_, @except;
 653                 push @out, $dxchan;
 654         }
 655         broadcast_list($s, $sort, $fref, @out);
 656 }
 657
 658
 659 # broadcast to a list of users
 660 sub broadcast_list
 661 {
 662         my $s = shift;
 663         my $sort = shift;
 664         my $fref = shift;
 665         my $dxchan;
 666
 667         foreach $dxchan (@_) {
 668                 my $filter = 1;
 669                 next if $dxchan == $main::me;
 670
 671                 if ($sort eq 'dx') {
 672                     next unless $dxchan->{dx};
 673                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 674                         next unless $filter;
 675                 }
 676                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 677                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 678                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 679                 next if $sort eq 'wx' && !$dxchan->{wx};
 680
 681                 $s =~ s/\a//og unless $dxchan->{beep};
 682
 683                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 684                         $dxchan->send($s);
 685                 } else {
 686                         $dxchan->delay($s);
 687                 }
 688         }
 689 }
 690
 691 sub process
 692 {
 693         foreach my $dxchan (get_all()) {
 694
 695                 while (my $data = shift @{$dxchan->{inqueue}}) {
 696                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 697                         next unless defined $sort;
 698
 699                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 700                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 701                         if ($dxchan->{disconnecting}) {
 702                                 dbg('In disconnection, ignored');
 703                                 next;
 704                         }
 705
 706                         # handle A records
 707                         my $user = $dxchan->user;
 708                         if ($sort eq 'A' || $sort eq 'O') {
 709                                 $dxchan->start($line, $sort);
 710                         } elsif ($sort eq 'I') {
 711                                 die "\$user not defined for $call" if !defined $user;
 712
 713                                 # normal input
 714                                 $dxchan->normal($line);
 715                         } elsif ($sort eq 'Z') {
 716                                 $dxchan->disconnect;
 717                         } elsif ($sort eq 'D') {
 718                                 ;                               # ignored (an echo)
 719                         } elsif ($sort eq 'G') {
 720                                 $dxchan->enhanced($line);
 721                         } else {
 722                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 723                         }
 724                 }
 725         }
 726 }
 727
 728 sub handle_xml
 729 {
 730         my $self = shift;
 731         my $r = 0;
 732
 733         if (DXXml::available()) {
 734                 $r = $self->{handle_xml} || 0;
 735         } else {
 736                 delete $self->{handle_xml} if exists $self->{handle_xml};
 737         }
 738         return $r;
 739 }
 740
 741 #no strict;
 742 sub AUTOLOAD
 743 {
 744         no strict;
 745         my $name = $AUTOLOAD;
 746         return if $name =~ /::DESTROY$/;
 747         $name =~ s/^.*:://o;
 748
 749         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 750
 751         # this clever line of code creates a subroutine which takes over from autoload
 752         # from OO Perl - Conway
 753         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 754         goto &$AUTOLOAD;
 755 }
 756
 757
 758 1;
 759 __END__;