perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   handle_xml => '9,Handles XML,yesno',
 121                   inqueue => '9,Input Queue,parray',
 122                  );
 123
 124 use vars qw($VERSION $BRANCH);
 125 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
 126 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
 127 $main::build += $VERSION;
 128 $main::branch += $BRANCH;
 129
 130 # object destruction
 131 sub DESTROY
 132 {
 133         my $self = shift;
 134         for (keys %$self) {
 135                 if (ref($self->{$_})) {
 136                         delete $self->{$_};
 137                 }
 138         }
 139         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 140         $count--;
 141 }
 142
 143 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 144 sub alloc
 145 {
 146         my ($pkg, $call, $conn, $user) = @_;
 147         my $self = {};
 148
 149         die "trying to create a duplicate channel for $call" if $channels{$call};
 150         $self->{call} = $call;
 151         $self->{priv} = 0;
 152         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 153         if (defined $user) {
 154                 $self->{user} = $user;
 155                 $self->{lang} = $user->lang;
 156                 $user->new_group unless $user->group;
 157                 $user->new_buddies unless $user->buddies;
 158                 $self->{group} = $user->group;
 159                 $self->{sort} = $user->sort;
 160         }
 161         $self->{startt} = $self->{t} = time;
 162         $self->{state} = 0;
 163         $self->{oldstate} = 0;
 164         $self->{lang} = $main::lang if !$self->{lang};
 165         $self->{func} = "";
 166
 167         # add in all the dxcc, itu, zone info
 168         my @dxcc = Prefix::extract($call);
 169         if (@dxcc > 0) {
 170                 $self->{dxcc} = $dxcc[1]->dxcc;
 171                 $self->{itu} = $dxcc[1]->itu;
 172                 $self->{cq} = $dxcc[1]->cq;
 173         }
 174         $self->{inqueue} = [];
 175
 176         $count++;
 177         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 178         bless $self, $pkg;
 179         return $channels{$call} = $self;
 180 }
 181
 182 # rebless this channel as something else
 183 sub rebless
 184 {
 185         my $self = shift;
 186         my $class = shift;
 187         return $channels{$self->{call}} = bless $self, $class;
 188 }
 189
 190 sub rec
 191 {
 192         my ($self, $msg) = @_;
 193
 194         # queue the message and the channel object for later processing
 195         if (defined $msg) {
 196                 push @{$self->{inqueue}}, $msg;
 197         }
 198 }
 199
 200 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 201 sub get
 202 {
 203         my $call = shift;
 204         return $channels{$call};
 205 }
 206
 207 # obtain all the channel objects
 208 sub get_all
 209 {
 210         return values(%channels);
 211 }
 212
 213 #
 214 # gimme all the ak1a nodes
 215 #
 216 sub get_all_nodes
 217 {
 218         my $ref;
 219         my @out;
 220         foreach $ref (values %channels) {
 221                 push @out, $ref if $ref->is_node;
 222         }
 223         return @out;
 224 }
 225
 226 # return a list of all users
 227 sub get_all_users
 228 {
 229         my $ref;
 230         my @out;
 231         foreach $ref (values %channels) {
 232                 push @out, $ref if $ref->is_user;
 233         }
 234         return @out;
 235 }
 236
 237 # return a list of all user callsigns
 238 sub get_all_user_calls
 239 {
 240         my $ref;
 241         my @out;
 242         foreach $ref (values %channels) {
 243                 push @out, $ref->{call} if $ref->is_user;
 244         }
 245         return @out;
 246 }
 247
 248 # obtain a channel object by searching for its connection reference
 249 sub get_by_cnum
 250 {
 251         my ($pkg, $conn) = @_;
 252         my $self;
 253
 254         foreach $self (values(%channels)) {
 255                 return $self if ($self->{conn} == $conn);
 256         }
 257         return undef;
 258 }
 259
 260 # get rid of a channel object [$obj->del()]
 261 sub del
 262 {
 263         my $self = shift;
 264
 265         $self->{group} = undef;         # belt and braces
 266         delete $channels{$self->{call}};
 267 }
 268
 269 # is it a bbs
 270 sub is_bbs
 271 {
 272         my $self = shift;
 273         return $self->{'sort'} eq 'B';
 274 }
 275
 276 sub is_node
 277 {
 278         my $self = shift;
 279         return $self->{'sort'} =~ /[ACRSXW]/;
 280 }
 281 # is it an ak1a node ?
 282 sub is_ak1a
 283 {
 284         my $self = shift;
 285         return $self->{'sort'} eq 'A';
 286 }
 287
 288 # is it a user?
 289 sub is_user
 290 {
 291         my $self = shift;
 292         return $self->{'sort'} eq 'U';
 293 }
 294
 295 # is it a clx node
 296 sub is_clx
 297 {
 298         my $self = shift;
 299         return $self->{'sort'} eq 'C';
 300 }
 301
 302 # it is Aranea
 303 sub is_aranea
 304 {
 305         my $self = shift;
 306         return $self->{'sort'} eq 'W';
 307 }
 308
 309 # is it a spider node
 310 sub is_spider
 311 {
 312         my $self = shift;
 313         return $self->{'sort'} eq 'S';
 314 }
 315
 316 # is it a DXNet node
 317 sub is_dxnet
 318 {
 319         my $self = shift;
 320         return $self->{'sort'} eq 'X';
 321 }
 322
 323 # is it a ar-cluster node
 324 sub is_arcluster
 325 {
 326         my $self = shift;
 327         return $self->{'sort'} eq 'R';
 328 }
 329
 330 # for perl 5.004's benefit
 331 sub sort
 332 {
 333         my $self = shift;
 334         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 335 }
 336
 337 # find out whether we are prepared to believe this callsign on this interface
 338 sub is_believed
 339 {
 340         my $self = shift;
 341         my $call = shift;
 342
 343         return grep $call eq $_, $self->user->believe;
 344 }
 345
 346 # handle out going messages, immediately without waiting for the select to drop
 347 # this could, in theory, block
 348 sub send_now
 349 {
 350         my $self = shift;
 351         my $conn = $self->{conn};
 352         return unless $conn;
 353         my $sort = shift;
 354         my $call = $self->{call};
 355
 356         for (@_) {
 357 #               chomp;
 358         my @lines = split /\n/;
 359                 for (@lines) {
 360                         $conn->send_now("$sort$call|$_");
 361                         dbg("-> $sort $call $_") if isdbg('chan');
 362                 }
 363         }
 364         $self->{t} = time;
 365 }
 366
 367 #
 368 # send later with letter (more control)
 369 #
 370
 371 sub send_later
 372 {
 373         my $self = shift;
 374         my $conn = $self->{conn};
 375         return unless $conn;
 376         my $sort = shift;
 377         my $call = $self->{call};
 378
 379         for (@_) {
 380 #               chomp;
 381         my @lines = split /\n/;
 382                 for (@lines) {
 383                         $conn->send_later("$sort$call|$_");
 384                         dbg("-> $sort $call $_") if isdbg('chan');
 385                 }
 386         }
 387         $self->{t} = time;
 388 }
 389
 390 #
 391 # the normal output routine
 392 #
 393 sub send                                                # this is always later and always data
 394 {
 395         my $self = shift;
 396         my $conn = $self->{conn};
 397         return unless $conn;
 398         my $call = $self->{call};
 399
 400         foreach my $l (@_) {
 401                 for (ref $l ? @$l : $l) {
 402                         my @lines = split /\n/;
 403                         for (@lines) {
 404                                 $conn->send_later("D$call|$_");
 405                                 dbg("-> D $call $_") if isdbg('chan');
 406                         }
 407                 }
 408         }
 409         $self->{t} = $main::systime;
 410 }
 411
 412 # send a file (always later)
 413 sub send_file
 414 {
 415         my ($self, $fn) = @_;
 416         my $call = $self->{call};
 417         my $conn = $self->{conn};
 418         my @buf;
 419
 420         open(F, $fn) or die "can't open $fn for sending file ($!)";
 421         @buf = <F>;
 422         close(F);
 423         $self->send(@buf);
 424 }
 425
 426 # this will implement language independence (in time)
 427 sub msg
 428 {
 429         my $self = shift;
 430         return DXM::msg($self->{lang}, @_);
 431 }
 432
 433 # stick a broadcast on the delayed queue (but only up to 20 items)
 434 sub delay
 435 {
 436         my $self = shift;
 437         my $s = shift;
 438
 439         $self->{delayed} = [] unless $self->{delayed};
 440         push @{$self->{delayed}}, $s;
 441         if (@{$self->{delayed}} >= 20) {
 442                 shift @{$self->{delayed}};   # lose oldest one
 443         }
 444 }
 445
 446 # change the state of the channel - lots of scope for debugging here :-)
 447 sub state
 448 {
 449         my $self = shift;
 450         if (@_) {
 451                 $self->{oldstate} = $self->{state};
 452                 $self->{state} = shift;
 453                 $self->{func} = '' unless defined $self->{func};
 454                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 455
 456                 # if there is any queued up broadcasts then splurge them out here
 457                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 458                         $self->send (@{$self->{delayed}});
 459                         delete $self->{delayed};
 460                 }
 461         }
 462         return $self->{state};
 463 }
 464
 465 # disconnect this channel
 466 sub disconnect
 467 {
 468         my $self = shift;
 469         my $user = $self->{user};
 470
 471         $user->close() if defined $user;
 472         $self->{conn}->disconnect;
 473         $self->del();
 474 }
 475
 476 #
 477 # just close all the socket connections down without any fiddling about, cleaning, being
 478 # nice to other processes and otherwise telling them what is going on.
 479 #
 480 # This is for the benefit of forked processes to prepare for starting new programs, they
 481 # don't want or need all this baggage.
 482 #
 483
 484 sub closeall
 485 {
 486         my $ref;
 487         foreach $ref (values %channels) {
 488                 $ref->{conn}->disconnect() if $ref->{conn};
 489         }
 490 }
 491
 492 #
 493 # Tell all the users that we have come in or out (if they want to know)
 494 #
 495 sub tell_login
 496 {
 497         my ($self, $m, $call) = @_;
 498
 499         $call ||= $self->{call};
 500
 501         # send info to all logged in thingies
 502         my @dxchan = get_all_users();
 503         my $dxchan;
 504         foreach $dxchan (@dxchan) {
 505                 next if $dxchan == $self;
 506                 next if $dxchan->{call} eq $main::mycall;
 507                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 508         }
 509 }
 510
 511 #
 512 # Tell all the users if a buddy is logged or out
 513 #
 514 sub tell_buddies
 515 {
 516         my ($self, $m, $call, $node) = @_;
 517
 518         $call ||= $self->{call};
 519         $call =~ s/-\d+$//;
 520         $m .= 'n' if $node;
 521
 522         # send info to all logged in thingies
 523         my @dxchan = get_all_users();
 524         my $dxchan;
 525         foreach $dxchan (@dxchan) {
 526                 next if $dxchan == $self;
 527                 next if $dxchan->{call} eq $main::mycall;
 528                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 529         }
 530 }
 531
 532 # various access routines
 533
 534 #
 535 # return a list of valid elements
 536 #
 537
 538 sub fields
 539 {
 540         return keys(%valid);
 541 }
 542
 543 #
 544 # return a prompt for a field
 545 #
 546
 547 sub field_prompt
 548 {
 549         my ($self, $ele) = @_;
 550         return $valid{$ele};
 551 }
 552
 553 # take a standard input message and decode it into its standard parts
 554 sub decode_input
 555 {
 556         my $dxchan = shift;
 557         my $data = shift;
 558         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 559
 560         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 561
 562         # the above regexp must work
 563         unless (defined $sort && defined $call && defined $line) {
 564 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 565                 dbg("DUFF Line on $chcall: $data");
 566                 return ();
 567         }
 568
 569         if(ref($dxchan) && $call ne $chcall) {
 570                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 571                 return();
 572         }
 573
 574         return ($sort, $call, $line);
 575 }
 576
 577 sub rspfcheck
 578 {
 579         my ($self, $flag, $node, $user) = @_;
 580         my $nref = Route::Node::get($node);
 581         my $dxchan = $nref->dxchan if $nref;
 582         if ($nref && $dxchan) {
 583             if ($dxchan == $self) {
 584                         return 1 unless $user;
 585                         return 1 if $user eq $node;
 586                         my @users = $nref->users;
 587                         return 1 if @users == 0 || grep $user eq $_, @users;
 588                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 589                 } else {
 590                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 591                 }
 592         } else {
 593                 return 1 if $flag;
 594                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 595         }
 596         return 0;
 597 }
 598
 599 # broadcast a message to all clusters taking into account isolation
 600 # [except those mentioned after buffer]
 601 sub broadcast_nodes
 602 {
 603         my $s = shift;                          # the line to be rebroadcast
 604         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 605         my @dxchan = get_all_nodes();
 606         my $dxchan;
 607
 608         # send it if it isn't the except list and isn't isolated and still has a hop count
 609         foreach $dxchan (@dxchan) {
 610                 next if grep $dxchan == $_, @except;
 611                 next if $dxchan == $main::me;
 612
 613                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 614
 615                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 616         }
 617 }
 618
 619 # broadcast a message to all clusters ignoring isolation
 620 # [except those mentioned after buffer]
 621 sub broadcast_all_nodes
 622 {
 623         my $s = shift;                          # the line to be rebroadcast
 624         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 625         my @dxchan = get_all_nodes();
 626         my $dxchan;
 627
 628         # send it if it isn't the except list and isn't isolated and still has a hop count
 629         foreach $dxchan (@dxchan) {
 630                 next if grep $dxchan == $_, @except;
 631                 next if $dxchan == $main::me;
 632
 633                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 634                 $dxchan->send($routeit);
 635         }
 636 }
 637
 638 # broadcast to all users
 639 # storing the spot or whatever until it is in a state to receive it
 640 sub broadcast_users
 641 {
 642         my $s = shift;                          # the line to be rebroadcast
 643         my $sort = shift;           # the type of transmission
 644         my $fref = shift;           # a reference to an object to filter on
 645         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 646         my @dxchan = get_all_users();
 647         my $dxchan;
 648         my @out;
 649
 650         foreach $dxchan (@dxchan) {
 651                 next if grep $dxchan == $_, @except;
 652                 push @out, $dxchan;
 653         }
 654         broadcast_list($s, $sort, $fref, @out);
 655 }
 656
 657
 658 # broadcast to a list of users
 659 sub broadcast_list
 660 {
 661         my $s = shift;
 662         my $sort = shift;
 663         my $fref = shift;
 664         my $dxchan;
 665
 666         foreach $dxchan (@_) {
 667                 my $filter = 1;
 668                 next if $dxchan == $main::me;
 669
 670                 if ($sort eq 'dx') {
 671                     next unless $dxchan->{dx};
 672                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 673                         next unless $filter;
 674                 }
 675                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 676                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 677                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 678                 next if $sort eq 'wx' && !$dxchan->{wx};
 679
 680                 $s =~ s/\a//og unless $dxchan->{beep};
 681
 682                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 683                         $dxchan->send($s);
 684                 } else {
 685                         $dxchan->delay($s);
 686                 }
 687         }
 688 }
 689
 690 sub process
 691 {
 692         foreach my $dxchan (get_all()) {
 693
 694                 while (my $data = shift @{$dxchan->{inqueue}}) {
 695                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 696                         next unless defined $sort;
 697
 698                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 699                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 700                         if ($dxchan->{disconnecting}) {
 701                                 dbg('In disconnection, ignored');
 702                                 next;
 703                         }
 704
 705                         # handle A records
 706                         my $user = $dxchan->user;
 707                         if ($sort eq 'A' || $sort eq 'O') {
 708                                 $dxchan->start($line, $sort);
 709                         } elsif ($sort eq 'I') {
 710                                 die "\$user not defined for $call" if !defined $user;
 711
 712                                 # normal input
 713                                 $dxchan->normal($line);
 714                         } elsif ($sort eq 'Z') {
 715                                 $dxchan->disconnect;
 716                         } elsif ($sort eq 'D') {
 717                                 ;                               # ignored (an echo)
 718                         } elsif ($sort eq 'G') {
 719                                 $dxchan->enhanced($line);
 720                         } else {
 721                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 722                         }
 723                 }
 724         }
 725 }
 726
 727 #no strict;
 728 sub AUTOLOAD
 729 {
 730         no strict;
 731         my $name = $AUTOLOAD;
 732         return if $name =~ /::DESTROY$/;
 733         $name =~ s/^.*:://o;
 734
 735         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 736
 737         # this clever line of code creates a subroutine which takes over from autoload
 738         # from OO Perl - Conway
 739         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 740         goto &$AUTOLOAD;
 741 }
 742
 743
 744 1;
 745 __END__;