perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2016 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   pc92filter => '5,PC92 Route Filt-out',
  84                   inannfilter => '5,Ann Filt-inp',
  85                   inwwvfilter => '5,WWV Filt-inp',
  86                   inwcyfilter => '5,WCY Filt-inp',
  87                   inspotsfilter => '5,Spot Filt-inp',
  88                   inroutefilter => '5,Route Filt-inp',
  89                   inpc92filter => '5,PC92 Route Filt-inp',
  90                   passwd => '9,Passwd List,yesno',
  91                   pingint => '5,Ping Interval ',
  92                   nopings => '5,Ping Obs Count',
  93                   lastping => '5,Ping last sent,atime',
  94                   pingtime => '5,Ping totaltime,parray',
  95                   pingave => '0,Ping ave time',
  96                   logininfo => '9,Login info req,yesno',
  97                   talklist => '0,Talk List,parray',
  98                   cluster => '5,Cluster data',
  99                   isbasic => '9,Internal Connection',
 100                   errors => '9,Errors',
 101                   route => '9,Route Data',
 102                   dxcc => '0,Country Code',
 103                   itu => '0,ITU Zone',
 104                   cq => '0,CQ Zone',
 105                   enhanced => '5,Enhanced Client,yesno',
 106                   gtk => '5,Using GTK,yesno',
 107                   senddbg => '8,Sending Debug,yesno',
 108                   width => '0,Column Width',
 109                   disconnecting => '9,Disconnecting,yesno',
 110                   ann_talk => '0,Suppress Talk Anns,yesno',
 111                   metric => '1,Route metric',
 112                   badcount => '1,Bad Word Count',
 113                   edit => '7,Edit Function',
 114                   registered => '9,Registered?,yesno',
 115                   prompt => '0,Required Prompt',
 116                   version => '1,Node Version',
 117                   build => '1,Node Build',
 118                   verified => '9,Verified?,yesno',
 119                   newroute => '1,New Style Routing,yesno',
 120                   ve7cc => '0,VE7CC program special,yesno',
 121                   lastmsgpoll => '0,Last Msg Poll,atime',
 122                   inscript => '9,In a script,yesno',
 123                   handle_xml => '9,Handles XML,yesno',
 124                   do_pc9x => '9,Handles PC9x,yesno',
 125                   inqueue => '9,Input Queue,parray',
 126                   next_pc92_update => '9,Next PC92 Update,atime',
 127                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 128                  );
 129
 130 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 131
 132 # object destruction
 133 sub DESTROY
 134 {
 135         my $self = shift;
 136         for (keys %$self) {
 137                 if (ref($self->{$_})) {
 138                         delete $self->{$_};
 139                 }
 140         }
 141         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 142         $count--;
 143 }
 144
 145 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 146 sub alloc
 147 {
 148         my ($pkg, $call, $conn, $user) = @_;
 149         my $self = {};
 150
 151         die "trying to create a duplicate channel for $call" if $channels{$call};
 152         $self->{call} = $call;
 153         $self->{priv} = 0;
 154         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 155         if (defined $user) {
 156                 $self->{user} = $user;
 157                 $self->{lang} = $user->lang;
 158                 $user->new_group unless $user->group;
 159                 $user->new_buddies unless $user->buddies;
 160                 $self->{group} = $user->group;
 161                 $self->{sort} = $user->sort;
 162         }
 163         $self->{startt} = $self->{t} = time;
 164         $self->{state} = 0;
 165         $self->{oldstate} = 0;
 166         $self->{lang} = $main::lang if !$self->{lang};
 167         $self->{func} = "";
 168
 169         # add in all the dxcc, itu, zone info
 170         my @dxcc = Prefix::extract($call);
 171         if (@dxcc > 0) {
 172                 $self->{dxcc} = $dxcc[1]->dxcc;
 173                 $self->{itu} = $dxcc[1]->itu;
 174                 $self->{cq} = $dxcc[1]->cq;
 175         }
 176         $self->{inqueue} = [];
 177
 178         $count++;
 179         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 180         bless $self, $pkg;
 181         return $channels{$call} = $self;
 182 }
 183
 184 # count errors and disconnect if too many
 185 # this has to be here because it can come from rcmd (DXProt) as
 186 # well as DXCommandmode.
 187 sub _error_out
 188 {
 189         my $self = shift;
 190         my $e = shift;
 191         if (++$self->{errors} > $maxerrors) {
 192                 $self->send($self->msg('e26'));
 193                 $self->disconnect;
 194                 return ();
 195         } else {
 196                 return ($self->msg($e));
 197         }
 198 }
 199
 200 # rebless this channel as something else
 201 sub rebless
 202 {
 203         my $self = shift;
 204         my $class = shift;
 205         return $channels{$self->{call}} = bless $self, $class;
 206 }
 207
 208 sub rec
 209 {
 210         my ($self, $msg) = @_;
 211
 212         # queue the message and the channel object for later processing
 213         if (defined $msg) {
 214                 push @{$self->{inqueue}}, $msg;
 215         }
 216         $self->process_one;
 217 }
 218
 219 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 220 sub get
 221 {
 222         my $call = shift;
 223         return $channels{$call};
 224 }
 225
 226 # obtain all the channel objects
 227 sub get_all
 228 {
 229         return values(%channels);
 230 }
 231
 232 #
 233 # gimme all the ak1a nodes
 234 #
 235 sub get_all_nodes
 236 {
 237         my $ref;
 238         my @out;
 239         foreach $ref (values %channels) {
 240                 push @out, $ref if $ref->is_node;
 241         }
 242         return @out;
 243 }
 244
 245 # return a list of node calls
 246 sub get_all_node_calls
 247 {
 248         my $ref;
 249         my @out;
 250         foreach $ref (values %channels) {
 251                 push @out, $ref->{call} if $ref->is_node;
 252         }
 253         return @out;
 254 }
 255
 256 # return a list of all users
 257 sub get_all_users
 258 {
 259         my $ref;
 260         my @out;
 261         foreach $ref (values %channels) {
 262                 push @out, $ref if $ref->is_user;
 263         }
 264         return @out;
 265 }
 266
 267 # return a list of all user callsigns
 268 sub get_all_user_calls
 269 {
 270         my $ref;
 271         my @out;
 272         foreach $ref (values %channels) {
 273                 push @out, $ref->{call} if $ref->is_user;
 274         }
 275         return @out;
 276 }
 277
 278 # obtain a channel object by searching for its connection reference
 279 sub get_by_cnum
 280 {
 281         my ($pkg, $conn) = @_;
 282         my $self;
 283
 284         foreach $self (values(%channels)) {
 285                 return $self if ($self->{conn} == $conn);
 286         }
 287         return undef;
 288 }
 289
 290 # get rid of a channel object [$obj->del()]
 291 sub del
 292 {
 293         my $self = shift;
 294
 295         $self->{group} = undef;         # belt and braces
 296         delete $channels{$self->{call}};
 297 }
 298
 299 # is it a bbs
 300 sub is_bbs
 301 {
 302         my $self = shift;
 303         return $self->{sort} eq 'B';
 304 }
 305
 306 sub is_node
 307 {
 308         my $self = shift;
 309         return $self->{sort} =~ /^[ACRSX]$/;
 310 }
 311 # is it an ak1a node ?
 312 sub is_ak1a
 313 {
 314         my $self = shift;
 315         return $self->{sort} eq 'A';
 316 }
 317
 318 # is it a user?
 319 sub is_user
 320 {
 321         my $self = shift;
 322         return $self->{sort} =~ /^[UW]$/;
 323 }
 324
 325 # is it a clx node
 326 sub is_clx
 327 {
 328         my $self = shift;
 329         return $self->{sort} eq 'C';
 330 }
 331
 332 # it is a Web connected user
 333 sub is_web
 334 {
 335         my $self = shift;
 336         return $self->{sort} eq 'W';
 337 }
 338
 339 # is it a spider node
 340 sub is_spider
 341 {
 342         my $self = shift;
 343         return $self->{sort} eq 'S';
 344 }
 345
 346 # is it a DXNet node
 347 sub is_dxnet
 348 {
 349         my $self = shift;
 350         return $self->{sort} eq 'X';
 351 }
 352
 353 # is it a ar-cluster node
 354 sub is_arcluster
 355 {
 356         my $self = shift;
 357         return $self->{sort} eq 'R';
 358 }
 359
 360 # for perl 5.004's benefit
 361 sub sort
 362 {
 363         my $self = shift;
 364         return @_ ? $self->{sort} = shift : $self->{sort} ;
 365 }
 366
 367 # find out whether we are prepared to believe this callsign on this interface
 368 sub is_believed
 369 {
 370         my $self = shift;
 371         my $call = shift;
 372
 373         return grep $call eq $_, $self->user->believe;
 374 }
 375
 376 # handle out going messages, immediately without waiting for the select to drop
 377 # this could, in theory, block
 378 sub send_now
 379 {
 380         my $self = shift;
 381         my $conn = $self->{conn};
 382         return unless $conn;
 383         my $sort = shift;
 384         my $call = $self->{call};
 385
 386         for (@_) {
 387 #               chomp;
 388         my @lines = split /\n/;
 389                 for (@lines) {
 390                         $conn->send_now("$sort$call|$_");
 391                         # debug log it, but not if it is a log message
 392                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 393                 }
 394         }
 395         $self->{t} = time;
 396 }
 397
 398 #
 399 # send later with letter (more control)
 400 #
 401
 402 sub send_later
 403 {
 404         my $self = shift;
 405         my $conn = $self->{conn};
 406         return unless $conn;
 407         my $sort = shift;
 408         my $call = $self->{call};
 409
 410         for (@_) {
 411 #               chomp;
 412         my @lines = split /\n/;
 413                 for (@lines) {
 414                         $conn->send_later("$sort$call|$_");
 415                         # debug log it, but not if it is a log message
 416                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 417                 }
 418         }
 419         $self->{t} = time;
 420 }
 421
 422 #
 423 # the normal output routine
 424 #
 425 sub send                                                # this is always later and always data
 426 {
 427         my $self = shift;
 428         my $conn = $self->{conn};
 429         return unless $conn;
 430         my $call = $self->{call};
 431
 432         foreach my $l (@_) {
 433                 for (ref $l ? @$l : $l) {
 434                         my @lines = split /\n/;
 435                         for (@lines) {
 436                                 $conn->send_later("D$call|$_");
 437                                 dbg("-> D $call $_") if isdbg('chan');
 438                         }
 439                 }
 440         }
 441         $self->{t} = $main::systime;
 442 }
 443
 444 # send a file (always later)
 445 sub send_file
 446 {
 447         my ($self, $fn) = @_;
 448         my $call = $self->{call};
 449         my $conn = $self->{conn};
 450         my @buf;
 451
 452         open(F, $fn) or die "can't open $fn for sending file ($!)";
 453         @buf = <F>;
 454         close(F);
 455         $self->send(@buf);
 456 }
 457
 458 # this will implement language independence (in time)
 459 sub msg
 460 {
 461         my $self = shift;
 462         return DXM::msg($self->{lang}, @_);
 463 }
 464
 465 # stick a broadcast on the delayed queue (but only up to 20 items)
 466 sub delay
 467 {
 468         my $self = shift;
 469         my $s = shift;
 470
 471         $self->{delayed} = [] unless $self->{delayed};
 472         push @{$self->{delayed}}, $s;
 473         if (@{$self->{delayed}} >= 20) {
 474                 shift @{$self->{delayed}};   # lose oldest one
 475         }
 476 }
 477
 478 # change the state of the channel - lots of scope for debugging here :-)
 479 sub state
 480 {
 481         my $self = shift;
 482         if (@_) {
 483                 $self->{oldstate} = $self->{state};
 484                 $self->{state} = shift;
 485                 $self->{func} = '' unless defined $self->{func};
 486                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 487
 488                 # if there is any queued up broadcasts then splurge them out here
 489                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 490                         $self->send (@{$self->{delayed}});
 491                         delete $self->{delayed};
 492                 }
 493         }
 494         return $self->{state};
 495 }
 496
 497 # disconnect this channel
 498 sub disconnect
 499 {
 500         my $self = shift;
 501         my $user = $self->{user};
 502
 503         $user->close() if defined $user;
 504         $self->{conn}->disconnect if $self->{conn};
 505         $self->del();
 506 }
 507
 508 #
 509 # just close all the socket connections down without any fiddling about, cleaning, being
 510 # nice to other processes and otherwise telling them what is going on.
 511 #
 512 # This is for the benefit of forked processes to prepare for starting new programs, they
 513 # don't want or need all this baggage.
 514 #
 515
 516 sub closeall
 517 {
 518         my $ref;
 519         foreach $ref (values %channels) {
 520                 $ref->{conn}->disconnect() if $ref->{conn};
 521         }
 522 }
 523
 524 #
 525 # Tell all the users that we have come in or out (if they want to know)
 526 #
 527 sub tell_login
 528 {
 529         my ($self, $m, $call) = @_;
 530
 531         $call ||= $self->{call};
 532
 533         # send info to all logged in thingies
 534         my @dxchan = get_all_users();
 535         my $dxchan;
 536         foreach $dxchan (@dxchan) {
 537                 next if $dxchan == $self;
 538                 next if $dxchan->{call} eq $main::mycall;
 539                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 540         }
 541 }
 542
 543 #
 544 # Tell all the users if a buddy is logged or out
 545 #
 546 sub tell_buddies
 547 {
 548         my ($self, $m, $call, $node) = @_;
 549
 550         $call ||= $self->{call};
 551         $call =~ s/-\d+$//;
 552         $m .= 'n' if $node;
 553
 554         # send info to all logged in thingies
 555         my @dxchan = get_all_users();
 556         my $dxchan;
 557         foreach $dxchan (@dxchan) {
 558                 next if $dxchan == $self;
 559                 next if $dxchan->{call} eq $main::mycall;
 560                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 561         }
 562 }
 563
 564 # various access routines
 565
 566 #
 567 # return a list of valid elements
 568 #
 569
 570 sub fields
 571 {
 572         return keys(%valid);
 573 }
 574
 575 #
 576 # return a prompt for a field
 577 #
 578
 579 sub field_prompt
 580 {
 581         my ($self, $ele) = @_;
 582         return $valid{$ele};
 583 }
 584
 585 # take a standard input message and decode it into its standard parts
 586 sub decode_input
 587 {
 588         my $dxchan = shift;
 589         my $data = shift;
 590         my ($sort, $call, $line) = $data =~ /^([A-Z])(#?[A-Z0-9\/\-]{3,25})\|(.*)$/;
 591
 592         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 593
 594         # the above regexp must work
 595         unless (defined $sort && defined $call && defined $line) {
 596 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 597                 dbg("DUFF Line on $chcall: $data");
 598                 return ();
 599         }
 600
 601         if(ref($dxchan) && $call ne $chcall) {
 602                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 603                 return();
 604         }
 605
 606         return ($sort, $call, $line);
 607 }
 608
 609 # broadcast a message to all clusters taking into account isolation
 610 # [except those mentioned after buffer]
 611 sub broadcast_nodes
 612 {
 613         my $s = shift;                          # the line to be rebroadcast
 614         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 615         my @dxchan = get_all_nodes();
 616         my $dxchan;
 617
 618         # send it if it isn't the except list and isn't isolated and still has a hop count
 619         foreach $dxchan (@dxchan) {
 620                 next if grep $dxchan == $_, @except;
 621                 next if $dxchan == $main::me;
 622
 623                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 624
 625                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 626         }
 627 }
 628
 629 # broadcast a message to all clusters ignoring isolation
 630 # [except those mentioned after buffer]
 631 sub broadcast_all_nodes
 632 {
 633         my $s = shift;                          # the line to be rebroadcast
 634         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 635         my @dxchan = get_all_nodes();
 636         my $dxchan;
 637
 638         # send it if it isn't the except list and isn't isolated and still has a hop count
 639         foreach $dxchan (@dxchan) {
 640                 next if grep $dxchan == $_, @except;
 641                 next if $dxchan == $main::me;
 642
 643                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 644                 $dxchan->send($routeit);
 645         }
 646 }
 647
 648 # broadcast to all users
 649 # storing the spot or whatever until it is in a state to receive it
 650 sub broadcast_users
 651 {
 652         my $s = shift;                          # the line to be rebroadcast
 653         my $sort = shift;           # the type of transmission
 654         my $fref = shift;           # a reference to an object to filter on
 655         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 656         my @dxchan = get_all_users();
 657         my $dxchan;
 658         my @out;
 659
 660         foreach $dxchan (@dxchan) {
 661                 next if grep $dxchan == $_, @except;
 662                 push @out, $dxchan;
 663         }
 664         broadcast_list($s, $sort, $fref, @out);
 665 }
 666
 667
 668 # broadcast to a list of users
 669 sub broadcast_list
 670 {
 671         my $s = shift;
 672         my $sort = shift;
 673         my $fref = shift;
 674         my $dxchan;
 675
 676         foreach $dxchan (@_) {
 677                 my $filter = 1;
 678                 next if $dxchan == $main::me;
 679
 680                 if ($sort eq 'dx') {
 681                     next unless $dxchan->{dx};
 682                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 683                         next unless $filter;
 684                 }
 685                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 686                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 687                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 688                 next if $sort eq 'wx' && !$dxchan->{wx};
 689
 690                 $s =~ s/\a//og unless $dxchan->{beep};
 691
 692                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 693                         $dxchan->send($s);
 694                 } else {
 695                         $dxchan->delay($s);
 696                 }
 697         }
 698 }
 699
 700 sub process_one
 701 {
 702         my $self = shift;
 703
 704         while (my $data = shift @{$self->{inqueue}}) {
 705                 my ($sort, $call, $line) = $self->decode_input($data);
 706                 next unless defined $sort;
 707
 708                 # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 709                 dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 710
 711                 # handle A records
 712                 my $user = $self->user;
 713                 if ($sort eq 'I') {
 714                         die "\$user not defined for $call" unless defined $user;
 715
 716                         # normal input
 717                         $self->normal($line);
 718                 } elsif ($sort eq 'G') {
 719                         $self->enhanced($line);
 720                 } elsif ($sort eq 'A' || $sort eq 'O') {
 721                         $self->start($line, $sort);
 722                 } elsif ($sort eq 'Z') {
 723                         $self->disconnect;
 724                 } elsif ($sort eq 'D') {
 725                         ;                               # ignored (an echo)
 726                 } else {
 727                         dbg atime . " DXChannel::process_one: Unknown command letter ($sort) received from $call\n";
 728                 }
 729         }
 730 }
 731
 732 sub process
 733 {
 734         foreach my $dxchan (values %channels) {
 735                 next if $dxchan->{disconnecting};
 736                 $dxchan->process_one;
 737         }
 738 }
 739
 740 sub handle_xml
 741 {
 742         my $self = shift;
 743         my $r = 0;
 744
 745         if (DXXml::available()) {
 746                 $r = $self->{handle_xml} || 0;
 747         } else {
 748                 delete $self->{handle_xml} if exists $self->{handle_xml};
 749         }
 750         return $r;
 751 }
 752
 753 sub error_handler
 754 {
 755         my $self = shift;
 756         my $error = shift || '';
 757         dbg("$self->{call} ERROR '$error', closing") if isdbg('chan');
 758         $self->{conn}->set_error(undef) if exists $self->{conn};
 759         $self->disconnect(1);
 760 }
 761
 762
 763 #no strict;
 764 sub AUTOLOAD
 765 {
 766         no strict;
 767         my $name = $AUTOLOAD;
 768         return if $name =~ /::DESTROY$/;
 769         $name =~ s/^.*:://o;
 770
 771         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 772
 773         # this clever line of code creates a subroutine which takes over from autoload
 774         # from OO Perl - Conway
 775         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 776         goto &$AUTOLOAD;
 777 }
 778
 779
 780 1;
 781 __END__;