perl/Route.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the abstracted routing for all protocols and
   4 # is probably what I SHOULD have done the first time.
   5 #
   6 # Heyho.
   7 #
   8 # This is just a container class which I expect to subclass
   9 #
  10 # Copyright (c) 2001 Dirk Koopman G1TLH
  11 #
  12 # $Id$
  13 #
  14
  15 package Route;
  16
  17 use DXDebug;
  18 use DXChannel;
  19 use Prefix;
  20
  21 use strict;
  22
  23
  24 use vars qw($VERSION $BRANCH);
  25 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  26 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  27 $main::build += $VERSION;
  28 $main::branch += $BRANCH;
  29
  30 use vars qw(%list %valid $filterdef);
  31
  32 %valid = (
  33                   call => "0,Callsign",
  34                   flags => "0,Flags,phex",
  35                   dxcc => '0,Country Code',
  36                   itu => '0,ITU Zone',
  37                   cq => '0,CQ Zone',
  38                   state => '0,State',
  39                   city => '0,City',
  40                   lastseen => '0,Last Seen,atime',
  41                  );
  42
  43 $filterdef = bless ([
  44                           # tag, sort, field, priv, special parser
  45                           ['channel', 'c', 0],
  46                           ['channel_dxcc', 'nc', 1],
  47                           ['channel_itu', 'ni', 2],
  48                           ['channel_zone', 'nz', 3],
  49                           ['call', 'c', 4],
  50                           ['by', 'c', 4],
  51                           ['call_dxcc', 'nc', 5],
  52                           ['by_dxcc', 'nc', 5],
  53                           ['call_itu', 'ni', 6],
  54                           ['by_itu', 'ni', 6],
  55                           ['call_zone', 'nz', 7],
  56                           ['by_zone', 'nz', 7],
  57                           ['channel_state', 'ns', 8],
  58                           ['call_state', 'ns', 9],
  59                           ['by_state', 'ns', 9],
  60                          ], 'Filter::Cmd');
  61
  62
  63 sub new
  64 {
  65         my ($pkg, $call) = @_;
  66         $pkg = ref $pkg if ref $pkg;
  67
  68         my $self = bless {call => $call}, $pkg;
  69         dbg("create $pkg with $call") if isdbg('routelow');
  70
  71         # add in all the dxcc, itu, zone info
  72         ($self->{dxcc}, $self->{itu}, $self->{cq}, $self->{state}, $self->{city}) =
  73                 Prefix::cty_data($call);
  74
  75         $self->{flags} = here(1);
  76
  77         return $self;
  78 }
  79
  80 #
  81 # get a callsign from a passed reference or a string
  82 #
  83
  84 sub _getcall
  85 {
  86         my $self = shift;
  87         my $thingy = shift;
  88         $thingy = $self unless $thingy;
  89         $thingy = $thingy->call if ref $thingy;
  90         $thingy = uc $thingy if $thingy;
  91         return $thingy;
  92 }
  93
  94 #
  95 # add and delete a callsign to/from a list
  96 #
  97
  98 sub _addlist
  99 {
 100         my $self = shift;
 101         my $field = shift;
 102         my @out;
 103         foreach my $c (@_) {
 104                 confess "Need a ref here" unless ref($c);
 105
 106                 my $call = $c->{call};
 107                 unless (grep $_ eq $call, @{$self->{$field}}) {
 108                         push @{$self->{$field}}, $call;
 109                         dbg(ref($self) . " adding $call to " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 110                         push @out, $c;
 111                 }
 112         }
 113         return @out;
 114 }
 115
 116 sub _dellist
 117 {
 118         my $self = shift;
 119         my $field = shift;
 120         my @out;
 121         foreach my $c (@_) {
 122                 confess "Need a ref here" unless ref($c);
 123                 my $call = $c->{call};
 124                 if (grep $_ eq $call, @{$self->{$field}}) {
 125                         $self->{$field} = [ grep {$_ ne $call} @{$self->{$field}} ];
 126                         dbg(ref($self) . " deleting $call from " . $self->{call} . "->\{$field\}") if isdbg('routelow');
 127                         push @out, $c;
 128                 }
 129         }
 130         return @out;
 131 }
 132
 133 sub is_empty
 134 {
 135         my $self = shift;
 136         return @{$self->{$_[0]}} == 0;
 137 }
 138
 139 #
 140 # flag field constructors/enquirers
 141 #
 142 # These can be called in various ways:-
 143 #
 144 # Route::here or $ref->here returns 1 or 0 depending on value of the here flag
 145 # Route::here(1) returns 2 (the bit value of the here flag)
 146 # $ref->here(1) or $ref->here(0) sets the here flag
 147 #
 148
 149 sub here
 150 {
 151         my $self = shift;
 152         my $r = shift;
 153         return $self ? 2 : 0 unless ref $self;
 154         return ($self->{flags} & 2) ? 1 : 0 unless defined $r;
 155         $self->{flags} &= ~2;
 156         $self->{flags} |= $r ? 2 : 0;
 157         return $r ? 1 : 0;
 158 }
 159
 160 sub conf
 161 {
 162         my $self = shift;
 163         my $r = shift;
 164         return $self ? 1 : 0 unless ref $self;
 165         return ($self->{flags} & 1) ? 1 : 0 unless defined $r;
 166         $self->{flags} &= ~1;
 167         $self->{flags} |= $r ? 1 : 0;
 168         return $r ? 1 : 0;
 169 }
 170
 171 #
 172 # display routines
 173 #
 174
 175 sub user_call
 176 {
 177         my $self = shift;
 178         my $call = sprintf "%s", $self->{call};
 179         return $self->here ? "$call" : "($call)";
 180 }
 181
 182 sub config
 183 {
 184         my $self = shift;
 185         my $nodes_only = shift;
 186         my $level = shift;
 187         my $seen = shift;
 188         my @out;
 189         my $line;
 190         my $call = $self->user_call;
 191         my $printit = 1;
 192
 193         # allow ranges
 194         if (@_) {
 195                 $printit = grep $call =~ m|$_|, @_;
 196         }
 197
 198         if ($printit) {
 199                 $line = ' ' x ($level*2) . "$call";
 200                 $call = ' ' x length $call;
 201
 202                 # recursion detector
 203                 if ((DXChannel->get($self->{call}) && $level > 1) || grep $self->{call} eq $_, @$seen) {
 204 #                       $line .= ' ...';
 205 #                       push @out, $line;
 206                         return @out;
 207                 }
 208                 push @$seen, $self->{call};
 209
 210                 # print users
 211                 unless ($nodes_only) {
 212                         if (@{$self->{users}}) {
 213                                 $line .= '->';
 214                                 foreach my $ucall (sort @{$self->{users}}) {
 215                                         my $uref = Route::User::get($ucall);
 216                                         my $c;
 217                                         if ($uref) {
 218                                                 $c = $uref->user_call;
 219                                         } else {
 220                                                 $c = "$ucall?";
 221                                         }
 222                                         if ((length $line) + (length $c) + 1 < 79) {
 223                                                 $line .= $c . ' ';
 224                                         } else {
 225                                                 $line =~ s/\s+$//;
 226                                                 push @out, $line;
 227                                                 $line = ' ' x ($level*2) . "$call->$c ";
 228                                         }
 229                                 }
 230                         }
 231                 }
 232                 $line =~ s/->$//g;
 233                 $line =~ s/\s+$//;
 234                 push @out, $line if length $line;
 235         }
 236
 237         # deal with more nodes
 238         foreach my $ncall (sort @{$self->{nodes}}) {
 239                 my $nref = Route::Node::get($ncall);
 240
 241                 if ($nref) {
 242                         my $c = $nref->user_call;
 243 #                       dbg("recursing from $call -> $c") if isdbg('routec');
 244                         push @out, $nref->config($nodes_only, $level+1, $seen, @_);
 245                 } else {
 246                         push @out, ' ' x (($level+1)*2)  . "$ncall?" if @_ == 0 || (@_ && grep $ncall =~ m|$_|, @_);
 247                 }
 248         }
 249
 250         return @out;
 251 }
 252
 253 sub cluster
 254 {
 255         my $nodes = Route::Node::count();
 256         my $tot = Route::User::count();
 257         my $users = scalar DXCommandmode::get_all();
 258         my $maxusers = Route::User::max();
 259         my $uptime = main::uptime();
 260
 261         return " $nodes nodes, $users local / $tot total users  Max users $maxusers  Uptime $uptime";
 262 }
 263
 264 #
 265 # routing things
 266 #
 267
 268 sub get
 269 {
 270         my $call = shift;
 271         return Route::Node::get($call) || Route::User::get($call);
 272 }
 273
 274 sub get_all
 275 {
 276         return (Route::Node::get_all(), Route::User::get_all());
 277 }
 278
 279 # find all the possible dxchannels which this object might be on
 280 sub alldxchan
 281 {
 282         my $self = shift;
 283
 284         my $dxchan = DXChannel->get($self->{call});
 285         if ($dxchan) {
 286                 dbg("alldxchan for $self->{call} = $dxchan->{call}") if isdbg('routelow');
 287                 return $dxchan if $dxchan;
 288         }
 289
 290         my @nodes;
 291         if ($self->isa('Route::User')) {
 292                 push @nodes, map{Route::Node::get($_)} @{$self->{nodes}};
 293         } elsif ($self->isa('Route::Node')) {
 294                 push @nodes, $self;
 295         }
 296
 297         # it isn't, build up a list of dxchannels and possible ping times
 298         # for all the candidates.
 299         my @dxchan;
 300         foreach my $nref (@nodes) {
 301                 next unless $nref;
 302                 foreach my $p (@{$nref->{dxchan}}) {
 303 #                       dbg("Trying dxchan $p") if isdbg('routech');
 304                         next if $p eq $main::mycall; # the root
 305                         my $dxchan = DXChannel->get($p);
 306                         if ($dxchan) {
 307                                 push @dxchan, $dxchan unless grep $dxchan == $_, @dxchan;
 308                         } else {
 309                                 next if grep $p eq $_, @_;
 310                                 my $ref = Route::Node::get($p);
 311 #                               dbg("Next node $p " . ($ref ? 'Found' : 'NOT Found') if isdbg('routech') );
 312                                 push @dxchan, $ref->alldxchan($self->{call}, @_) if $ref;
 313                         }
 314                 }
 315         }
 316         dbg("alldxchan for $self->{call} = (" . join(',', @dxchan) . ")") if isdbg('routelow');
 317         return @dxchan;
 318 }
 319
 320 sub bestdxchan
 321 {
 322         my $self = shift;
 323
 324         # ALWAYS return the locally connected channel if present;
 325         my $dxchan = DXChannel->get($self->call);
 326         return $dxchan if $dxchan;
 327
 328         my @dxchan = sort { ($a->pingave || 9999999) <=> ($b->pingave || 9999999) } $self->alldxchan;
 329         return undef unless @dxchan;
 330
 331         return shift @dxchan;
 332 }
 333
 334 #
 335 # track destruction
 336 #
 337
 338 sub DESTROY
 339 {
 340         my $self = shift;
 341         my $pkg = ref $self;
 342
 343         dbg("$pkg $self->{call} destroyed") if isdbg('routelow');
 344 }
 345
 346 no strict;
 347 #
 348 # return a list of valid elements
 349 #
 350
 351 sub fields
 352 {
 353         my $pkg = shift;
 354         $pkg = ref $pkg if ref $pkg;
 355     my $val = "${pkg}::valid";
 356         my @out = keys %$val;
 357         push @out, keys %valid;
 358         return @out;
 359 }
 360
 361 #
 362 # return a prompt for a field
 363 #
 364
 365 sub field_prompt
 366 {
 367         my ($self, $ele) = @_;
 368         my $pkg = ref $self;
 369     my $val = "${pkg}::valid";
 370         return $val->{$ele} || $valid{$ele};
 371 }
 372
 373 #
 374 # generic AUTOLOAD for accessors
 375 #
 376 sub AUTOLOAD
 377 {
 378         no strict;
 379         my $name = $AUTOLOAD;
 380         return if $name =~ /::DESTROY$/;
 381         $name =~ s/^.*:://o;
 382
 383         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 384
 385         # this clever line of code creates a subroutine which takes over from autoload
 386         # from OO Perl - Conway
 387         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 388        goto &$AUTOLOAD;
 389
 390 }
 391
 392 1;