Get basic web protocol working
[spider.git] / perl / DXChannel.pm
1 #
2 # module to manage channel lists & data
3 #
4 # This is the base class for all channel operations, which is everything to do 
5 # with input and output really.
6 #
7 # The instance variable in the outside world will be generally be called $dxchan
8 #
9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
10 # by various other modules. The point to understand is that the 'instance variable'
11 # is in fact what normal people would call the state vector and all useful info
12 # about a connection goes in there.
13 #
14 # Another point to note is that a vector may contain a list of other vectors. 
15 # I have simply added another variable to the vector for 'simplicity' (or laziness
16 # as it is more commonly called)
17 #
18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
19 # firstly and OO about ninthly (if you don't like the design and you can't 
20 # improve it with better OO and thus make it smaller and more efficient, then tough). 
21 #
22 # Copyright (c) 1998-2016 - Dirk Koopman G1TLH
23 #
24 #
25 #
26 package DXChannel;
27
28 use Msg;
29 use DXM;
30 use DXUtil;
31 use DXVars;
32 use DXDebug;
33 use Filter;
34 use Prefix;
35 use Route;
36
37 use strict;
38 use vars qw(%channels %valid @ISA $count $maxerrors);
39
40 %channels = ();
41 $count = 0;
42
43 %valid = (
44                   call => '0,Callsign',
45                   conn => '9,Msg Conn ref',
46                   user => '9,DXUser ref',
47                   startt => '0,Start Time,atime',
48                   t => '9,Time,atime',
49                   pc50_t => '5,Last PC50 Time,atime',
50                   priv => '9,Privilege',
51                   state => '0,Current State',
52                   oldstate => '5,Last State',
53                   list => '9,Dep Chan List',
54                   name => '0,User Name',
55                   consort => '5,Connection Type',
56                   'sort' => '5,Type of Channel',
57                   wwv => '0,Want WWV,yesno',
58                   wcy => '0,Want WCY,yesno',
59                   wx => '0,Want WX,yesno',
60                   talk => '0,Want Talk,yesno',
61                   ann => '0,Want Announce,yesno',
62                   here => '0,Here?,yesno',
63                   conf => '0,In Conference?,yesno',
64                   dx => '0,DX Spots,yesno',
65                   redirect => '0,Redirect messages to',
66                   lang => '0,Language',
67                   func => '5,Function',
68                   loc => '9,Local Vars', # used by func to store local variables in
69                   beep => '0,Want Beeps,yesno',
70                   lastread => '5,Last Msg Read',
71                   outbound => '5,outbound?,yesno',
72                   remotecmd => '9,doing rcmd,yesno',
73                   pagelth => '0,Page Length',
74                   pagedata => '9,Page Data Store',
75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
76                   isolate => '5,Isolate network,yesno',
77                   delayed => '5,Delayed messages,parray',
78                   annfilter => '5,Ann Filt-out',
79                   wwvfilter => '5,WWV Filt-out',
80                   wcyfilter => '5,WCY Filt-out',
81                   spotsfilter => '5,Spot Filt-out',
82                   routefilter => '5,Route Filt-out',
83                   pc92filter => '5,PC92 Route Filt-out',
84                   inannfilter => '5,Ann Filt-inp',
85                   inwwvfilter => '5,WWV Filt-inp',
86                   inwcyfilter => '5,WCY Filt-inp',
87                   inspotsfilter => '5,Spot Filt-inp',
88                   inroutefilter => '5,Route Filt-inp',
89                   inpc92filter => '5,PC92 Route Filt-inp',
90                   passwd => '9,Passwd List,yesno',
91                   pingint => '5,Ping Interval ',
92                   nopings => '5,Ping Obs Count',
93                   lastping => '5,Ping last sent,atime',
94                   pingtime => '5,Ping totaltime,parray',
95                   pingave => '0,Ping ave time',
96                   logininfo => '9,Login info req,yesno',
97                   talklist => '0,Talk List,parray',
98                   cluster => '5,Cluster data',
99                   isbasic => '9,Internal Connection', 
100                   errors => '9,Errors',
101                   route => '9,Route Data',
102                   dxcc => '0,Country Code',
103                   itu => '0,ITU Zone',
104                   cq => '0,CQ Zone',
105                   enhanced => '5,Enhanced Client,yesno',
106                   gtk => '5,Using GTK,yesno',
107                   senddbg => '8,Sending Debug,yesno',
108                   width => '0,Column Width',
109                   disconnecting => '9,Disconnecting,yesno',
110                   ann_talk => '0,Suppress Talk Anns,yesno',
111                   metric => '1,Route metric',
112                   badcount => '1,Bad Word Count',
113                   edit => '7,Edit Function',
114                   registered => '9,Registered?,yesno',
115                   prompt => '0,Required Prompt',
116                   version => '1,Node Version',
117                   build => '1,Node Build',
118                   verified => '9,Verified?,yesno',
119                   newroute => '1,New Style Routing,yesno',
120                   ve7cc => '0,VE7CC program special,yesno',
121                   lastmsgpoll => '0,Last Msg Poll,atime',
122                   inscript => '9,In a script,yesno',
123                   handle_xml => '9,Handles XML,yesno',
124                   do_pc9x => '9,Handles PC9x,yesno',
125                   inqueue => '9,Input Queue,parray',
126                   next_pc92_update => '9,Next PC92 Update,atime',
127                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
128                   hostname => '0,Hostname',
129                  );
130
131 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
132
133 # object destruction
134 sub DESTROY
135 {
136         my $self = shift;
137         for (keys %$self) {
138                 if (ref($self->{$_})) {
139                         delete $self->{$_};
140                 }
141         }
142         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
143         $count--;
144 }
145
146 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
147 sub alloc
148 {
149         my ($pkg, $call, $conn, $user) = @_;
150         my $self = {};
151   
152         die "trying to create a duplicate channel for $call" if $channels{$call};
153         $self->{call} = $call;
154         $self->{priv} = 0;
155         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
156         if (defined $user) {
157                 $self->{user} = $user;
158                 $self->{lang} = $user->lang;
159                 $user->new_group unless $user->group;
160                 $user->new_buddies unless $user->buddies;
161                 $self->{group} = $user->group;
162                 $self->{sort} = $user->sort;
163         }
164         $self->{startt} = $self->{t} = time;
165         $self->{state} = 0;
166         $self->{oldstate} = 0;
167         $self->{lang} = $main::lang if !$self->{lang};
168         $self->{func} = "";
169
170         # add in all the dxcc, itu, zone info
171         my @dxcc = Prefix::extract($call);
172         if (@dxcc > 0) {
173                 $self->{dxcc} = $dxcc[1]->dxcc;
174                 $self->{itu} = $dxcc[1]->itu;
175                 $self->{cq} = $dxcc[1]->cq;
176         }
177         $self->{inqueue} = [];
178
179         $count++;
180         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
181         bless $self, $pkg; 
182         return $channels{$call} = $self;
183 }
184
185 # count errors and disconnect if too many
186 # this has to be here because it can come from rcmd (DXProt) as
187 # well as DXCommandmode.
188 sub _error_out
189 {
190         my $self = shift;
191         my $e = shift;
192         if (++$self->{errors} > $maxerrors) {
193                 $self->send($self->msg('e26'));
194                 $self->disconnect;
195                 return ();
196         } else {
197                 return ($self->msg($e));
198         }
199 }
200
201 # rebless this channel as something else
202 sub rebless
203 {
204         my $self = shift;
205         my $class = shift;
206         return $channels{$self->{call}} = bless $self, $class;
207 }
208
209 sub rec 
210 {
211         my ($self, $msg) = @_;
212         
213         # queue the message and the channel object for later processing
214         if (defined $msg) {
215                 push @{$self->{inqueue}}, $msg;
216         }
217         $self->process_one;
218 }
219
220 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
221 sub get
222 {
223         my $call = shift;
224         return $channels{$call};
225 }
226
227 # obtain all the channel objects
228 sub get_all
229 {
230         return values(%channels);
231 }
232
233 #
234 # gimme all the ak1a nodes
235 #
236 sub get_all_nodes
237 {
238         my $ref;
239         my @out;
240         foreach $ref (values %channels) {
241                 push @out, $ref if $ref->is_node;
242         }
243         return @out;
244 }
245
246 # return a list of node calls
247 sub get_all_node_calls
248 {
249         my $ref;
250         my @out;
251         foreach $ref (values %channels) {
252                 push @out, $ref->{call} if $ref->is_node;
253         }
254         return @out;
255 }
256
257 # return a list of all users
258 sub get_all_users
259 {
260         my $ref;
261         my @out;
262         foreach $ref (values %channels) {
263                 push @out, $ref if $ref->is_user;
264         }
265         return @out;
266 }
267
268 # return a list of all user callsigns
269 sub get_all_user_calls
270 {
271         my $ref;
272         my @out;
273         foreach $ref (values %channels) {
274                 push @out, $ref->{call} if $ref->is_user;
275         }
276         return @out;
277 }
278
279 # obtain a channel object by searching for its connection reference
280 sub get_by_cnum
281 {
282         my ($pkg, $conn) = @_;
283         my $self;
284   
285         foreach $self (values(%channels)) {
286                 return $self if ($self->{conn} == $conn);
287         }
288         return undef;
289 }
290
291 # get rid of a channel object [$obj->del()]
292 sub del
293 {
294         my $self = shift;
295
296         $self->{group} = undef;         # belt and braces
297         delete $channels{$self->{call}};
298 }
299
300 # is it a bbs
301 sub is_bbs
302 {
303         my $self = shift;
304         return $self->{sort} eq 'B';
305 }
306
307 sub is_node
308 {
309         my $self = shift;
310         return $self->{sort} =~ /^[ACRSX]$/;
311 }
312 # is it an ak1a node ?
313 sub is_ak1a
314 {
315         my $self = shift;
316         return $self->{sort} eq 'A';
317 }
318
319 # is it a user?
320 sub is_user
321 {
322         my $self = shift;
323         return $self->{sort} =~ /^[UW]$/;
324 }
325
326 # is it a clx node
327 sub is_clx
328 {
329         my $self = shift;
330         return $self->{sort} eq 'C';
331 }
332
333 # it is a Web connected user
334 sub is_web
335 {
336         my $self = shift;
337         return $self->{sort} eq 'W';
338 }
339
340 # is it a spider node
341 sub is_spider
342 {
343         my $self = shift;
344         return $self->{sort} eq 'S';
345 }
346
347 # is it a DXNet node
348 sub is_dxnet
349 {
350         my $self = shift;
351         return $self->{sort} eq 'X';
352 }
353
354 # is it a ar-cluster node
355 sub is_arcluster
356 {
357         my $self = shift;
358         return $self->{sort} eq 'R';
359 }
360
361 # for perl 5.004's benefit
362 sub sort
363 {
364         my $self = shift;
365         return @_ ? $self->{sort} = shift : $self->{sort} ;
366 }
367
368 # find out whether we are prepared to believe this callsign on this interface
369 sub is_believed
370 {
371         my $self = shift;
372         my $call = shift;
373         
374         return grep $call eq $_, $self->user->believe;
375 }
376
377 # handle out going messages, immediately without waiting for the select to drop
378 # this could, in theory, block
379 sub send_now
380 {
381         my $self = shift;
382         my $conn = $self->{conn};
383         return unless $conn;
384         my $sort = shift;
385         my $call = $self->{call};
386         
387         for (@_) {
388 #               chomp;
389         my @lines = split /\n/;
390                 for (@lines) {
391                         $conn->send_now("$sort$call|$_");
392                         # debug log it, but not if it is a log message
393                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
394                 }
395         }
396         $self->{t} = time;
397 }
398
399 #
400 # send later with letter (more control)
401 #
402
403 sub send_later
404 {
405         my $self = shift;
406         my $conn = $self->{conn};
407         return unless $conn;
408         my $sort = shift;
409         my $call = $self->{call};
410         
411         for (@_) {
412 #               chomp;
413         my @lines = split /\n/;
414                 for (@lines) {
415                         $conn->send_later("$sort$call|$_");
416                         # debug log it, but not if it is a log message
417                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
418                 }
419         }
420         $self->{t} = time;
421 }
422
423 #
424 # the normal output routine
425 #
426 sub send                                                # this is always later and always data
427 {
428         my $self = shift;
429         my $conn = $self->{conn};
430         return unless $conn;
431         my $call = $self->{call};
432
433         foreach my $l (@_) {
434                 for (ref $l ? @$l : $l) {
435                         my @lines = split /\n/;
436                         for (@lines) {
437                                 $conn->send_later("D$call|$_");
438                                 dbg("-> D $call $_") if isdbg('chan');
439                         }
440                 }
441         }
442         $self->{t} = $main::systime;
443 }
444
445 # send a file (always later)
446 sub send_file
447 {
448         my ($self, $fn) = @_;
449         my $call = $self->{call};
450         my $conn = $self->{conn};
451         my @buf;
452   
453         open(F, $fn) or die "can't open $fn for sending file ($!)";
454         @buf = <F>;
455         close(F);
456         $self->send(@buf);
457 }
458
459 # this will implement language independence (in time)
460 sub msg
461 {
462         my $self = shift;
463         return DXM::msg($self->{lang}, @_);
464 }
465
466 # stick a broadcast on the delayed queue (but only up to 20 items)
467 sub delay
468 {
469         my $self = shift;
470         my $s = shift;
471         
472         $self->{delayed} = [] unless $self->{delayed};
473         push @{$self->{delayed}}, $s;
474         if (@{$self->{delayed}} >= 20) {
475                 shift @{$self->{delayed}};   # lose oldest one
476         }
477 }
478
479 # change the state of the channel - lots of scope for debugging here :-)
480 sub state
481 {
482         my $self = shift;
483         if (@_) {
484                 $self->{oldstate} = $self->{state};
485                 $self->{state} = shift;
486                 $self->{func} = '' unless defined $self->{func};
487                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
488
489                 # if there is any queued up broadcasts then splurge them out here
490                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
491                         $self->send (@{$self->{delayed}});
492                         delete $self->{delayed};
493                 }
494         }
495         return $self->{state};
496 }
497
498 # disconnect this channel
499 sub disconnect
500 {
501         my $self = shift;
502         my $user = $self->{user};
503         
504         $user->close() if defined $user;
505         $self->{conn}->disconnect if $self->{conn};
506         $self->del();
507 }
508
509 #
510 # just close all the socket connections down without any fiddling about, cleaning, being
511 # nice to other processes and otherwise telling them what is going on.
512 #
513 # This is for the benefit of forked processes to prepare for starting new programs, they
514 # don't want or need all this baggage.
515 #
516
517 sub closeall
518 {
519         my $ref;
520         foreach $ref (values %channels) {
521                 $ref->{conn}->disconnect() if $ref->{conn};
522         }
523 }
524
525 #
526 # Tell all the users that we have come in or out (if they want to know)
527 #
528 sub tell_login
529 {
530         my ($self, $m, $call) = @_;
531         
532         $call ||= $self->{call};
533         
534         # send info to all logged in thingies
535         my @dxchan = get_all_users();
536         my $dxchan;
537         foreach $dxchan (@dxchan) {
538                 next if $dxchan == $self;
539                 next if $dxchan->{call} eq $main::mycall;
540                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
541         }
542 }
543
544 #
545 # Tell all the users if a buddy is logged or out
546 #
547 sub tell_buddies
548 {
549         my ($self, $m, $call, $node) = @_;
550         
551         $call ||= $self->{call};
552         $call =~ s/-\d+$//;
553         $m .= 'n' if $node;
554         
555         # send info to all logged in thingies
556         my @dxchan = get_all_users();
557         my $dxchan;
558         foreach $dxchan (@dxchan) {
559                 next if $dxchan == $self;
560                 next if $dxchan->{call} eq $main::mycall;
561                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
562         }
563 }
564
565 # various access routines
566
567 #
568 # return a list of valid elements 
569
570
571 sub fields
572 {
573         return keys(%valid);
574 }
575
576 #
577 # return a prompt for a field
578 #
579
580 sub field_prompt
581
582         my ($self, $ele) = @_;
583         return $valid{$ele};
584 }
585
586 # take a standard input message and decode it into its standard parts
587 sub decode_input
588 {
589         my $dxchan = shift;
590         my $data = shift;
591         my ($sort, $call, $line) = $data =~ /^([A-Z])(#?[A-Z0-9\/\-]{3,25})\|(.*)$/;
592
593         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
594         
595         # the above regexp must work
596         unless (defined $sort && defined $call && defined $line) {
597 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
598                 dbg("DUFF Line on $chcall: $data");
599                 return ();
600         }
601
602         if(ref($dxchan) && $call ne $chcall) {
603                 dbg("DUFF Line come in for $call on wrong channel $chcall");
604                 return();
605         }
606         
607         return ($sort, $call, $line);
608 }
609
610 # broadcast a message to all clusters taking into account isolation
611 # [except those mentioned after buffer]
612 sub broadcast_nodes
613 {
614         my $s = shift;                          # the line to be rebroadcast
615         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
616         my @dxchan = get_all_nodes();
617         my $dxchan;
618         
619         # send it if it isn't the except list and isn't isolated and still has a hop count
620         foreach $dxchan (@dxchan) {
621                 next if grep $dxchan == $_, @except;
622                 next if $dxchan == $main::me;
623                 
624                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
625
626                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
627         }
628 }
629
630 # broadcast a message to all clusters ignoring isolation
631 # [except those mentioned after buffer]
632 sub broadcast_all_nodes
633 {
634         my $s = shift;                          # the line to be rebroadcast
635         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
636         my @dxchan = get_all_nodes();
637         my $dxchan;
638         
639         # send it if it isn't the except list and isn't isolated and still has a hop count
640         foreach $dxchan (@dxchan) {
641                 next if grep $dxchan == $_, @except;
642                 next if $dxchan == $main::me;
643
644                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
645                 $dxchan->send($routeit);
646         }
647 }
648
649 # broadcast to all users
650 # storing the spot or whatever until it is in a state to receive it
651 sub broadcast_users
652 {
653         my $s = shift;                          # the line to be rebroadcast
654         my $sort = shift;           # the type of transmission
655         my $fref = shift;           # a reference to an object to filter on
656         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
657         my @dxchan = get_all_users();
658         my $dxchan;
659         my @out;
660         
661         foreach $dxchan (@dxchan) {
662                 next if grep $dxchan == $_, @except;
663                 push @out, $dxchan;
664         }
665         broadcast_list($s, $sort, $fref, @out);
666 }
667
668
669 # broadcast to a list of users
670 sub broadcast_list
671 {
672         my $s = shift;
673         my $sort = shift;
674         my $fref = shift;
675         my $dxchan;
676         
677         foreach $dxchan (@_) {
678                 my $filter = 1;
679                 next if $dxchan == $main::me;
680                 
681                 if ($sort eq 'dx') {
682                     next unless $dxchan->{dx};
683                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
684                         next unless $filter;
685                 }
686                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
687                 next if $sort eq 'wwv' && !$dxchan->{wwv};
688                 next if $sort eq 'wcy' && !$dxchan->{wcy};
689                 next if $sort eq 'wx' && !$dxchan->{wx};
690
691                 $s =~ s/\a//og unless $dxchan->{beep};
692
693                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
694                         $dxchan->send($s);      
695                 } else {
696                         $dxchan->delay($s);
697                 }
698         }
699 }
700
701 sub process_one
702 {
703         my $self = shift;
704
705         while (my $data = shift @{$self->{inqueue}}) {
706                 my ($sort, $call, $line) = $self->decode_input($data);
707                 next unless defined $sort;
708                 
709                 # do the really sexy console interface bit! (Who is going to do the TK interface then?)
710                 dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
711                 
712                 # handle A records
713                 my $user = $self->user;
714                 if ($sort eq 'I') {
715                         die "\$user not defined for $call" unless defined $user;
716                         
717                         # normal input
718                         $self->normal($line);
719                 } elsif ($sort eq 'G') {
720                         $self->enhanced($line);
721                 } elsif ($sort eq 'A' || $sort eq 'O' || $sort eq 'W') {
722                         $self->start($line, $sort);
723                 } elsif ($sort eq 'Z') {
724                         $self->disconnect;
725                 } elsif ($sort eq 'D') {
726                         ;                               # ignored (an echo)
727                 } else {
728                         dbg atime . " DXChannel::process_one: Unknown command letter ($sort) received from $call\n";
729                 }
730         }
731 }
732
733 sub process
734 {
735         foreach my $dxchan (values %channels) {
736                 next if $dxchan->{disconnecting};
737                 $dxchan->process_one;
738         }
739 }
740
741 sub handle_xml
742 {
743         my $self = shift;
744         my $r = 0;
745         
746         if (DXXml::available()) {
747                 $r = $self->{handle_xml} || 0;
748         } else {
749                 delete $self->{handle_xml} if exists $self->{handle_xml};
750         }
751         return $r;
752 }
753
754 sub error_handler
755 {
756         my $self = shift;
757         my $error = shift || '';
758         dbg("$self->{call} ERROR '$error', closing") if isdbg('chan');
759         $self->{conn}->set_error(undef) if exists $self->{conn};
760         $self->disconnect(1);
761 }
762
763
764 #no strict;
765 sub AUTOLOAD
766 {
767         no strict;
768         my $name = $AUTOLOAD;
769         return if $name =~ /::DESTROY$/;
770         $name =~ s/^.*:://o;
771   
772         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
773
774         # this clever line of code creates a subroutine which takes over from autoload
775         # from OO Perl - Conway
776         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
777         goto &$AUTOLOAD;
778 }
779
780
781 1;
782 __END__;