perl/DXUser.pm

   1 #
   2 # DX cluster user routines
   3 #
   4 # Copyright (c) 1998 - Dirk Koopman G1TLH
   5 #
   6 # $Id$
   7 #
   8
   9 package DXUser;
  10
  11 use DXLog;
  12 use DB_File;
  13 use Data::Dumper;
  14 use Fcntl;
  15 use IO::File;
  16 use DXDebug;
  17 use DXUtil;
  18 use LRU;
  19
  20 use strict;
  21
  22 use vars qw($VERSION $BRANCH);
  23 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  24 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  25 $main::build += $VERSION;
  26 $main::branch += $BRANCH;
  27
  28 use vars qw(%u $dbm $filename %valid $lastoperinterval $lasttime $lru $lrusize $tooold $v3);
  29
  30 %u = ();
  31 $dbm = undef;
  32 $filename = undef;
  33 $lastoperinterval = 60*24*60*60;
  34 $lasttime = 0;
  35 $lrusize = 2000;
  36 $tooold = 86400 * 365;          # this marks an old user who hasn't given enough info to be useful
  37 $v3 = 0;
  38
  39 # hash of valid elements and a simple prompt
  40 %valid = (
  41                   call => '0,Callsign',
  42                   alias => '0,Real Callsign',
  43                   name => '0,Name',
  44                   qth => '0,Home QTH',
  45                   lat => '0,Latitude,slat',
  46                   long => '0,Longitude,slong',
  47                   qra => '0,Locator',
  48                   email => '0,E-mail Address,parray',
  49                   priv => '9,Privilege Level',
  50                   lastin => '0,Last Time in,cldatetime',
  51                   passwd => '9,Password,yesno',
  52                   passphrase => '9,Pass Phrase,yesno',
  53                   addr => '0,Full Address',
  54                   'sort' => '0,Type of User', # A - ak1a, U - User, S - spider cluster, B - BBS
  55                   xpert => '0,Expert Status,yesno',
  56                   bbs => '0,Home BBS',
  57                   node => '0,Last Node',
  58                   homenode => '0,Home Node',
  59                   lockout => '9,Locked out?,yesno',     # won't let them in at all
  60                   dxok => '9,Accept DX Spots?,yesno', # accept his dx spots?
  61                   annok => '9,Accept Announces?,yesno', # accept his announces?
  62                   lang => '0,Language',
  63                   hmsgno => '0,Highest Msgno',
  64                   group => '0,Chat Group,parray',       # used to create a group of users/nodes for some purpose or other
  65                   isolate => '9,Isolate network,yesno',
  66                   wantbeep => '0,Req Beep,yesno',
  67                   wantann => '0,Req Announce,yesno',
  68                   wantwwv => '0,Req WWV,yesno',
  69                   wantwcy => '0,Req WCY,yesno',
  70                   wantecho => '0,Req Echo,yesno',
  71                   wanttalk => '0,Req Talk,yesno',
  72                   wantwx => '0,Req WX,yesno',
  73                   wantdx => '0,Req DX Spots,yesno',
  74                   wantemail => '0,Req Msgs as Email,yesno',
  75                   pagelth => '0,Current Pagelth',
  76                   pingint => '9,Node Ping interval',
  77                   nopings => '9,Ping Obs Count',
  78                   wantlogininfo => '0,Login Info Req,yesno',
  79           wantgrid => '0,Show DX Grid,yesno',
  80                   wantann_talk => '0,Talklike Anns,yesno',
  81                   wantpc16 => '9,Want Users from node,yesno',
  82                   wantsendpc16 => '9,Send PC16,yesno',
  83                   wantroutepc19 => '9,Route PC19,yesno',
  84                   wantusstate => '0,Show US State,yesno',
  85                   wantdxcq => '0,Show CQ Zone,yesno',
  86                   wantdxitu => '0,Show ITU Zone,yesno',
  87                   lastoper => '9,Last for/oper,cldatetime',
  88                   nothere => '0,Not Here Text',
  89                   registered => '9,Registered?,yesno',
  90                   prompt => '0,Required Prompt',
  91                   version => '1,Version',
  92                   build => '1,Build',
  93                   believe => '1,Believable nodes,parray',
  94                   lastping => '1,Last Ping at,ptimelist',
  95                  );
  96
  97 #no strict;
  98 sub AUTOLOAD
  99 {
 100         no strict;
 101         my $name = $AUTOLOAD;
 102
 103         return if $name =~ /::DESTROY$/;
 104         $name =~ s/^.*:://o;
 105
 106         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 107         # this clever line of code creates a subroutine which takes over from autoload
 108         # from OO Perl - Conway
 109         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 110        goto &$AUTOLOAD;
 111 }
 112
 113 #use strict;
 114
 115 #
 116 # initialise the system
 117 #
 118 sub init
 119 {
 120         my ($pkg, $fn, $mode) = @_;
 121
 122         confess "need a filename in User" if !$fn;
 123
 124         my $ufn;
 125         my $convert;
 126
 127         eval {
 128                 require Storable;
 129         };
 130
 131 #       eval "use Storable qw(nfreeze thaw)";
 132
 133         if ($@) {
 134                 $ufn = "$fn.v2";
 135                 $v3 = $convert = 0;
 136                 dbg("the module Storable appears to be missing!!");
 137                 dbg("trying to continue in compatibility mode (this may fail)");
 138                 dbg("please install Storable from CPAN as soon as possible");
 139         } else {
 140                 import Storable qw(nfreeze thaw);
 141
 142                 $ufn = "$fn.v3";
 143                 $v3 = 1;
 144                 $convert++ if -e "$fn.v2" && !-e $ufn;
 145         }
 146
 147         if ($mode) {
 148                 $dbm = tie (%u, 'DB_File', $ufn, O_CREAT|O_RDWR, 0666, $DB_BTREE) or confess "can't open user file: $fn ($!) [rebuild it from user_asc?]";
 149         } else {
 150                 $dbm = tie (%u, 'DB_File', $ufn, O_RDONLY, 0666, $DB_BTREE) or confess "can't open user file: $fn ($!) [rebuild it from user_asc?]";
 151         }
 152
 153         die "Cannot open $ufn ($!)\n" unless $dbm;
 154
 155         $lru = LRU->newbase("DXUser", $lrusize);
 156
 157         # do a conversion if required
 158         if ($dbm && $convert) {
 159                 my ($key, $val, $action, $count, $err) = ('','',0,0,0);
 160
 161                 my %oldu;
 162                 dbg("Converting the User File to V3 ");
 163                 dbg("This will take a while, I suggest you go and have cup of strong tea");
 164                 my $odbm = tie (%oldu, 'DB_File', "$fn.v2", O_RDONLY, 0666, $DB_BTREE) or confess "can't open user file: $fn.v2 ($!) [rebuild it from user_asc?]";
 165         for ($action = R_FIRST; !$odbm->seq($key, $val, $action); $action = R_NEXT) {
 166                         my $ref = asc_decode($val);
 167                         if ($ref) {
 168                                 $ref->put;
 169                                 $count++;
 170                         } else {
 171                                 $err++
 172                         }
 173                 }
 174                 undef $odbm;
 175                 untie %oldu;
 176                 dbg("Conversion completed $count records $err errors");
 177         }
 178         $filename = $ufn;
 179 }
 180
 181 sub del_file
 182 {
 183         my ($pkg, $fn) = @_;
 184
 185         confess "need a filename in User" if !$fn;
 186         $fn .= $v3 ? ".v3" : ".v2";
 187         unlink $fn;
 188 }
 189
 190 #
 191 # periodic processing
 192 #
 193 sub process
 194 {
 195         if ($main::systime > $lasttime + 15) {
 196                 $dbm->sync;
 197                 $lasttime = $main::systime;
 198         }
 199 }
 200
 201 #
 202 # close the system
 203 #
 204
 205 sub finish
 206 {
 207         undef $dbm;
 208         untie %u;
 209 }
 210
 211 #
 212 # new - create a new user
 213 #
 214
 215 sub alloc
 216 {
 217         my $pkg = shift;
 218         my $call = uc shift;
 219         my $self = bless {call => $call, 'sort'=>'U'}, $pkg;
 220         return $self;
 221 }
 222
 223 sub new
 224 {
 225         my $pkg = shift;
 226         my $call = shift;
 227         #  $call =~ s/-\d+$//o;
 228
 229 #       confess "can't create existing call $call in User\n!" if $u{$call};
 230
 231         my $self = $pkg->alloc($call);
 232         $self->put;
 233         return $self;
 234 }
 235
 236 #
 237 # get - get an existing user - this seems to return a different reference everytime it is
 238 #       called - see below
 239 #
 240
 241 sub get
 242 {
 243         my $pkg = shift;
 244         my $call = uc shift;
 245         my $data;
 246
 247         # is it in the LRU cache?
 248         my $ref = $lru->get($call);
 249         return $ref if $ref;
 250
 251         # search for it
 252         unless ($dbm->get($call, $data)) {
 253                 $ref = decode($data);
 254                 $lru->put($call, $ref);
 255                 return $ref;
 256         }
 257         return undef;
 258 }
 259
 260 #
 261 # get an existing either from the channel (if there is one) or from the database
 262 #
 263 # It is important to note that if you have done a get (for the channel say) and you
 264 # want access or modify that you must use this call (and you must NOT use get's all
 265 # over the place willy nilly!)
 266 #
 267
 268 sub get_current
 269 {
 270         my $pkg = shift;
 271         my $call = uc shift;
 272
 273         my $dxchan = DXChannel::get($call);
 274         return $dxchan->user if $dxchan;
 275         my $rref = Route::get($call);
 276         return $rref->user if $rref && exists $rref->{user};
 277         return $pkg->get($call);
 278 }
 279
 280 #
 281 # get all callsigns in the database
 282 #
 283
 284 sub get_all_calls
 285 {
 286         return (sort keys %u);
 287 }
 288
 289 #
 290 # put - put a user
 291 #
 292
 293 sub put
 294 {
 295         my $self = shift;
 296         confess "Trying to put nothing!" unless $self && ref $self;
 297         my $call = $self->{call};
 298         # delete all instances of this
 299 #       for ($dbm->get_dup($call)) {
 300 #               $dbm->del_dup($call, $_);
 301 #       }
 302         $dbm->del($call);
 303         delete $self->{annok} if $self->{annok};
 304         delete $self->{dxok} if $self->{dxok};
 305         $lru->put($call, $self);
 306         my $ref = $self->encode;
 307         $dbm->put($call, $ref);
 308 }
 309
 310 # freeze the user
 311 sub encode
 312 {
 313         goto &asc_encode unless $v3;
 314         my $self = shift;
 315         return nfreeze($self);
 316 }
 317
 318 # thaw the user
 319 sub decode
 320 {
 321         goto &asc_decode unless $v3;
 322         return thaw(shift);
 323 }
 324
 325 #
 326 # create a string from a user reference (in_ascii)
 327 #
 328 sub asc_encode
 329 {
 330         my $self = shift;
 331         my $dd = new Data::Dumper([$self]);
 332         $dd->Indent(0);
 333         $dd->Terse(1);
 334     $dd->Quotekeys($] < 5.005 ? 1 : 0);
 335         return $dd->Dumpxs;
 336 }
 337
 338 #
 339 # create a hash from a string (in ascii)
 340 #
 341 sub asc_decode
 342 {
 343         my $s = shift;
 344         my $ref;
 345         eval '$ref = ' . $s;
 346         if ($@) {
 347                 LogDbg('err', $@);
 348                 $ref = undef;
 349         }
 350         return $ref;
 351 }
 352
 353 #
 354 # del - delete a user
 355 #
 356
 357 sub del
 358 {
 359         my $self = shift;
 360         my $call = $self->{call};
 361         # delete all instances of this
 362 #       for ($dbm->get_dup($call)) {
 363 #               $dbm->del_dup($call, $_);
 364 #       }
 365         $lru->remove($call);
 366         $dbm->del($call);
 367 }
 368
 369 #
 370 # close - close down a user
 371 #
 372
 373 sub close
 374 {
 375         my $self = shift;
 376         $self->{lastin} = time;
 377         $self->put();
 378 }
 379
 380 #
 381 # sync the database
 382 #
 383
 384 sub sync
 385 {
 386         $dbm->sync;
 387 }
 388
 389 #
 390 # return a list of valid elements
 391 #
 392
 393 sub fields
 394 {
 395         return keys(%valid);
 396 }
 397
 398
 399 #
 400 # export the database to an ascii file
 401 #
 402
 403 sub export
 404 {
 405         my $fn = shift;
 406
 407         # save old ones
 408         rename "$fn.oooo", "$fn.ooooo" if -e "$fn.oooo";
 409         rename "$fn.ooo", "$fn.oooo" if -e "$fn.ooo";
 410         rename "$fn.oo", "$fn.ooo" if -e "$fn.oo";
 411         rename "$fn.o", "$fn.oo" if -e "$fn.o";
 412         rename "$fn", "$fn.o" if -e "$fn";
 413
 414         my $count = 0;
 415         my $err = 0;
 416         my $del = 0;
 417         my $fh = new IO::File ">$fn" or return "cannot open $fn ($!)";
 418         if ($fh) {
 419                 my $key = 0;
 420                 my $val = undef;
 421                 my $action;
 422                 my $t = scalar localtime;
 423                 print $fh q{#!/usr/bin/perl
 424 #
 425 # The exported userfile for a DXSpider System
 426 #
 427 # Input file: $filename
 428 #       Time: $t
 429 #
 430
 431 package main;
 432
 433 # search local then perl directories
 434 BEGIN {
 435         umask 002;
 436
 437         # root of directory tree for this system
 438         $root = "/spider";
 439         $root = $ENV{'DXSPIDER_ROOT'} if $ENV{'DXSPIDER_ROOT'};
 440
 441         unshift @INC, "$root/perl";     # this IS the right way round!
 442         unshift @INC, "$root/local";
 443
 444         # try to detect a lockfile (this isn't atomic but
 445         # should do for now
 446         $lockfn = "$root/local/cluster.lck";       # lock file name
 447         if (-e $lockfn) {
 448                 open(CLLOCK, "$lockfn") or die "Can't open Lockfile ($lockfn) $!";
 449                 my $pid = <CLLOCK>;
 450                 chomp $pid;
 451                 die "Lockfile ($lockfn) and process $pid exists - cluster must be stopped first\n" if kill 0, $pid;
 452                 close CLLOCK;
 453         }
 454 }
 455
 456 package DXUser;
 457
 458 use DXVars;
 459 use DXUser;
 460
 461 if (@ARGV) {
 462         $main::userfn = shift @ARGV;
 463         print "user filename now $userfn\n";
 464 }
 465
 466 DXUser->del_file($main::userfn);
 467 DXUser->init($main::userfn, 1);
 468 %u = ();
 469 my $count = 0;
 470 my $err = 0;
 471 while (<DATA>) {
 472         chomp;
 473         my @f = split /\t/;
 474         my $ref = asc_decode($f[1]);
 475         if ($ref) {
 476                 $ref->put();
 477                 $count++;
 478         } else {
 479                 print "# Error: $f[0]\t$f[1]\n";
 480                 $err++
 481         }
 482 }
 483 DXUser->sync; DXUser->finish;
 484 print "There are $count user records and $err errors\n";
 485 };
 486                 print $fh "__DATA__\n";
 487
 488         for ($action = R_FIRST; !$dbm->seq($key, $val, $action); $action = R_NEXT) {
 489                         if (!is_callsign($key) || $key =~ /^0/) {
 490                                 my $eval = $val;
 491                                 my $ekey = $key;
 492                                 $eval =~ s/([\%\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 493                                 $ekey =~ s/([\%\x00-\x1f\x7f-\xff])/sprintf("%%%02X", ord($1))/eg;
 494                                 LogDbg('DXCommand', "Export Error1: $ekey\t$eval");
 495                                 eval {$dbm->del($key)};
 496                                 dbg(carp("Export Error1: $ekey\t$eval\n$@")) if $@;
 497                                 ++$err;
 498                                 next;
 499                         }
 500                         my $ref = decode($val);
 501                         if ($ref) {
 502                                 my $t = $ref->{lastin} || 0;
 503                                 if ($ref->{sort} eq 'U' && !$ref->{priv} && $main::systime > $t + $tooold) {
 504                                         unless ($ref->{lat} && $ref->{long} || $ref->{qth} || $ref->{qra}) {
 505                                                 eval {$dbm->del($key)};
 506                                                 dbg(carp("Export Error2: $key\t$val\n$@")) if $@;
 507                                                 LogDbg('DXCommand', "$ref->{call} deleted, too old");
 508                                                 $del++;
 509                                                 next;
 510                                         }
 511                                 }
 512                                 # only store users that are reasonably active or have useful information
 513                                 print $fh "$key\t" . $ref->asc_encode . "\n";
 514                                 ++$count;
 515                         } else {
 516                                 LogDbg('DXCommand', "Export Error3: $key\t$val");
 517                                 eval {$dbm->del($key)};
 518                                 dbg(carp("Export Error3: $key\t$val\n$@")) if $@;
 519                                 ++$err;
 520                         }
 521                 }
 522         $fh->close;
 523     }
 524         return "$count Users $del Deleted $err Errors ('sh/log Export' for details)";
 525 }
 526
 527 #
 528 # group handling
 529 #
 530
 531 # add one or more groups
 532 sub add_group
 533 {
 534         my $self = shift;
 535         my $ref = $self->{group} || [ 'local' ];
 536         $self->{group} = $ref if !$self->{group};
 537         push @$ref, @_ if @_;
 538 }
 539
 540 # remove one or more groups
 541 sub del_group
 542 {
 543         my $self = shift;
 544         my $ref = $self->{group} || [ 'local' ];
 545         my @in = @_;
 546
 547         $self->{group} = $ref if !$self->{group};
 548
 549         @$ref = map { my $a = $_; return (grep { $_ eq $a } @in) ? () : $a } @$ref;
 550 }
 551
 552 # does this thing contain all the groups listed?
 553 sub union
 554 {
 555         my $self = shift;
 556         my $ref = $self->{group};
 557         my $n;
 558
 559         return 0 if !$ref || @_ == 0;
 560         return 1 if @$ref == 0 && @_ == 0;
 561         for ($n = 0; $n < @_; ) {
 562                 for (@$ref) {
 563                         my $a = $_;
 564                         $n++ if grep $_ eq $a, @_;
 565                 }
 566         }
 567         return $n >= @_;
 568 }
 569
 570 # simplified group test just for one group
 571 sub in_group
 572 {
 573         my $self = shift;
 574         my $s = shift;
 575         my $ref = $self->{group};
 576
 577         return 0 if !$ref;
 578         return grep $_ eq $s, $ref;
 579 }
 580
 581 # set up a default group (only happens for them's that connect direct)
 582 sub new_group
 583 {
 584         my $self = shift;
 585         $self->{group} = [ 'local' ];
 586 }
 587
 588 #
 589 # return a prompt for a field
 590 #
 591
 592 sub field_prompt
 593 {
 594         my ($self, $ele) = @_;
 595         return $valid{$ele};
 596 }
 597
 598 # some variable accessors
 599 sub sort
 600 {
 601         my $self = shift;
 602         @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 603 }
 604
 605 # some accessors
 606
 607 # want is default = 1
 608 sub _want
 609 {
 610         my $n = shift;
 611         my $self = shift;
 612         my $val = shift;
 613         my $s = "want$n";
 614         $self->{$s} = $val if defined $val;
 615         return exists $self->{$s} ? $self->{$s} : 1;
 616 }
 617
 618 # wantnot is default = 0
 619 sub _wantnot
 620 {
 621         my $n = shift;
 622         my $self = shift;
 623         my $val = shift;
 624         my $s = "want$n";
 625         $self->{$s} = $val if defined $val;
 626         return exists $self->{$s} ? $self->{$s} : 0;
 627 }
 628
 629 sub wantbeep
 630 {
 631         return _want('beep', @_);
 632 }
 633
 634 sub wantann
 635 {
 636         return _want('ann', @_);
 637 }
 638
 639 sub wantwwv
 640 {
 641         return _want('wwv', @_);
 642 }
 643
 644 sub wantwcy
 645 {
 646         return _want('wcy', @_);
 647 }
 648
 649 sub wantecho
 650 {
 651         return _want('echo', @_);
 652 }
 653
 654 sub wantwx
 655 {
 656         return _want('wx', @_);
 657 }
 658
 659 sub wantdx
 660 {
 661         return _want('dx', @_);
 662 }
 663
 664 sub wanttalk
 665 {
 666         return _want('talk', @_);
 667 }
 668
 669 sub wantgrid
 670 {
 671         return _want('grid', @_);
 672 }
 673
 674 sub wantemail
 675 {
 676         return _want('email', @_);
 677 }
 678
 679 sub wantann_talk
 680 {
 681         return _want('ann_talk', @_);
 682 }
 683
 684 sub wantpc16
 685 {
 686         return _want('pc16', @_);
 687 }
 688
 689 sub wantsendpc16
 690 {
 691         return _want('sendpc16', @_);
 692 }
 693
 694 sub wantroutepc16
 695 {
 696         return _want('routepc16', @_);
 697 }
 698
 699 sub wantusstate
 700 {
 701         return _want('usstate', @_);
 702 }
 703
 704 sub wantdxcq
 705 {
 706         return _want('dxcq', @_);
 707 }
 708
 709 sub wantdxitu
 710 {
 711         return _want('dxitu', @_);
 712 }
 713
 714 sub wantlogininfo
 715 {
 716         my $self = shift;
 717         my $val = shift;
 718         $self->{wantlogininfo} = $val if defined $val;
 719         return $self->{wantlogininfo};
 720 }
 721
 722 sub is_node
 723 {
 724         my $self = shift;
 725         return $self->{sort} =~ /[ACRSX]/;
 726 }
 727
 728 sub is_user
 729 {
 730         my $self = shift;
 731         return $self->{sort} eq 'U';
 732 }
 733
 734 sub is_bbs
 735 {
 736         my $self = shift;
 737         return $self->{sort} eq 'B';
 738 }
 739
 740 sub is_spider
 741 {
 742         my $self = shift;
 743         return $self->{sort} eq 'S';
 744 }
 745
 746 sub is_clx
 747 {
 748         my $self = shift;
 749         return $self->{sort} eq 'C';
 750 }
 751
 752 sub is_dxnet
 753 {
 754         my $self = shift;
 755         return $self->{sort} eq 'X';
 756 }
 757
 758 sub is_arcluster
 759 {
 760         my $self = shift;
 761         return $self->{sort} eq 'R';
 762 }
 763
 764 sub is_ak1a
 765 {
 766         my $self = shift;
 767         return $self->{sort} eq 'A';
 768 }
 769
 770 sub unset_passwd
 771 {
 772         my $self = shift;
 773         delete $self->{passwd};
 774 }
 775
 776 sub unset_passphrase
 777 {
 778         my $self = shift;
 779         delete $self->{passphrase};
 780 }
 781
 782 sub set_believe
 783 {
 784         my $self = shift;
 785         my $call = uc shift;
 786         $self->{believe} ||= [];
 787         push @{$self->{believe}}, $call unless grep $_ eq $call, @{$self->{believe}};
 788 }
 789
 790 sub unset_believe
 791 {
 792         my $self = shift;
 793         my $call = uc shift;
 794         if (exists $self->{believe}) {
 795                 $self->{believe} = [grep {$_ ne $call} @{$self->{believe}}];
 796                 delete $self->{believe} unless @{$self->{believe}};
 797         }
 798 }
 799
 800 sub believe
 801 {
 802         my $self = shift;
 803         return exists $self->{believe} ? @{$self->{believe}} : ();
 804 }
 805
 806 sub lastping
 807 {
 808         my $self = shift;
 809         my $call = shift;
 810         $self->{lastping} ||= {};
 811         $self->{lastping} = {} unless ref $self->{lastping};
 812         my $b = $self->{lastping};
 813         $b->{$call} = shift if @_;
 814         return $b->{$call};
 815 }
 816 1;
 817 __END__
 818
 819
 820
 821
 822