perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   handle_xml => '9,Handles XML,yesno',
 121                   inqueue => '9,Input Queue,parray',
 122                  );
 123
 124 use vars qw($VERSION $BRANCH);
 125 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 126 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 127 $main::build += $VERSION;
 128 $main::branch += $BRANCH;
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group() if !$user->group;
 157                 $self->{group} = $user->group;
 158                 $self->{sort} = $user->sort;
 159         }
 160         $self->{startt} = $self->{t} = time;
 161         $self->{state} = 0;
 162         $self->{oldstate} = 0;
 163         $self->{lang} = $main::lang if !$self->{lang};
 164         $self->{func} = "";
 165
 166         # add in all the dxcc, itu, zone info
 167         my @dxcc = Prefix::extract($call);
 168         if (@dxcc > 0) {
 169                 $self->{dxcc} = $dxcc[1]->dxcc;
 170                 $self->{itu} = $dxcc[1]->itu;
 171                 $self->{cq} = $dxcc[1]->cq;
 172         }
 173         $self->{inqueue} = [];
 174
 175         $count++;
 176         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 177         bless $self, $pkg;
 178         return $channels{$call} = $self;
 179 }
 180
 181 # rebless this channel as something else
 182 sub rebless
 183 {
 184         my $self = shift;
 185         my $class = shift;
 186         return $channels{$self->{call}} = bless $self, $class;
 187 }
 188
 189 sub rec
 190 {
 191         my ($self, $msg) = @_;
 192
 193         # queue the message and the channel object for later processing
 194         if (defined $msg) {
 195                 push @{$self->{inqueue}}, $msg;
 196         }
 197 }
 198
 199 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 200 sub get
 201 {
 202         my $call = shift;
 203         return $channels{$call};
 204 }
 205
 206 # obtain all the channel objects
 207 sub get_all
 208 {
 209         return values(%channels);
 210 }
 211
 212 #
 213 # gimme all the ak1a nodes
 214 #
 215 sub get_all_nodes
 216 {
 217         my $ref;
 218         my @out;
 219         foreach $ref (values %channels) {
 220                 push @out, $ref if $ref->is_node;
 221         }
 222         return @out;
 223 }
 224
 225 # return a list of all users
 226 sub get_all_users
 227 {
 228         my $ref;
 229         my @out;
 230         foreach $ref (values %channels) {
 231                 push @out, $ref if $ref->is_user;
 232         }
 233         return @out;
 234 }
 235
 236 # return a list of all user callsigns
 237 sub get_all_user_calls
 238 {
 239         my $ref;
 240         my @out;
 241         foreach $ref (values %channels) {
 242                 push @out, $ref->{call} if $ref->is_user;
 243         }
 244         return @out;
 245 }
 246
 247 # obtain a channel object by searching for its connection reference
 248 sub get_by_cnum
 249 {
 250         my ($pkg, $conn) = @_;
 251         my $self;
 252
 253         foreach $self (values(%channels)) {
 254                 return $self if ($self->{conn} == $conn);
 255         }
 256         return undef;
 257 }
 258
 259 # get rid of a channel object [$obj->del()]
 260 sub del
 261 {
 262         my $self = shift;
 263
 264         $self->{group} = undef;         # belt and braces
 265         delete $channels{$self->{call}};
 266 }
 267
 268 # is it a bbs
 269 sub is_bbs
 270 {
 271         my $self = shift;
 272         return $self->{'sort'} eq 'B';
 273 }
 274
 275 sub is_node
 276 {
 277         my $self = shift;
 278         return $self->{'sort'} =~ /[ACRSXW]/;
 279 }
 280 # is it an ak1a node ?
 281 sub is_ak1a
 282 {
 283         my $self = shift;
 284         return $self->{'sort'} eq 'A';
 285 }
 286
 287 # is it a user?
 288 sub is_user
 289 {
 290         my $self = shift;
 291         return $self->{'sort'} eq 'U';
 292 }
 293
 294 # is it a clx node
 295 sub is_clx
 296 {
 297         my $self = shift;
 298         return $self->{'sort'} eq 'C';
 299 }
 300
 301 # it is Aranea
 302 sub is_aranea
 303 {
 304         my $self = shift;
 305         return $self->{'sort'} eq 'W';
 306 }
 307
 308 # is it a spider node
 309 sub is_spider
 310 {
 311         my $self = shift;
 312         return $self->{'sort'} eq 'S';
 313 }
 314
 315 # is it a DXNet node
 316 sub is_dxnet
 317 {
 318         my $self = shift;
 319         return $self->{'sort'} eq 'X';
 320 }
 321
 322 # is it a ar-cluster node
 323 sub is_arcluster
 324 {
 325         my $self = shift;
 326         return $self->{'sort'} eq 'R';
 327 }
 328
 329 # for perl 5.004's benefit
 330 sub sort
 331 {
 332         my $self = shift;
 333         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 334 }
 335
 336 # find out whether we are prepared to believe this callsign on this interface
 337 sub is_believed
 338 {
 339         my $self = shift;
 340         my $call = shift;
 341
 342         return grep $call eq $_, $self->user->believe;
 343 }
 344
 345 # handle out going messages, immediately without waiting for the select to drop
 346 # this could, in theory, block
 347 sub send_now
 348 {
 349         my $self = shift;
 350         my $conn = $self->{conn};
 351         return unless $conn;
 352         my $sort = shift;
 353         my $call = $self->{call};
 354
 355         for (@_) {
 356 #               chomp;
 357         my @lines = split /\n/;
 358                 for (@lines) {
 359                         $conn->send_now("$sort$call|$_");
 360                         dbg("-> $sort $call $_") if isdbg('chan');
 361                 }
 362         }
 363         $self->{t} = time;
 364 }
 365
 366 #
 367 # send later with letter (more control)
 368 #
 369
 370 sub send_later
 371 {
 372         my $self = shift;
 373         my $conn = $self->{conn};
 374         return unless $conn;
 375         my $sort = shift;
 376         my $call = $self->{call};
 377
 378         for (@_) {
 379 #               chomp;
 380         my @lines = split /\n/;
 381                 for (@lines) {
 382                         $conn->send_later("$sort$call|$_");
 383                         dbg("-> $sort $call $_") if isdbg('chan');
 384                 }
 385         }
 386         $self->{t} = time;
 387 }
 388
 389 #
 390 # the normal output routine
 391 #
 392 sub send                                                # this is always later and always data
 393 {
 394         my $self = shift;
 395         my $conn = $self->{conn};
 396         return unless $conn;
 397         my $call = $self->{call};
 398
 399         foreach my $l (@_) {
 400                 for (ref $l ? @$l : $l) {
 401                         my @lines = split /\n/;
 402                         for (@lines) {
 403                                 $conn->send_later("D$call|$_");
 404                                 dbg("-> D $call $_") if isdbg('chan');
 405                         }
 406                 }
 407         }
 408         $self->{t} = $main::systime;
 409 }
 410
 411 # send a file (always later)
 412 sub send_file
 413 {
 414         my ($self, $fn) = @_;
 415         my $call = $self->{call};
 416         my $conn = $self->{conn};
 417         my @buf;
 418
 419         open(F, $fn) or die "can't open $fn for sending file ($!)";
 420         @buf = <F>;
 421         close(F);
 422         $self->send(@buf);
 423 }
 424
 425 # this will implement language independence (in time)
 426 sub msg
 427 {
 428         my $self = shift;
 429         return DXM::msg($self->{lang}, @_);
 430 }
 431
 432 # stick a broadcast on the delayed queue (but only up to 20 items)
 433 sub delay
 434 {
 435         my $self = shift;
 436         my $s = shift;
 437
 438         $self->{delayed} = [] unless $self->{delayed};
 439         push @{$self->{delayed}}, $s;
 440         if (@{$self->{delayed}} >= 20) {
 441                 shift @{$self->{delayed}};   # lose oldest one
 442         }
 443 }
 444
 445 # change the state of the channel - lots of scope for debugging here :-)
 446 sub state
 447 {
 448         my $self = shift;
 449         if (@_) {
 450                 $self->{oldstate} = $self->{state};
 451                 $self->{state} = shift;
 452                 $self->{func} = '' unless defined $self->{func};
 453                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 454
 455                 # if there is any queued up broadcasts then splurge them out here
 456                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 457                         $self->send (@{$self->{delayed}});
 458                         delete $self->{delayed};
 459                 }
 460         }
 461         return $self->{state};
 462 }
 463
 464 # disconnect this channel
 465 sub disconnect
 466 {
 467         my $self = shift;
 468         my $user = $self->{user};
 469
 470         $user->close() if defined $user;
 471         $self->{conn}->disconnect;
 472         $self->del();
 473 }
 474
 475 #
 476 # just close all the socket connections down without any fiddling about, cleaning, being
 477 # nice to other processes and otherwise telling them what is going on.
 478 #
 479 # This is for the benefit of forked processes to prepare for starting new programs, they
 480 # don't want or need all this baggage.
 481 #
 482
 483 sub closeall
 484 {
 485         my $ref;
 486         foreach $ref (values %channels) {
 487                 $ref->{conn}->disconnect() if $ref->{conn};
 488         }
 489 }
 490
 491 #
 492 # Tell all the users that we have come in or out (if they want to know)
 493 #
 494 sub tell_login
 495 {
 496         my ($self, $m) = @_;
 497
 498         # send info to all logged in thingies
 499         my @dxchan = get_all_users();
 500         my $dxchan;
 501         foreach $dxchan (@dxchan) {
 502                 next if $dxchan == $self;
 503                 next if $dxchan->{call} eq $main::mycall;
 504                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 505         }
 506 }
 507
 508 # various access routines
 509
 510 #
 511 # return a list of valid elements
 512 #
 513
 514 sub fields
 515 {
 516         return keys(%valid);
 517 }
 518
 519 #
 520 # return a prompt for a field
 521 #
 522
 523 sub field_prompt
 524 {
 525         my ($self, $ele) = @_;
 526         return $valid{$ele};
 527 }
 528
 529 # take a standard input message and decode it into its standard parts
 530 sub decode_input
 531 {
 532         my $dxchan = shift;
 533         my $data = shift;
 534         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 535
 536         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 537
 538         # the above regexp must work
 539         unless (defined $sort && defined $call && defined $line) {
 540 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 541                 dbg("DUFF Line on $chcall: $data");
 542                 return ();
 543         }
 544
 545         if(ref($dxchan) && $call ne $chcall) {
 546                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 547                 return();
 548         }
 549
 550         return ($sort, $call, $line);
 551 }
 552
 553 sub rspfcheck
 554 {
 555         my ($self, $flag, $node, $user) = @_;
 556         my $nref = Route::Node::get($node);
 557         my $dxchan = $nref->dxchan if $nref;
 558         if ($nref && $dxchan) {
 559             if ($dxchan == $self) {
 560                         return 1 unless $user;
 561                         return 1 if $user eq $node;
 562                         my @users = $nref->users;
 563                         return 1 if @users == 0 || grep $user eq $_, @users;
 564                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 565                 } else {
 566                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 567                 }
 568         } else {
 569                 return 1 if $flag;
 570                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 571         }
 572         return 0;
 573 }
 574
 575 # broadcast a message to all clusters taking into account isolation
 576 # [except those mentioned after buffer]
 577 sub broadcast_nodes
 578 {
 579         my $s = shift;                          # the line to be rebroadcast
 580         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 581         my @dxchan = get_all_nodes();
 582         my $dxchan;
 583
 584         # send it if it isn't the except list and isn't isolated and still has a hop count
 585         foreach $dxchan (@dxchan) {
 586                 next if grep $dxchan == $_, @except;
 587                 next if $dxchan == $main::me;
 588
 589                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 590
 591                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 592         }
 593 }
 594
 595 # broadcast a message to all clusters ignoring isolation
 596 # [except those mentioned after buffer]
 597 sub broadcast_all_nodes
 598 {
 599         my $s = shift;                          # the line to be rebroadcast
 600         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 601         my @dxchan = get_all_nodes();
 602         my $dxchan;
 603
 604         # send it if it isn't the except list and isn't isolated and still has a hop count
 605         foreach $dxchan (@dxchan) {
 606                 next if grep $dxchan == $_, @except;
 607                 next if $dxchan == $main::me;
 608
 609                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 610                 $dxchan->send($routeit);
 611         }
 612 }
 613
 614 # broadcast to all users
 615 # storing the spot or whatever until it is in a state to receive it
 616 sub broadcast_users
 617 {
 618         my $s = shift;                          # the line to be rebroadcast
 619         my $sort = shift;           # the type of transmission
 620         my $fref = shift;           # a reference to an object to filter on
 621         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 622         my @dxchan = get_all_users();
 623         my $dxchan;
 624         my @out;
 625
 626         foreach $dxchan (@dxchan) {
 627                 next if grep $dxchan == $_, @except;
 628                 push @out, $dxchan;
 629         }
 630         broadcast_list($s, $sort, $fref, @out);
 631 }
 632
 633
 634 # broadcast to a list of users
 635 sub broadcast_list
 636 {
 637         my $s = shift;
 638         my $sort = shift;
 639         my $fref = shift;
 640         my $dxchan;
 641
 642         foreach $dxchan (@_) {
 643                 my $filter = 1;
 644                 next if $dxchan == $main::me;
 645
 646                 if ($sort eq 'dx') {
 647                     next unless $dxchan->{dx};
 648                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 649                         next unless $filter;
 650                 }
 651                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 652                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 653                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 654                 next if $sort eq 'wx' && !$dxchan->{wx};
 655
 656                 $s =~ s/\a//og unless $dxchan->{beep};
 657
 658                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 659                         $dxchan->send($s);
 660                 } else {
 661                         $dxchan->delay($s);
 662                 }
 663         }
 664 }
 665
 666 sub process
 667 {
 668         foreach my $dxchan (get_all()) {
 669
 670                 while (my $data = shift @{$dxchan->{inqueue}}) {
 671                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 672                         next unless defined $sort;
 673
 674                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 675                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 676                         if ($dxchan->{disconnecting}) {
 677                                 dbg('In disconnection, ignored');
 678                                 next;
 679                         }
 680
 681                         # handle A records
 682                         my $user = $dxchan->user;
 683                         if ($sort eq 'A' || $sort eq 'O') {
 684                                 $dxchan->start($line, $sort);
 685                         } elsif ($sort eq 'I') {
 686                                 die "\$user not defined for $call" if !defined $user;
 687
 688                                 # normal input
 689                                 $dxchan->normal($line);
 690                         } elsif ($sort eq 'Z') {
 691                                 $dxchan->disconnect;
 692                         } elsif ($sort eq 'D') {
 693                                 ;                               # ignored (an echo)
 694                         } elsif ($sort eq 'G') {
 695                                 $dxchan->enhanced($line);
 696                         } else {
 697                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 698                         }
 699                 }
 700         }
 701 }
 702
 703 #no strict;
 704 sub AUTOLOAD
 705 {
 706         no strict;
 707         my $name = $AUTOLOAD;
 708         return if $name =~ /::DESTROY$/;
 709         $name =~ s/^.*:://o;
 710
 711         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 712
 713         # this clever line of code creates a subroutine which takes over from autoload
 714         # from OO Perl - Conway
 715         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 716         goto &$AUTOLOAD;
 717 }
 718
 719
 720 1;
 721 __END__;