+# enter the spot for dup checking and return true if it is already a dup
+sub dup
+{
+ my ($freq, $call, $d, $text, $by, $node, $just_find) = @_;
+
+ dbg("Spot::dup: freq=$freq call=$call d=$d text='$text' by=$by node=$node" . ($just_find ? " jf=$just_find" : "")) if isdbg('spotdup');
+
+ # dump if too old
+ return 2 if $d < $main::systime - $dupage;
+
+ # turn the time into minutes (should be already but...)
+ $d = int ($d / 60);
+ $d *= 60;
+
+ my $nd = nearest($timegranularity, $d);
+
+ # remove SSID or area
+ $by =~ s|[-/]\d+$||;
+
+# $freq = sprintf "%.1f", $freq; # normalise frequency
+ $freq = int $freq; # normalise frequency
+
+ my $qrg = nearest($qrggranularity, $freq); # to the nearest however many hz
+
+ $call = substr($call, 0, $maxcalllth) if length $call > $maxcalllth;
+
+ my $dtext ;
+
+ my $l = length $text;
+ $dtext = qq{original:'$text'($l)} if isdbg('spottext');
+
+ chomp $text;
+
+ $text =~ s/\%([0-9A-F][0-9A-F])/chr(hex($1))/eg;
+ $text = uc unpad($text);
+
+ $l = length $text;
+ $dtext .= qq{->afterhex: '$text'($l)} if isdbg('spottext');
+ my @dubious;
+ if (isdbg('spottext')) {
+ (@dubious) = $text =~ /([?\x00-\x08\x0a-\x1F\x7B-\xFF]+)+/;
+ $dtext .= sprintf q{DUBIOUS '%s'}, join '', @dubious if @dubious;
+ }
+
+ my $otext = $text;
+# $text = Encode::encode("iso-8859-1", $text) if $main::can_encode && Encode::is_utf8($text, 1);
+ $text =~ s/^\+\w+\s*//; # remove leading LoTW callsign
+ $text =~ s/\s{2,}[\dA-Z]?[A-Z]\d?$//g if length $text > 24;
+ $text =~ s/\x09+//g;
+ $text =~ s/[\W\x00-\x2F\x7B-\xFF]//g; # tautology, just to make quite sure!
+ $text = substr($text, 0, $duplth) if length $text > $duplth;
+
+ $l = length $text;
+ $dtext .= qq{->final:'$text'($l)} if isdbg('spottext');
+
+ my $t = 0;
+ my $ldupkey;
+
+ # new feature: don't include the origin node in Spot dupes
+ # default = true
+ unless ($no_node_in_dupe) {
+ $ldupkey = $oldstyle ? "X|$call|$by|$node|$freq|$d|$text" : "X|$call|$by|$node|$qrg|$nd|$text";
+
+ $t = DXDupe::find($ldupkey);
+ dbg("Spot::dup ldupkey $ldupkey t '$t'") if isdbg('spotdup');
+ $dtext .= ' DUPE' if $t;
+ dbg("text transforms: $dtext") if length $text && isdbg('spottext');
+ return 1 if $t > 0;
+
+ DXDupe::add($ldupkey, $main::systime+$dupage) unless $just_find;
+ }
+
+ $otext = substr($otext, 0, $duplth) if length $otext > $duplth;
+ $otext =~ s/\s+$//;
+ if (length $otext && $otext ne $text) {
+ $ldupkey = $oldstyle ? "X|$freq|$call|$by|$otext" : "X|$qrg|$call|$by|$otext";
+ $t = DXDupe::find($ldupkey);
+ dbg("Spot::dup (OTEXT) ldupkey $ldupkey t '$t'") if isdbg('spotdup');
+ if (isdbg('spottext')) {
+ $dtext .= sprintf q{ DUBIOUS '%s'}, join '', @dubious if @dubious;
+ $dtext .= ' DUPE (OTEXT)' if $t;
+ dbg("text transforms: $dtext") if length $text;
+ }
+ return 1 if $t > 0;
+ DXDupe::add($ldupkey, $main::systime+$dupage) unless $just_find;
+ }
+ return undef;
+}
+
+sub dup_find
+{
+ return dup(@_, 1);
+}
+
+sub listdups
+{
+ return DXDupe::listdups('X', $dupage, @_);
+}
+
+sub genstats
+{
+ my $date = shift;
+ my $in = $fp->open($date) or dbg("Spot::genstats: Cannot open " . $fp->fn($date) . " $!");
+ my $out = $statp->open($date, 'w') or dbg("Spot::genstats: Cannot open " . $statp->fn($date) . " $!");
+ my @freq;
+ my %list;
+ my @tot;
+
+ if ($in && $out) {
+ my $i = 0;
+ @freq = map {[$i++, Bands::get_freq($_)]} qw(136khz 160m 80m 60m 40m 30m 20m 17m 15m 12m 10m 6m 4m 2m 220 70cm 23cm 13cm 9cm 6cm 3cm 12mm 6mm);
+ while (<$in>) {
+ chomp;
+ my ($freq, $by, $dxcc) = (split /\^/)[0,4,6];
+ my $ref = $list{$by} || [0, $dxcc];
+ for (@freq) {
+ next unless defined $_;
+ if ($freq >= $_->[1] && $freq <= $_->[2]) {
+ $$ref[$_->[0]+2]++;
+ $tot[$_->[0]+2]++;
+ $$ref[0]++;
+ $tot[0]++;
+ $list{$by} = $ref;
+ last;
+ }
+ }
+ }
+
+ for ($i = 0; $i < @freq+2; $i++) {
+ $tot[$i] ||= 0;
+ }
+ $statp->write($date, join('^', 'TOTALS', @tot));
+
+ for (sort {$list{$b}->[0] <=> $list{$a}->[0]} keys %list) {
+ my $ref = $list{$_};
+ my $call = $_;
+ for ($i = 0; $i < @freq+2; ++$i) {
+ $ref->[$i] ||= 0;
+ }
+ $statp->write($date, join('^', $call, @$ref));
+ }
+ $statp->close;
+ }
+}
+
+# return true if the stat file is newer than than the spot file
+sub checkstats
+{
+ my $date = shift;
+ my $in = $fp->mtime($date);
+ my $out = $statp->mtime($date);
+ return defined $out && defined $in && $out >= $in;
+}
+
+# daily processing
+sub daily
+{
+ my $date = Julian::Day->new($main::systime)->sub(1);
+ genstats($date) unless checkstats($date);
+ clean_cache();
+}
+
+sub _cachek
+{
+ return "$_[0]->[0]|$_[0]->[1]";
+}
+
+sub clean_cache
+{
+ if ($spotcachedays > 0) {
+ my $now = Julian::Day->new($main::systime);
+ for (my $i = $spotcachedays; $i < $spotcachedays + 5; ++$i ) {
+ my $k = _cachek($now->sub($i));
+ if (exists $spotcache{$k}) {
+ dbg("Spot::spotcache deleting day $k, more than $spotcachedays days old");
+ delete $spotcache{$k};
+ }
+ }
+ }
+}