perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   gtk => '5,Using GTK,yesno',
 105                   senddbg => '8,Sending Debug,yesno',
 106                   width => '0,Column Width',
 107                   disconnecting => '9,Disconnecting,yesno',
 108                   ann_talk => '0,Suppress Talk Anns,yesno',
 109                   metric => '1,Route metric',
 110                   badcount => '1,Bad Word Count',
 111                   edit => '7,Edit Function',
 112                   registered => '9,Registered?,yesno',
 113                   prompt => '0,Required Prompt',
 114                   version => '1,Node Version',
 115                   build => '1,Node Build',
 116                   verified => '9,Verified?,yesno',
 117                   newroute => '1,New Style Routing,yesno',
 118                   ve7cc => '0,VE7CC program special,yesno',
 119                   lastmsgpoll => '0,Last Msg Poll,atime',
 120                   inscript => '9,In a script,yesno',
 121                   handle_xml => '9,Handles XML,yesno',
 122                   inqueue => '9,Input Queue,parray',
 123                  );
 124
 125 # object destruction
 126 sub DESTROY
 127 {
 128         my $self = shift;
 129         for (keys %$self) {
 130                 if (ref($self->{$_})) {
 131                         delete $self->{$_};
 132                 }
 133         }
 134         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 135         $count--;
 136 }
 137
 138 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 139 sub alloc
 140 {
 141         my ($pkg, $call, $conn, $user) = @_;
 142         my $self = {};
 143
 144         die "trying to create a duplicate channel for $call" if $channels{$call};
 145         $self->{call} = $call;
 146         $self->{priv} = 0;
 147         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 148         if (defined $user) {
 149                 $self->{user} = $user;
 150                 $self->{lang} = $user->lang;
 151                 $user->new_group unless $user->group;
 152                 $user->new_buddies unless $user->buddies;
 153                 $self->{group} = $user->group;
 154                 $self->{sort} = $user->sort;
 155         }
 156         $self->{startt} = $self->{t} = time;
 157         $self->{state} = 0;
 158         $self->{oldstate} = 0;
 159         $self->{lang} = $main::lang if !$self->{lang};
 160         $self->{func} = "";
 161
 162         # add in all the dxcc, itu, zone info
 163         my @dxcc = Prefix::extract($call);
 164         if (@dxcc > 0) {
 165                 $self->{dxcc} = $dxcc[1]->dxcc;
 166                 $self->{itu} = $dxcc[1]->itu;
 167                 $self->{cq} = $dxcc[1]->cq;
 168         }
 169         $self->{inqueue} = [];
 170
 171         $count++;
 172         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 173         bless $self, $pkg;
 174         return $channels{$call} = $self;
 175 }
 176
 177 # rebless this channel as something else
 178 sub rebless
 179 {
 180         my $self = shift;
 181         my $class = shift;
 182         return $channels{$self->{call}} = bless $self, $class;
 183 }
 184
 185 sub rec
 186 {
 187         my ($self, $msg) = @_;
 188
 189         # queue the message and the channel object for later processing
 190         if (defined $msg) {
 191                 push @{$self->{inqueue}}, $msg;
 192         }
 193 }
 194
 195 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 196 sub get
 197 {
 198         my $call = shift;
 199         return $channels{$call};
 200 }
 201
 202 # obtain all the channel objects
 203 sub get_all
 204 {
 205         return values(%channels);
 206 }
 207
 208 #
 209 # gimme all the ak1a nodes
 210 #
 211 sub get_all_nodes
 212 {
 213         my $ref;
 214         my @out;
 215         foreach $ref (values %channels) {
 216                 push @out, $ref if $ref->is_node;
 217         }
 218         return @out;
 219 }
 220
 221 # return a list of all users
 222 sub get_all_users
 223 {
 224         my $ref;
 225         my @out;
 226         foreach $ref (values %channels) {
 227                 push @out, $ref if $ref->is_user;
 228         }
 229         return @out;
 230 }
 231
 232 # return a list of all user callsigns
 233 sub get_all_user_calls
 234 {
 235         my $ref;
 236         my @out;
 237         foreach $ref (values %channels) {
 238                 push @out, $ref->{call} if $ref->is_user;
 239         }
 240         return @out;
 241 }
 242
 243 # obtain a channel object by searching for its connection reference
 244 sub get_by_cnum
 245 {
 246         my ($pkg, $conn) = @_;
 247         my $self;
 248
 249         foreach $self (values(%channels)) {
 250                 return $self if ($self->{conn} == $conn);
 251         }
 252         return undef;
 253 }
 254
 255 # get rid of a channel object [$obj->del()]
 256 sub del
 257 {
 258         my $self = shift;
 259
 260         $self->{group} = undef;         # belt and braces
 261         delete $channels{$self->{call}};
 262 }
 263
 264 # is it a bbs
 265 sub is_bbs
 266 {
 267         my $self = shift;
 268         return $self->{'sort'} eq 'B';
 269 }
 270
 271 sub is_node
 272 {
 273         my $self = shift;
 274         return $self->{'sort'} =~ /[ACRSXW]/;
 275 }
 276 # is it an ak1a node ?
 277 sub is_ak1a
 278 {
 279         my $self = shift;
 280         return $self->{'sort'} eq 'A';
 281 }
 282
 283 # is it a user?
 284 sub is_user
 285 {
 286         my $self = shift;
 287         return $self->{'sort'} eq 'U';
 288 }
 289
 290 # is it a clx node
 291 sub is_clx
 292 {
 293         my $self = shift;
 294         return $self->{'sort'} eq 'C';
 295 }
 296
 297 # it is Aranea
 298 sub is_aranea
 299 {
 300         my $self = shift;
 301         return $self->{'sort'} eq 'W';
 302 }
 303
 304 # is it a spider node
 305 sub is_spider
 306 {
 307         my $self = shift;
 308         return $self->{'sort'} eq 'S';
 309 }
 310
 311 # is it a DXNet node
 312 sub is_dxnet
 313 {
 314         my $self = shift;
 315         return $self->{'sort'} eq 'X';
 316 }
 317
 318 # is it a ar-cluster node
 319 sub is_arcluster
 320 {
 321         my $self = shift;
 322         return $self->{'sort'} eq 'R';
 323 }
 324
 325 # for perl 5.004's benefit
 326 sub sort
 327 {
 328         my $self = shift;
 329         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 330 }
 331
 332 # find out whether we are prepared to believe this callsign on this interface
 333 sub is_believed
 334 {
 335         my $self = shift;
 336         my $call = shift;
 337
 338         return grep $call eq $_, $self->user->believe;
 339 }
 340
 341 # handle out going messages, immediately without waiting for the select to drop
 342 # this could, in theory, block
 343 sub send_now
 344 {
 345         my $self = shift;
 346         my $conn = $self->{conn};
 347         return unless $conn;
 348         my $sort = shift;
 349         my $call = $self->{call};
 350
 351         for (@_) {
 352 #               chomp;
 353         my @lines = split /\n/;
 354                 for (@lines) {
 355                         $conn->send_now("$sort$call|$_");
 356                         # debug log it, but not if it is a log message
 357                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 358                 }
 359         }
 360         $self->{t} = time;
 361 }
 362
 363 #
 364 # send later with letter (more control)
 365 #
 366
 367 sub send_later
 368 {
 369         my $self = shift;
 370         my $conn = $self->{conn};
 371         return unless $conn;
 372         my $sort = shift;
 373         my $call = $self->{call};
 374
 375         for (@_) {
 376 #               chomp;
 377         my @lines = split /\n/;
 378                 for (@lines) {
 379                         $conn->send_later("$sort$call|$_");
 380                         # debug log it, but not if it is a log message
 381                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 382                 }
 383         }
 384         $self->{t} = time;
 385 }
 386
 387 #
 388 # the normal output routine
 389 #
 390 sub send                                                # this is always later and always data
 391 {
 392         my $self = shift;
 393         my $conn = $self->{conn};
 394         return unless $conn;
 395         my $call = $self->{call};
 396
 397         foreach my $l (@_) {
 398                 for (ref $l ? @$l : $l) {
 399                         my @lines = split /\n/;
 400                         for (@lines) {
 401                                 $conn->send_later("D$call|$_");
 402                                 dbg("-> D $call $_") if isdbg('chan');
 403                         }
 404                 }
 405         }
 406         $self->{t} = $main::systime;
 407 }
 408
 409 # send a file (always later)
 410 sub send_file
 411 {
 412         my ($self, $fn) = @_;
 413         my $call = $self->{call};
 414         my $conn = $self->{conn};
 415         my @buf;
 416
 417         open(F, $fn) or die "can't open $fn for sending file ($!)";
 418         @buf = <F>;
 419         close(F);
 420         $self->send(@buf);
 421 }
 422
 423 # this will implement language independence (in time)
 424 sub msg
 425 {
 426         my $self = shift;
 427         return DXM::msg($self->{lang}, @_);
 428 }
 429
 430 # stick a broadcast on the delayed queue (but only up to 20 items)
 431 sub delay
 432 {
 433         my $self = shift;
 434         my $s = shift;
 435
 436         $self->{delayed} = [] unless $self->{delayed};
 437         push @{$self->{delayed}}, $s;
 438         if (@{$self->{delayed}} >= 20) {
 439                 shift @{$self->{delayed}};   # lose oldest one
 440         }
 441 }
 442
 443 # change the state of the channel - lots of scope for debugging here :-)
 444 sub state
 445 {
 446         my $self = shift;
 447         if (@_) {
 448                 $self->{oldstate} = $self->{state};
 449                 $self->{state} = shift;
 450                 $self->{func} = '' unless defined $self->{func};
 451                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 452
 453                 # if there is any queued up broadcasts then splurge them out here
 454                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 455                         $self->send (@{$self->{delayed}});
 456                         delete $self->{delayed};
 457                 }
 458         }
 459         return $self->{state};
 460 }
 461
 462 # disconnect this channel
 463 sub disconnect
 464 {
 465         my $self = shift;
 466         my $user = $self->{user};
 467
 468         $user->close() if defined $user;
 469         $self->{conn}->disconnect;
 470         $self->del();
 471 }
 472
 473 #
 474 # just close all the socket connections down without any fiddling about, cleaning, being
 475 # nice to other processes and otherwise telling them what is going on.
 476 #
 477 # This is for the benefit of forked processes to prepare for starting new programs, they
 478 # don't want or need all this baggage.
 479 #
 480
 481 sub closeall
 482 {
 483         my $ref;
 484         foreach $ref (values %channels) {
 485                 $ref->{conn}->disconnect() if $ref->{conn};
 486         }
 487 }
 488
 489 #
 490 # Tell all the users that we have come in or out (if they want to know)
 491 #
 492 sub tell_login
 493 {
 494         my ($self, $m, $call) = @_;
 495
 496         $call ||= $self->{call};
 497
 498         # send info to all logged in thingies
 499         my @dxchan = get_all_users();
 500         my $dxchan;
 501         foreach $dxchan (@dxchan) {
 502                 next if $dxchan == $self;
 503                 next if $dxchan->{call} eq $main::mycall;
 504                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 505         }
 506 }
 507
 508 #
 509 # Tell all the users if a buddy is logged or out
 510 #
 511 sub tell_buddies
 512 {
 513         my ($self, $m, $call, $node) = @_;
 514
 515         $call ||= $self->{call};
 516         $call =~ s/-\d+$//;
 517         $m .= 'n' if $node;
 518
 519         # send info to all logged in thingies
 520         my @dxchan = get_all_users();
 521         my $dxchan;
 522         foreach $dxchan (@dxchan) {
 523                 next if $dxchan == $self;
 524                 next if $dxchan->{call} eq $main::mycall;
 525                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 526         }
 527 }
 528
 529 # various access routines
 530
 531 #
 532 # return a list of valid elements
 533 #
 534
 535 sub fields
 536 {
 537         return keys(%valid);
 538 }
 539
 540 #
 541 # return a prompt for a field
 542 #
 543
 544 sub field_prompt
 545 {
 546         my ($self, $ele) = @_;
 547         return $valid{$ele};
 548 }
 549
 550 # take a standard input message and decode it into its standard parts
 551 sub decode_input
 552 {
 553         my $dxchan = shift;
 554         my $data = shift;
 555         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 556
 557         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 558
 559         # the above regexp must work
 560         unless (defined $sort && defined $call && defined $line) {
 561 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 562                 dbg("DUFF Line on $chcall: $data");
 563                 return ();
 564         }
 565
 566         if(ref($dxchan) && $call ne $chcall) {
 567                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 568                 return();
 569         }
 570
 571         return ($sort, $call, $line);
 572 }
 573
 574 sub rspfcheck
 575 {
 576         my ($self, $flag, $node, $user) = @_;
 577         my $nref = Route::Node::get($node);
 578         my $dxchan = $nref->dxchan if $nref;
 579         if ($nref && $dxchan) {
 580             if ($dxchan == $self) {
 581                         return 1 unless $user;
 582                         return 1 if $user eq $node;
 583                         my @users = $nref->users;
 584                         return 1 if @users == 0 || grep $user eq $_, @users;
 585                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 586                 } else {
 587                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 588                 }
 589         } else {
 590                 return 1 if $flag;
 591                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 592         }
 593         return 0;
 594 }
 595
 596 # broadcast a message to all clusters taking into account isolation
 597 # [except those mentioned after buffer]
 598 sub broadcast_nodes
 599 {
 600         my $s = shift;                          # the line to be rebroadcast
 601         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 602         my @dxchan = get_all_nodes();
 603         my $dxchan;
 604
 605         # send it if it isn't the except list and isn't isolated and still has a hop count
 606         foreach $dxchan (@dxchan) {
 607                 next if grep $dxchan == $_, @except;
 608                 next if $dxchan == $main::me;
 609
 610                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 611
 612                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 613         }
 614 }
 615
 616 # broadcast a message to all clusters ignoring isolation
 617 # [except those mentioned after buffer]
 618 sub broadcast_all_nodes
 619 {
 620         my $s = shift;                          # the line to be rebroadcast
 621         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 622         my @dxchan = get_all_nodes();
 623         my $dxchan;
 624
 625         # send it if it isn't the except list and isn't isolated and still has a hop count
 626         foreach $dxchan (@dxchan) {
 627                 next if grep $dxchan == $_, @except;
 628                 next if $dxchan == $main::me;
 629
 630                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 631                 $dxchan->send($routeit);
 632         }
 633 }
 634
 635 # broadcast to all users
 636 # storing the spot or whatever until it is in a state to receive it
 637 sub broadcast_users
 638 {
 639         my $s = shift;                          # the line to be rebroadcast
 640         my $sort = shift;           # the type of transmission
 641         my $fref = shift;           # a reference to an object to filter on
 642         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 643         my @dxchan = get_all_users();
 644         my $dxchan;
 645         my @out;
 646
 647         foreach $dxchan (@dxchan) {
 648                 next if grep $dxchan == $_, @except;
 649                 push @out, $dxchan;
 650         }
 651         broadcast_list($s, $sort, $fref, @out);
 652 }
 653
 654
 655 # broadcast to a list of users
 656 sub broadcast_list
 657 {
 658         my $s = shift;
 659         my $sort = shift;
 660         my $fref = shift;
 661         my $dxchan;
 662
 663         foreach $dxchan (@_) {
 664                 my $filter = 1;
 665                 next if $dxchan == $main::me;
 666
 667                 if ($sort eq 'dx') {
 668                     next unless $dxchan->{dx};
 669                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 670                         next unless $filter;
 671                 }
 672                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 673                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 674                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 675                 next if $sort eq 'wx' && !$dxchan->{wx};
 676
 677                 $s =~ s/\a//og unless $dxchan->{beep};
 678
 679                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 680                         $dxchan->send($s);
 681                 } else {
 682                         $dxchan->delay($s);
 683                 }
 684         }
 685 }
 686
 687 sub process
 688 {
 689         foreach my $dxchan (get_all()) {
 690
 691                 while (my $data = shift @{$dxchan->{inqueue}}) {
 692                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 693                         next unless defined $sort;
 694
 695                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 696                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 697                         if ($dxchan->{disconnecting}) {
 698                                 dbg('In disconnection, ignored');
 699                                 next;
 700                         }
 701
 702                         # handle A records
 703                         my $user = $dxchan->user;
 704                         if ($sort eq 'A' || $sort eq 'O') {
 705                                 $dxchan->start($line, $sort);
 706                         } elsif ($sort eq 'I') {
 707                                 die "\$user not defined for $call" if !defined $user;
 708
 709                                 # normal input
 710                                 $dxchan->normal($line);
 711                         } elsif ($sort eq 'Z') {
 712                                 $dxchan->disconnect;
 713                         } elsif ($sort eq 'D') {
 714                                 ;                               # ignored (an echo)
 715                         } elsif ($sort eq 'G') {
 716                                 $dxchan->enhanced($line);
 717                         } else {
 718                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 719                         }
 720                 }
 721         }
 722 }
 723
 724 sub handle_xml
 725 {
 726         my $self = shift;
 727         my $r = 0;
 728
 729         if (DXXml::available()) {
 730                 $r = $self->{handle_xml} || 0;
 731         } else {
 732                 delete $self->{handle_xml} if exists $self->{handle_xml};
 733         }
 734         return $r;
 735 }
 736
 737 #no strict;
 738 sub AUTOLOAD
 739 {
 740         no strict;
 741         my $name = $AUTOLOAD;
 742         return if $name =~ /::DESTROY$/;
 743         $name =~ s/^.*:://o;
 744
 745         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 746
 747         # this clever line of code creates a subroutine which takes over from autoload
 748         # from OO Perl - Conway
 749         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 750         goto &$AUTOLOAD;
 751 }
 752
 753
 754 1;
 755 __END__;