perl/DXProtHandle.pm

   1 #
   2 #
   3 # This module impliments the handlers for the protocal mode for a dx cluster
   4 #
   5 # Copyright (c) 1998-2007 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXProt;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXM;
  18 use DXProtVars;
  19 use DXCommandmode;
  20 use DXLog;
  21 use Spot;
  22 use DXProtout;
  23 use DXDebug;
  24 use Filter;
  25 use Local;
  26 use DXDb;
  27 use AnnTalk;
  28 use Geomag;
  29 use WCY;
  30 use BadWords;
  31 use DXHash;
  32 use Route;
  33 use Route::Node;
  34 use Script;
  35 use RouteDB;
  36
  37
  38 use strict;
  39
  40 use vars qw($pc11_max_age $pc23_max_age $last_pc50 $eph_restime $eph_info_restime $eph_pc34_restime
  41                         $last_hour $last10 %eph  %pings %rcmds $ann_to_talk
  42                         $pingint $obscount %pc19list $chatdupeage $chatimportfn
  43                         $investigation_int $pc19_version $myprot_version
  44                         %nodehops $baddx $badspotter $badnode $censorpc
  45                         $allowzero $decode_dk0wcy $send_opernam @checklist
  46                         $eph_pc15_restime $pc9x_past_age $pc9x_dupe_age
  47                         $pc10_dupe_age $pc92_slug_changes $last_pc92_slug
  48                         $pc92Ain $pc92Cin $pc92Din $pc92Kin $pc9x_time_tolerance
  49                    );
  50
  51 $pc9x_dupe_age = 60;                    # catch loops of circular (usually) D records
  52 $pc10_dupe_age = 45;                    # just something to catch duplicate PC10->PC93 conversions
  53 $pc92_slug_changes = 60;                # slug any changes going outward for this long
  54 $last_pc92_slug = 0;                    # the last time we sent out any delayed add or del PC92s
  55 $pc9x_time_tolerance = 15*60;   # the time on a pc9x is allowed to be out by this amount
  56 $pc9x_past_age = (122*60)+              # maximum age in the past of a px9x (a config record might be the only
  57         $pc9x_time_tolerance;           # thing a node might send - once an hour and we allow an extra hour for luck)
  58                                 # this is actually the partition between "yesterday" and "today" but old.
  59
  60
  61 # incoming talk commands
  62 sub handle_10
  63 {
  64         my $self = shift;
  65         my $pcno = shift;
  66         my $line = shift;
  67         my $origin = shift;
  68
  69         # this is to catch loops caused by bad software ...
  70         if (eph_dup($line, $pc10_dupe_age)) {
  71                 return;
  72         }
  73
  74         # will we allow it at all?
  75         if ($censorpc) {
  76                 my @bad;
  77                 if (@bad = BadWords::check($_[3])) {
  78                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
  79                         return;
  80                 }
  81         }
  82
  83         # is it for me or one of mine?
  84         my ($from, $to, $via, $call, $dxchan);
  85         $from = $_[1];
  86         if ($_[5] gt ' ') {
  87                 $via = $_[2];
  88                 $to = $_[5];
  89         } else {
  90                 $to = $_[2];
  91         }
  92
  93         # if this is a 'nodx' node then ignore it
  94         if ($badnode->in($_[6]) || ($via && $badnode->in($via))) {
  95                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
  96                 return;
  97         }
  98
  99         # if this is a 'bad spotter' user then ignore it
 100         my $nossid = $from;
 101         $nossid =~ s/-\d+$//;
 102         if ($badspotter->in($nossid)) {
 103                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 104                 return;
 105         }
 106
 107         # if we are converting announces to talk is it a dup?
 108         if ($ann_to_talk) {
 109                 if (AnnTalk::is_talk_candidate($from, $_[3]) && AnnTalk::dup($from, $to, $_[3])) {
 110                         dbg("PCPROT: Dupe talk from announce, dropped") if isdbg('chanerr');
 111                         return;
 112                 }
 113         }
 114
 115         # remember a route to this node and also the node on which this user is
 116         RouteDB::update($_[6], $self->{call});
 117 #       RouteDB::update($to, $_[6]);
 118
 119         # convert this to a PC93, coming from mycall with origin set and process it as such
 120         $main::me->normal(pc93($to, $from, $via, $_[3], $_[6]));
 121 }
 122
 123 # DX Spot handling
 124 sub handle_11
 125 {
 126         my $self = shift;
 127         my $pcno = shift;
 128         my $line = shift;
 129         my $origin = shift;
 130
 131         # route 'foreign' pc26s
 132         if ($pcno == 26) {
 133                 if ($_[7] ne $main::mycall) {
 134                         $self->route($_[7], $line);
 135                         return;
 136                 }
 137         }
 138
 139 #       my ($hops) = $_[8] =~ /^H(\d+)/;
 140
 141         # is the spotted callsign blank? This should really be trapped earlier but it
 142         # could break other protocol sentences. Also check for lower case characters.
 143         if ($_[2] =~ /^\s*$/) {
 144                 dbg("PCPROT: blank callsign, dropped") if isdbg('chanerr');
 145                 return;
 146         }
 147         if ($_[2] =~ /[a-z]/) {
 148                 dbg("PCPROT: lowercase characters, dropped") if isdbg('chanerr');
 149                 return;
 150         }
 151
 152
 153         # if this is a 'nodx' node then ignore it
 154         if ($badnode->in($_[7])) {
 155                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 156                 return;
 157         }
 158
 159         # if this is a 'bad spotter' user then ignore it
 160         my $nossid = $_[6];
 161         $nossid =~ s/-\d+$//;
 162         if ($badspotter->in($nossid)) {
 163                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 164                 return;
 165         }
 166
 167         # convert the date to a unix date
 168         my $d = cltounix($_[3], $_[4]);
 169         # bang out (and don't pass on) if date is invalid or the spot is too old (or too young)
 170         if (!$d || ($pcno == 11 && ($d < $main::systime - $pc11_max_age || $d > $main::systime + 900))) {
 171                 dbg("PCPROT: Spot ignored, invalid date or out of range ($_[3] $_[4])\n") if isdbg('chanerr');
 172                 return;
 173         }
 174
 175         # is it 'baddx'
 176         if ($baddx->in($_[2]) || BadWords::check($_[2]) || $_[2] =~ /COCK/) {
 177                 dbg("PCPROT: Bad DX spot, ignored") if isdbg('chanerr');
 178                 return;
 179         }
 180
 181         # do some de-duping
 182         $_[5] =~ s/^\s+//;                      # take any leading blanks off
 183         $_[2] = unpad($_[2]);           # take off leading and trailing blanks from spotted callsign
 184         if ($_[2] =~ /BUST\w*$/) {
 185                 dbg("PCPROT: useless 'BUSTED' spot") if isdbg('chanerr');
 186                 return;
 187         }
 188         if ($censorpc) {
 189                 my @bad;
 190                 if (@bad = BadWords::check($_[5])) {
 191                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 192                         return;
 193                 }
 194         }
 195
 196         # remember a route
 197 #       RouteDB::update($_[7], $self->{call});
 198 #       RouteDB::update($_[6], $_[7]);
 199
 200         my @spot = Spot::prepare($_[1], $_[2], $d, $_[5], $nossid, $_[7]);
 201         # global spot filtering on INPUT
 202         if ($self->{inspotsfilter}) {
 203                 my ($filter, $hops) = $self->{inspotsfilter}->it(@spot);
 204                 unless ($filter) {
 205                         dbg("PCPROT: Rejected by input spot filter") if isdbg('chanerr');
 206                         return;
 207                 }
 208         }
 209
 210         # this goes after the input filtering, but before the add
 211         # so that if it is input filtered, it isn't added to the dup
 212         # list. This allows it to come in from a "legitimate" source
 213         if (Spot::dup(@spot[0..4,5])) {
 214                 dbg("PCPROT: Duplicate Spot ignored\n") if isdbg('chanerr');
 215                 return;
 216         }
 217
 218         # add it
 219         Spot::add(@spot);
 220
 221         #
 222         # @spot at this point contains:-
 223         # freq, spotted call, time, text, spotter, spotted cc, spotters cc, orig node
 224         # then  spotted itu, spotted cq, spotters itu, spotters cq
 225         # you should be able to route on any of these
 226         #
 227
 228         # fix up qra locators of known users
 229         my $user = DXUser->get_current($spot[4]);
 230         if ($user) {
 231                 my $qra = $user->qra;
 232                 unless ($qra && is_qra($qra)) {
 233                         my $lat = $user->lat;
 234                         my $long = $user->long;
 235                         if (defined $lat && defined $long) {
 236                                 $user->qra(DXBearing::lltoqra($lat, $long));
 237                                 $user->put;
 238                         }
 239                 }
 240
 241                 # send a remote command to a distant cluster if it is visible and there is no
 242                 # qra locator and we havn't done it for a month.
 243
 244                 unless ($user->qra) {
 245                         my $node;
 246                         my $to = $user->homenode;
 247                         my $last = $user->lastoper || 0;
 248                         if ($send_opernam && $to && $to ne $main::mycall && $main::systime > $last + $DXUser::lastoperinterval && ($node = Route::Node::get($to)) ) {
 249                                 my $cmd = "forward/opernam $spot[4]";
 250                                 # send the rcmd but we aren't interested in the replies...
 251                                 my $dxchan = $node->dxchan;
 252                                 if ($dxchan && $dxchan->is_clx) {
 253                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 254                                 } else {
 255                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 256                                 }
 257                                 if ($to ne $_[7]) {
 258                                         $to = $_[7];
 259                                         $node = Route::Node::get($to);
 260                                         if ($node) {
 261                                                 $dxchan = $node->dxchan;
 262                                                 if ($dxchan && $dxchan->is_clx) {
 263                                                         route(undef, $to, pc84($main::mycall, $to, $main::mycall, $cmd));
 264                                                 } else {
 265                                                         route(undef, $to, pc34($main::mycall, $to, $cmd));
 266                                                 }
 267                                         }
 268                                 }
 269                                 $user->lastoper($main::systime);
 270                                 $user->put;
 271                         }
 272                 }
 273         }
 274
 275         # local processing
 276         if (defined *Local::spot) {
 277                 my $r;
 278                 eval {
 279                         $r = Local::spot($self, @spot);
 280                 };
 281                 return if $r;
 282         }
 283
 284         # DON'T be silly and send on PC26s!
 285         return if $pcno == 26;
 286
 287         # send out the filtered spots
 288         send_dx_spot($self, $line, @spot) if @spot;
 289 }
 290
 291 # announces
 292 sub handle_12
 293 {
 294         my $self = shift;
 295         my $pcno = shift;
 296         my $line = shift;
 297         my $origin = shift;
 298
 299         # announce duplicate checking
 300         $_[3] =~ s/^\s+//;                      # remove leading blanks
 301
 302         if ($censorpc) {
 303                 my @bad;
 304                 if (@bad = BadWords::check($_[3])) {
 305                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
 306                         return;
 307                 }
 308         }
 309
 310         # if this is a 'nodx' node then ignore it
 311         if ($badnode->in($_[5])) {
 312                 dbg("PCPROT: Bad Node, dropped") if isdbg('chanerr');
 313                 return;
 314         }
 315
 316         # if this is a 'bad spotter' user then ignore it
 317         my $nossid = $_[1];
 318         $nossid =~ s/-\d+$//;
 319         if ($badspotter->in($nossid)) {
 320                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
 321                 return;
 322         }
 323
 324
 325         my $dxchan;
 326
 327         if ((($dxchan = DXChannel::get($_[2])) && $dxchan->is_user) || $_[4] =~ /^[\#\w.]+$/){
 328                 $self->send_chat(0, $line, @_[1..6]);
 329         } elsif ($_[2] eq '*' || $_[2] eq $main::mycall) {
 330
 331                 # remember a route
 332 #               RouteDB::update($_[5], $self->{call});
 333 #               RouteDB::update($_[1], $_[5]);
 334
 335                 # ignore something that looks like a chat line coming in with sysop
 336                 # flag - this is a kludge...
 337                 if ($_[3] =~ /^\#\d+ / && $_[4] eq '*') {
 338                         dbg('PCPROT: Probable chat rewrite, dropped') if isdbg('chanerr');
 339                         return;
 340                 }
 341
 342                 # here's a bit of fun, convert incoming ann with a callsign in the first word
 343                 # or one saying 'to <call>' to a talk if we can route to the recipient
 344                 if ($ann_to_talk) {
 345                         my $call = AnnTalk::is_talk_candidate($_[1], $_[3]);
 346                         if ($call) {
 347                                 my $ref = Route::get($call);
 348                                 if ($ref) {
 349                                         $dxchan = $ref->dxchan;
 350                                         $dxchan->talk($_[1], $call, undef, $_[3], $_[5]) if $dxchan != $self;
 351                                         return;
 352                                 }
 353                         }
 354                 }
 355
 356                 # send it
 357                 $self->send_announce(0, $line, @_[1..6]);
 358         } else {
 359                 $self->route($_[2], $line);
 360         }
 361
 362         # local processing
 363         if (defined *Local::ann) {
 364                 my $r;
 365                 eval {
 366                         $r = Local::ann($self, $line, @_[1..6]);
 367                 };
 368                 return if $r;
 369         }
 370 }
 371
 372 sub handle_15
 373 {
 374         my $self = shift;
 375         my $pcno = shift;
 376         my $line = shift;
 377         my $origin = shift;
 378
 379         if (eph_dup($line, $eph_pc15_restime)) {
 380                 return;
 381         } else {
 382                 unless ($self->{isolate}) {
 383                         DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
 384                 }
 385         }
 386 }
 387
 388 # incoming user
 389 sub handle_16
 390 {
 391         my $self = shift;
 392         my $pcno = shift;
 393         my $line = shift;
 394         my $origin = shift;
 395
 396         # general checks
 397         my $dxchan;
 398         my $ncall = $_[1];
 399         my $newline = "PC16^";
 400
 401         # dos I want users from this channel?
 402         unless ($self->user->wantpc16) {
 403                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 404                 return;
 405         }
 406
 407         # is it me?
 408         if ($ncall eq $main::mycall) {
 409                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 410                 return;
 411         }
 412
 413         my $h;
 414         $h = 1 if DXChannel::get($ncall);
 415         RouteDB::update($ncall, $self->{call}, $h);
 416         if ($h && $self->{call} ne $ncall) {
 417                 dbg("PCPROT: trying to update a local node, ignored") if isdbg('chanerr');
 418                 return;
 419         }
 420
 421         if (eph_dup($line)) {
 422                 return;
 423         }
 424
 425         # isolate now means only accept stuff from this call only
 426         if ($self->{isolate} && $ncall ne $self->{call}) {
 427                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 428                 return;
 429         }
 430
 431         my $parent = Route::Node::get($ncall);
 432
 433         if ($parent) {
 434                 $dxchan = $parent->dxchan;
 435                 if ($dxchan && $dxchan ne $self) {
 436                         dbg("PCPROT: PC16 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 437                         return;
 438                 }
 439
 440                 # input filter if required
 441                 return unless $self->in_filter_route($parent);
 442         } else {
 443                 $parent = Route::Node->new($ncall);
 444         }
 445
 446         unless ($h) {
 447                 if ($parent->via_pc92) {
 448                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 449                         return;
 450                 }
 451         }
 452
 453         my $i;
 454         my @rout;
 455         for ($i = 2; $i < $#_; $i++) {
 456                 my ($call, $conf, $here) = $_[$i] =~ /^(\S+) (\S) (\d)/o;
 457                 next unless $call && $conf && defined $here && is_callsign($call);
 458                 next if $call eq $main::mycall;
 459
 460                 eph_del_regex("^PC17\\^$call\\^$ncall");
 461
 462                 $conf = $conf eq '*';
 463
 464                 # reject this if we think it is a node already
 465                 my $r = Route::Node::get($call);
 466                 my $u = DXUser->get_current($call) unless $r;
 467                 if ($r || ($u && $u->is_node)) {
 468                         dbg("PCPROT: $call is a node") if isdbg('chanerr');
 469                         next;
 470                 }
 471
 472                 $r = Route::User::get($call);
 473                 my $flags = Route::here($here)|Route::conf($conf);
 474
 475                 if ($r) {
 476                         my $au = $r->addparent($parent);
 477                         if ($r->flags != $flags) {
 478                                 $r->flags($flags);
 479                                 $au = $r;
 480                         }
 481                         push @rout, $r if $h && $au;
 482                 } else {
 483                         my @ans = $parent->add_user($call, $flags);
 484                         push @rout, @ans if $h && @ans;
 485                 }
 486
 487                 # add this station to the user database, if required
 488                 my $user = DXUser->get_current($ncall);
 489                 $user = DXUser->new($call) unless $user;
 490                 $user->homenode($parent->call) if !$user->homenode;
 491                 $user->node($parent->call);
 492                 $user->lastin($main::systime) unless DXChannel::get($call);
 493                 $user->put;
 494
 495                 # send info to all logged in thingies
 496                 $self->tell_login('loginu', "$ncall: $call") if $user->is_local_node;
 497                 $self->tell_buddies('loginb', $call, $ncall);
 498         }
 499         if (@rout) {
 500                 $self->route_pc16($origin, $line, $parent, @rout) if @rout;
 501 #               $self->route_pc92a($main::mycall, undef, $parent, @rout) if $h && $self->{state} eq 'normal';
 502         }
 503 }
 504
 505 # remove a user
 506 sub handle_17
 507 {
 508         my $self = shift;
 509         my $pcno = shift;
 510         my $line = shift;
 511         my $origin = shift;
 512         my $dxchan;
 513         my $ncall = $_[2];
 514         my $ucall = $_[1];
 515
 516         eph_del_regex("^PC16\\^$ncall.*$ucall");
 517
 518         # do I want users from this channel?
 519         unless ($self->user->wantpc16) {
 520                 dbg("PCPROT: don't send users to $self->{call}") if isdbg('chanerr');
 521                 return;
 522         }
 523
 524         if ($ncall eq $main::mycall) {
 525                 dbg("PCPROT: trying to alter config on this node from outside!") if isdbg('chanerr');
 526                 return;
 527         }
 528
 529         # isolate now means only accept stuff from this call only
 530         if ($self->{isolate} && $ncall ne $self->{call}) {
 531                 dbg("PCPROT: $self->{call} isolated, $ncall ignored") if isdbg('chanerr');
 532                 return;
 533         }
 534
 535         RouteDB::delete($ncall, $self->{call});
 536
 537         my $uref = Route::User::get($ucall);
 538         unless ($uref) {
 539                 dbg("PCPROT: Route::User $ucall not in config") if isdbg('chanerr');
 540                 return;
 541         }
 542         my $parent = Route::Node::get($ncall);
 543         unless ($parent) {
 544                 dbg("PCPROT: Route::Node $ncall not in config") if isdbg('chanerr');
 545                 return;
 546         }
 547
 548         $dxchan = DXChannel::get($ncall);
 549         if ($dxchan && $dxchan ne $self) {
 550                 dbg("PCPROT: PC17 from $self->{call} trying to alter locally connected $ncall, ignored!") if isdbg('chanerr');
 551                 return;
 552         }
 553
 554         unless ($dxchan) {
 555                 if ($parent->via_pc92) {
 556                         dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 557                         return;
 558                 }
 559         }
 560
 561         if (DXChannel::get($ucall)) {
 562                 dbg("PCPROT: trying do disconnect local user, ignored") if isdbg('chanerr');
 563                 return;
 564         }
 565
 566         # input filter if required and then remove user if present
 567 #               return unless $self->in_filter_route($parent);
 568         $parent->del_user($uref);
 569
 570         # send info to all logged in thingies
 571         my $user = DXUser->get_current($ncall);
 572         $self->tell_login('logoutu', "$ncall: $ucall") if $user && $user->is_local_node;
 573         $self->tell_buddies('logoutb', $ucall, $ncall);
 574
 575         if (eph_dup($line)) {
 576                 return;
 577         }
 578
 579         $self->route_pc17($origin, $line, $parent, $uref);
 580 #       $self->route_pc92d($main::mycall, undef, $parent, $uref) if $dxchan;
 581 }
 582
 583 # link request
 584 sub handle_18
 585 {
 586         my $self = shift;
 587         my $pcno = shift;
 588         my $line = shift;
 589         my $origin = shift;
 590         $self->state('init');
 591
 592         my $parent = Route::Node::get($self->{call});
 593
 594         # record the type and version offered
 595         if (my ($version) = $_[1] =~ /DXSpider Version: (\d+\.\d+)/) {
 596                 $self->{version} = 53 + $version;
 597                 $self->user->version(53 + $version);
 598                 $parent->version(0 + $version);
 599                 my ($build) = $_[1] =~ /Build: (\d+(?:\.\d+)?)/;
 600                 $self->{build} = 0 + $build;
 601                 $self->user->build(0 + $build);
 602                 $parent->build(0 + $build);
 603                 dbg("DXSpider version $version build $build");
 604                 unless ($self->is_spider) {
 605                         dbg("Change U " . $self->user->sort . " C $self->{sort} -> S");
 606                         $self->user->sort('S');
 607                         $self->user->put;
 608                         $self->sort('S');
 609                 }
 610 #               $self->{handle_xml}++ if DXXml::available() && $_[1] =~ /\bxml/;
 611         } else {
 612                 dbg("Unknown software");
 613                 $self->version(50.0);
 614                 $self->version($_[2] / 100) if $_[2] && $_[2] =~ /^\d+$/;
 615                 $self->user->version($self->version);
 616         }
 617
 618         if ($_[1] =~ /\bpc9x/) {
 619                 if ($self->{isolate}) {
 620                         dbg("pc9x recognised, but $self->{call} is isolated, using old protocol");
 621                 } elsif (!$self->user->wantpc9x) {
 622                         dbg("pc9x explicitly switched off on $self->{call}, using old protocol");
 623                 } else {
 624                         $self->{do_pc9x} = 1;
 625                         dbg("Do px9x set on $self->{call}");
 626                 }
 627         }
 628
 629         # first clear out any nodes on this dxchannel
 630         my @rout = $parent->del_nodes;
 631         $self->route_pc21($origin, $line, @rout, $parent) if @rout;
 632         $self->send_local_config();
 633         $self->send(pc20());
 634 }
 635
 636 sub check_add_node
 637 {
 638         my $call = shift;
 639
 640         # add this station to the user database, if required (don't remove SSID from nodes)
 641         my $user = DXUser->get_current($call);
 642         if (!$user) {
 643                 $user = DXUser->new($call);
 644                 $user->priv(1);         # I have relented and defaulted nodes
 645                 $user->lockout(1);
 646                 $user->homenode($call);
 647                 $user->node($call);
 648         }
 649         $user->sort('A') unless $user->is_node;
 650         return $user;
 651 }
 652
 653 # incoming cluster list
 654 sub handle_19
 655 {
 656         my $self = shift;
 657         my $pcno = shift;
 658         my $line = shift;
 659         my $origin = shift;
 660
 661         my $i;
 662         my $newline = "PC19^";
 663
 664         # new routing list
 665         my (@rout, @pc92out);
 666
 667         # first get the INTERFACE node
 668         my $parent = Route::Node::get($self->{call});
 669         unless ($parent) {
 670                 dbg("PCPROT: my parent $self->{call} has disappeared");
 671                 $self->disconnect;
 672                 return;
 673         }
 674
 675         my $h;
 676
 677         # parse the PC19
 678         #
 679         # We are making a major change from now on. We are only going to accept
 680         # PC19s from directly connected nodes.  This means that we are probably
 681         # going to throw away most of the data that we are being sent.
 682         #
 683         # The justification for this is that most of it is wrong or out of date
 684         # anyway.
 685         #
 686         # From now on we are only going to believe PC92 data and locally connected
 687         # non-pc92 nodes.
 688         #
 689         for ($i = 1; $i < $#_-1; $i += 4) {
 690                 my $here = $_[$i];
 691                 my $call = uc $_[$i+1];
 692                 my $conf = $_[$i+2];
 693                 my $ver = $_[$i+3];
 694                 next unless defined $here && defined $conf && is_callsign($call);
 695
 696                 eph_del_regex("^PC(?:21\\^$call|17\\^[^\\^]+\\^$call)");
 697
 698                 # check for sane parameters
 699                 #                               $ver = 5000 if $ver eq '0000';
 700                 next unless $ver && $ver =~ /^\d+$/;
 701                 next if $ver < 5000;    # only works with version 5 software
 702                 next if length $call < 3; # min 3 letter callsigns
 703                 next if $call eq $main::mycall;
 704
 705                 # check that this PC19 isn't trying to alter the wrong dxchan
 706                 $h = 0;
 707                 my $dxchan = DXChannel::get($call);
 708                 if ($dxchan) {
 709                         if ($dxchan == $self) {
 710                                 $h = 1;
 711                         } else {
 712                                 dbg("PCPROT: PC19 from $self->{call} trying to alter wrong locally connected $call, ignored!") if isdbg('chanerr');
 713                                 next;
 714                         }
 715                 }
 716
 717                 # isolate now means only accept stuff from this call only
 718                 if ($self->{isolate} && $call ne $self->{call}) {
 719                         dbg("PCPROT: $self->{call} isolated, $call ignored") if isdbg('chanerr');
 720                         next;
 721                 }
 722
 723                 my $user = check_add_node($call);
 724
 725 #               if (eph_dup($genline)) {
 726 #                       dbg("PCPROT: dup PC19 for $call detected") if isdbg('chanerr');
 727 #                       next;
 728 #               }
 729
 730                 RouteDB::update($call, $self->{call}, $dxchan ? 1 : undef);
 731
 732                 unless ($h) {
 733                         if ($parent->via_pc92) {
 734                                 dbg("PCPROT: non-local node controlled by PC92, ignored") if isdbg('chanerr');
 735                                 next;
 736                         }
 737                 }
 738
 739                 my $r = Route::Node::get($call);
 740                 my $flags = Route::here($here)|Route::conf($conf);
 741
 742                 # modify the routing table if it is in it, otherwise store it in the pc19list for now
 743                 if ($r) {
 744                         my $ar;
 745                         if ($call ne $parent->call) {
 746                                 if ($self->in_filter_route($r)) {
 747                                         $ar = $parent->add($call, $ver, $flags);
 748 #                                       push @rout, $ar if $ar;
 749                                 } else {
 750                                         next;
 751                                 }
 752                         }
 753                         if ($r->version ne $ver || $r->flags != $flags) {
 754                                 $r->version($ver);
 755                                 $r->flags($flags);
 756                         }
 757                         push @rout, $r;
 758                 } else {
 759                         if ($call eq $self->{call} || $user->wantroutepc19) {
 760                                 my $new = Route->new($call); # throw away
 761                                 if ($self->in_filter_route($new)) {
 762                                         my $ar = $parent->add($call, $ver, $flags);
 763                                         $user->wantroutepc19(1) unless defined $user->wantroutepc19;
 764                                         push @rout, $ar if $ar;
 765                                         push @pc92out, $r if $h;
 766                                 } else {
 767                                         next;
 768                                 }
 769                         }
 770                 }
 771
 772                 # unbusy and stop and outgoing mail (ie if somehow we receive another PC19 without a disconnect)
 773                 my $mref = DXMsg::get_busy($call);
 774                 $mref->stop_msg($call) if $mref;
 775
 776                 $user->lastin($main::systime) unless DXChannel::get($call);
 777                 $user->put;
 778         }
 779
 780         # we are not automatically sending out PC19s, we send out a composite PC21,PC19 instead
 781         # but remember there will only be one (pair) these because any extras will be
 782         # thrown away.
 783         if (@rout) {
 784 #               $self->route_pc21($self->{call}, $line, @rout);
 785                 $self->route_pc19($self->{call}, $line, @rout);
 786         }
 787         if (@pc92out && !$pc92_slug_changes) {
 788                 $self->route_pc92a($main::mycall, $line, $main::routeroot, @pc92out) if $self->{state} eq 'normal';
 789         }
 790 }
 791
 792 # send local configuration
 793 sub handle_20
 794 {
 795         my $self = shift;
 796         my $pcno = shift;
 797         my $line = shift;
 798         my $origin = shift;
 799
 800         if ($self->{do_pc9x} && $self->{state} ne 'init92') {
 801                 $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 802                 $self->{do_pc9x} = 0;
 803         }
 804         $self->send_local_config;
 805         $self->send(pc22());
 806         $self->state('normal');
 807         $self->{lastping} = 0;
 808         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 809 }
 810
 811 # delete a cluster from the list
 812 #
 813 # This should never occur for directly connected nodes.
 814 #
 815 sub handle_21
 816 {
 817         my $self = shift;
 818         my $pcno = shift;
 819         my $line = shift;
 820         my $origin = shift;
 821         my $call = uc $_[1];
 822
 823         eph_del_regex("^PC1[679].*$call");
 824
 825         # if I get a PC21 from the same callsign as self then ignore it
 826         if ($call eq $self->{call}) {
 827                 dbg("PCPROT: self referencing PC21 from $self->{call}");
 828                 return;
 829         }
 830
 831         # for the above reason and also because of the check for PC21s coming
 832         # in for self->call from outside being ignored further down
 833         # we don't need any isolation code here, because we will never
 834         # act on a PC21 with self->call in it.
 835
 836         RouteDB::delete($call, $self->{call});
 837
 838         my $parent = Route::Node::get($self->{call});
 839         unless ($parent) {
 840                 dbg("PCPROT: my parent $self->{call} has disappeared");
 841                 $self->disconnect;
 842                 return;
 843         }
 844
 845         my @rout;
 846
 847         if ($call ne $main::mycall) { # don't allow malicious buggers to disconnect me!
 848                 my $node = Route::Node::get($call);
 849                 if ($node) {
 850
 851                         if ($node->via_pc92) {
 852                                 dbg("PCPROT: controlled by PC92, ignored") if isdbg('chanerr');
 853                                 return;
 854                         }
 855
 856                         my $dxchan = DXChannel::get($call);
 857                         if ($dxchan && $dxchan != $self) {
 858                                 dbg("PCPROT: PC21 from $self->{call} trying to alter locally connected $call, ignored!") if isdbg('chanerr');
 859                                 return;
 860                         }
 861
 862                         # input filter it
 863                         return unless $self->in_filter_route($node);
 864
 865                         # routing objects, force a PC21 if it is local
 866                         push @rout, $node->del($parent);
 867                         push @rout, $call if $dxchan && @rout == 0;
 868                 }
 869         } else {
 870                 dbg("PCPROT: I WILL _NOT_ be disconnected!") if isdbg('chanerr');
 871                 return;
 872         }
 873
 874         if (eph_dup($line)) {
 875                 return;
 876         }
 877
 878         if (@rout) {
 879                 $self->route_pc21($origin, $line, @rout);
 880 #               $self->route_pc92d($main::mycall, $line, $main::routeroot, @rout);
 881         }
 882 }
 883
 884
 885 sub handle_22
 886 {
 887         my $self = shift;
 888         my $pcno = shift;
 889         my $line = shift;
 890         my $origin = shift;
 891
 892         if ($self->{do_pc9x}) {
 893                 if ($self->{state} ne 'init92') {
 894                         $self->send("Reseting to oldstyle routing because login call not sent in any pc92");
 895                         $self->{do_pc9x} = 0;
 896                 }
 897         }
 898         $self->{lastping} = 0;
 899         $self->state('normal');
 900         $self->route_pc92a($main::mycall, undef, $main::routeroot, Route::Node::get($self->{call}));
 901 }
 902
 903 # WWV info
 904 sub handle_23
 905 {
 906         my $self = shift;
 907         my $pcno = shift;
 908         my $line = shift;
 909         my $origin = shift;
 910
 911         # route foreign' pc27s
 912         if ($pcno == 27) {
 913                 if ($_[8] ne $main::mycall) {
 914                         $self->route($_[8], $line);
 915                         return;
 916                 }
 917         }
 918
 919
 920         # do some de-duping
 921         my $d = cltounix($_[1], sprintf("%02d18Z", $_[2]));
 922         my $sfi = unpad($_[3]);
 923         my $k = unpad($_[4]);
 924         my $i = unpad($_[5]);
 925         my ($r) = $_[6] =~ /R=(\d+)/;
 926         $r = 0 unless $r;
 927         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $_[2] < 0 || $_[2] > 23) {
 928                 dbg("PCPROT: WWV Date ($_[1] $_[2]) out of range") if isdbg('chanerr');
 929                 return;
 930         }
 931
 932         # global wwv filtering on INPUT
 933         my @dxcc = ((Prefix::cty_data($_[7]))[0..2], (Prefix::cty_data($_[8]))[0..2]);
 934         if ($self->{inwwvfilter}) {
 935                 my ($filter, $hops) = $self->{inwwvfilter}->it(@_[7,8], $origin, @dxcc);
 936                 unless ($filter) {
 937                         dbg("PCPROT: Rejected by input wwv filter") if isdbg('chanerr');
 938                         return;
 939                 }
 940         }
 941         $_[7] =~ s/-\d+$//o;            # remove spotter's ssid
 942         if (Geomag::dup($d,$sfi,$k,$i,$_[6],$_[7])) {
 943                 dbg("PCPROT: Dup WWV Spot ignored\n") if isdbg('chanerr');
 944                 return;
 945         }
 946
 947         # note this only takes the first one it gets
 948         Geomag::update($d, $_[2], $sfi, $k, $i, @_[6..8], $r);
 949
 950         if (defined *Local::wwv) {
 951                 my $rep;
 952                 eval {
 953                         $rep = Local::wwv($self, $_[1], $_[2], $sfi, $k, $i, @_[6..8], $r);
 954                 };
 955                 return if $rep;
 956         }
 957
 958         # DON'T be silly and send on PC27s!
 959         return if $pcno == 27;
 960
 961         # broadcast to the eager world
 962         send_wwv_spot($self, $line, $d, $_[2], $sfi, $k, $i, @_[6..8]);
 963 }
 964
 965 # set here status
 966 sub handle_24
 967 {
 968         my $self = shift;
 969         my $pcno = shift;
 970         my $line = shift;
 971         my $origin = shift;
 972         my $call = uc $_[1];
 973         my ($nref, $uref);
 974         $nref = Route::Node::get($call);
 975         $uref = Route::User::get($call);
 976         return unless $nref || $uref; # if we don't know where they are, it's pointless sending it on
 977
 978         if (eph_dup($line)) {
 979                 return;
 980         }
 981
 982         $nref->here($_[2]) if $nref;
 983         $uref->here($_[2]) if $uref;
 984         my $ref = $nref || $uref;
 985         return unless $self->in_filter_route($ref);
 986
 987         $self->route_pc24($origin, $line, $ref, $_[3]);
 988 }
 989
 990 # merge request
 991 sub handle_25
 992 {
 993         my $self = shift;
 994         my $pcno = shift;
 995         my $line = shift;
 996         my $origin = shift;
 997         if ($_[1] ne $main::mycall) {
 998                 $self->route($_[1], $line);
 999                 return;
1000         }
1001         if ($_[2] eq $main::mycall) {
1002                 dbg("PCPROT: Trying to merge to myself, ignored") if isdbg('chanerr');
1003                 return;
1004         }
1005
1006         Log('DXProt', "Merge request for $_[3] spots and $_[4] WWV from $_[2]");
1007
1008         # spots
1009         if ($_[3] > 0) {
1010                 my @in = reverse Spot::search(1, undef, undef, 0, $_[3]);
1011                 my $in;
1012                 foreach $in (@in) {
1013                         $self->send(pc26(@{$in}[0..4], $_[2]));
1014                 }
1015         }
1016
1017         # wwv
1018         if ($_[4] > 0) {
1019                 my @in = reverse Geomag::search(0, $_[4], time, 1);
1020                 my $in;
1021                 foreach $in (@in) {
1022                         $self->send(pc27(@{$in}[0..5], $_[2]));
1023                 }
1024         }
1025 }
1026
1027 sub handle_26 {goto &handle_11}
1028 sub handle_27 {goto &handle_23}
1029
1030 # mail/file handling
1031 sub handle_28
1032 {
1033         my $self = shift;
1034         my $pcno = shift;
1035         my $line = shift;
1036         my $origin = shift;
1037         if ($_[1] eq $main::mycall) {
1038                 no strict 'refs';
1039                 my $sub = "DXMsg::handle_$pcno";
1040                 &$sub($self, @_);
1041         } else {
1042                 $self->route($_[1], $line) unless $self->is_clx;
1043         }
1044 }
1045
1046 sub handle_29 {goto &handle_28}
1047 sub handle_30 {goto &handle_28}
1048 sub handle_31 {goto &handle_28}
1049 sub handle_32 {goto &handle_28}
1050 sub handle_33 {goto &handle_28}
1051
1052 sub handle_34
1053 {
1054         my $self = shift;
1055         my $pcno = shift;
1056         my $line = shift;
1057         my $origin = shift;
1058         if (eph_dup($line, $eph_pc34_restime)) {
1059                 return;
1060         } else {
1061                 $self->process_rcmd($_[1], $_[2], $_[2], $_[3]);
1062         }
1063 }
1064
1065 # remote command replies
1066 sub handle_35
1067 {
1068         my $self = shift;
1069         my $pcno = shift;
1070         my $line = shift;
1071         my $origin = shift;
1072         eph_del_regex("^PC35\\^$_[2]\\^$_[1]\\^");
1073         $self->process_rcmd_reply($_[1], $_[2], $_[1], $_[3]);
1074 }
1075
1076 sub handle_36 {goto &handle_34}
1077
1078 # database stuff
1079 sub handle_37
1080 {
1081         my $self = shift;
1082         my $pcno = shift;
1083         my $line = shift;
1084         my $origin = shift;
1085         if ($_[1] eq $main::mycall) {
1086                 no strict 'refs';
1087                 my $sub = "DXDb::handle_$pcno";
1088                 &$sub($self, @_);
1089         } else {
1090                 $self->route($_[1], $line) unless $self->is_clx;
1091         }
1092 }
1093
1094 # node connected list from neighbour
1095 sub handle_38
1096 {
1097         my $self = shift;
1098         my $pcno = shift;
1099         my $line = shift;
1100         my $origin = shift;
1101 }
1102
1103 # incoming disconnect
1104 sub handle_39
1105 {
1106         my $self = shift;
1107         my $pcno = shift;
1108         my $line = shift;
1109         my $origin = shift;
1110         if ($_[1] eq $self->{call}) {
1111                 $self->disconnect(1);
1112         } else {
1113                 dbg("PCPROT: came in on wrong channel") if isdbg('chanerr');
1114         }
1115 }
1116
1117 sub handle_40 {goto &handle_28}
1118
1119 # user info
1120 sub handle_41
1121 {
1122         my $self = shift;
1123         my $pcno = shift;
1124         my $line = shift;
1125         my $origin = shift;
1126         my $call = $_[1];
1127         my $sort = $_[2];
1128         my $val = $_[3];
1129
1130         my $l = "PC41^$call^$sort";
1131         if (eph_dup($l, $eph_info_restime)) {
1132                 return;
1133         }
1134
1135         # input filter if required
1136         #                       my $ref = Route::get($call) || Route->new($call);
1137         #                       return unless $self->in_filter_route($ref);
1138
1139         if ($val eq $sort || $val =~ /^\s*$/) {
1140                 dbg('PCPROT: invalid value') if isdbg('chanerr');
1141                 return;
1142         }
1143
1144         # add this station to the user database, if required
1145         my $user = DXUser->get_current($call);
1146         $user = DXUser->new($call) unless $user;
1147
1148         if ($sort == 1) {
1149                 if (($val =~ /spotter/i || $val =~ /self/i) && $user->name && $user->name ne $val) {
1150                         dbg("PCPROT: invalid name") if isdbg('chanerr');
1151                         if ($main::mycall eq 'GB7DJK' || $main::mycall eq 'GB7BAA' || $main::mycall eq 'WR3D') {
1152                                 DXChannel::broadcast_nodes(pc41($_[1], 1, $user->name)); # send it to everyone including me
1153                         }
1154                         return;
1155                 }
1156                 $user->name($val);
1157         } elsif ($sort == 2) {
1158                 $user->qth($val);
1159         } elsif ($sort == 3) {
1160                 if (is_latlong($val)) {
1161                         my ($lat, $long) = DXBearing::stoll($val);
1162                         $user->lat($lat) if $lat;
1163                         $user->long($long) if $long;
1164                         $user->qra(DXBearing::lltoqra($lat, $long)) unless $user->qra;
1165                 } else {
1166                         dbg('PCPROT: not a valid lat/long') if isdbg('chanerr');
1167                         return;
1168                 }
1169         } elsif ($sort == 4) {
1170                 $user->homenode($val);
1171         } elsif ($sort == 5) {
1172                 if (is_qra(uc $val)) {
1173                         my ($lat, $long) = DXBearing::qratoll(uc $val);
1174                         $user->lat($lat) if $lat && !$user->lat;
1175                         $user->long($long) if $long && !$user->long;
1176                         $user->qra(uc $val);
1177                 } else {
1178                         dbg('PCPROT: not a valid QRA locator') if isdbg('chanerr');
1179                         return;
1180                 }
1181         }
1182         $user->lastoper($main::systime); # to cut down on excessive for/opers being generated
1183         $user->put;
1184
1185         unless ($self->{isolate}) {
1186                 DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1187         }
1188
1189         #  perhaps this IS what we want after all
1190         #                       $self->route_pc41($ref, $call, $sort, $val, $_[4]);
1191 }
1192
1193 sub handle_42 {goto &handle_28}
1194
1195
1196 # database
1197 sub handle_44 {goto &handle_37}
1198 sub handle_45 {goto &handle_37}
1199 sub handle_46 {goto &handle_37}
1200 sub handle_47 {goto &handle_37}
1201 sub handle_48 {goto &handle_37}
1202
1203 # message and database
1204 sub handle_49
1205 {
1206         my $self = shift;
1207         my $pcno = shift;
1208         my $line = shift;
1209         my $origin = shift;
1210
1211         if (eph_dup($line)) {
1212                 return;
1213         }
1214
1215         if ($_[1] eq $main::mycall) {
1216                 DXMsg::handle_49($self, @_);
1217         } else {
1218                 $self->route($_[1], $line) unless $self->is_clx;
1219         }
1220 }
1221
1222 # keep alive/user list
1223 sub handle_50
1224 {
1225         my $self = shift;
1226         my $pcno = shift;
1227         my $line = shift;
1228         my $origin = shift;
1229
1230         return if (eph_dup($line));
1231
1232         my $call = $_[1];
1233
1234         RouteDB::update($call, $self->{call});
1235
1236         my $node = Route::Node::get($call);
1237         if ($node) {
1238                 return unless $node->call eq $self->{call};
1239                 $node->usercount($_[2]) unless $node->users;
1240                 $node->reset_obs;
1241
1242                 # input filter if required
1243 #               return unless $self->in_filter_route($node);
1244
1245                 unless ($self->{isolate}) {
1246                         DXChannel::broadcast_nodes($line, $self); # send it to everyone but me
1247                 }
1248 #               $self->route_pc50($origin, $line, $node, $_[2], $_[3]) unless eph_dup($line);
1249         }
1250 }
1251
1252 # incoming ping requests/answers
1253 sub handle_51
1254 {
1255         my $self = shift;
1256         my $pcno = shift;
1257         my $line = shift;
1258         my $origin = shift;
1259         my $to = $_[1];
1260         my $from = $_[2];
1261         my $flag = $_[3];
1262
1263
1264         # is it for us?
1265         if ($to eq $main::mycall) {
1266                 if ($flag == 1) {
1267                         $self->send(pc51($from, $to, '0'));
1268                 } else {
1269                         DXXml::Ping::handle_ping_reply($self, $from);
1270                 }
1271         } else {
1272
1273                 RouteDB::update($from, $self->{call});
1274
1275                 if (eph_dup($line)) {
1276                         return;
1277                 }
1278                 # route down an appropriate thingy
1279                 $self->route($to, $line);
1280         }
1281 }
1282
1283 sub handle_61 { goto &handle_11; }
1284
1285 # dunno but route it
1286 sub handle_75
1287 {
1288         my $self = shift;
1289         my $pcno = shift;
1290         my $line = shift;
1291         my $origin = shift;
1292         my $call = $_[1];
1293         if ($call ne $main::mycall) {
1294                 $self->route($call, $line);
1295         }
1296 }
1297
1298 # WCY broadcasts
1299 sub handle_73
1300 {
1301         my $self = shift;
1302         my $pcno = shift;
1303         my $line = shift;
1304         my $origin = shift;
1305         my $call = $_[1];
1306
1307         # do some de-duping
1308         my $d = cltounix($call, sprintf("%02d18Z", $_[2]));
1309         if (($pcno == 23 && $d < $main::systime - $pc23_max_age) || $d > $main::systime + 1500 || $_[2] < 0 || $_[2] > 23) {
1310                 dbg("PCPROT: WCY Date ($call $_[2]) out of range") if isdbg('chanerr');
1311                 return;
1312         }
1313         @_ = map { unpad($_) } @_;
1314         if (WCY::dup($d)) {
1315                 dbg("PCPROT: Dup WCY Spot ignored\n") if isdbg('chanerr');
1316                 return;
1317         }
1318
1319         my $wcy = WCY::update($d, @_[2..12]);
1320
1321         if (defined *Local::wcy) {
1322                 my $rep;
1323                 eval {
1324                         $rep = Local::wcy($self, @_[1..12]);
1325                 };
1326                 return if $rep;
1327         }
1328
1329         # broadcast to the eager world
1330         send_wcy_spot($self, $line, $d, @_[2..12]);
1331 }
1332
1333 # remote commands (incoming)
1334 sub handle_84
1335 {
1336         my $self = shift;
1337         my $pcno = shift;
1338         my $line = shift;
1339         my $origin = shift;
1340         $self->process_rcmd($_[1], $_[2], $_[3], $_[4]);
1341 }
1342
1343 # remote command replies
1344 sub handle_85
1345 {
1346         my $self = shift;
1347         my $pcno = shift;
1348         my $line = shift;
1349         my $origin = shift;
1350         $self->process_rcmd_reply($_[1], $_[2], $_[3], $_[4]);
1351 }
1352
1353 # decode a pc92 call: flag call : version : build
1354 sub _decode_pc92_call
1355 {
1356         my $icall = shift;
1357         my @part = split /:/, $icall;
1358         my ($flag, $call) = unpack "A A*", $part[0];
1359         unless (defined $flag && $flag ge '0' && $flag le '7') {
1360                 dbg("PCPROT: $icall no flag byte (0-7) at front of call, ignored") if isdbg('chanerr');
1361                 return ();
1362         }
1363         unless ($call && is_callsign($call)) {
1364                 dbg("PCPROT: $icall no recognisable callsign, ignored") if isdbg('chanerr');
1365                 return ();
1366         }
1367         my $is_node = $flag & 4;
1368         my $is_extnode = $flag & 2;
1369         my $here = $flag & 1;
1370         return ($call, $is_node, $is_extnode, $here, $part[1], $part[2]);
1371 }
1372
1373 # decode a pc92 call: flag call : version : build
1374 sub _encode_pc92_call
1375 {
1376         my $ref = shift;
1377
1378         # plain call or value
1379         return $ref unless ref $ref;
1380
1381         my $ext = shift;
1382         my $flag = 0;
1383         my $call = $ref->call;
1384         my $extra = '';
1385         $flag |= $ref->here ? 1 : 0;
1386         if ($ref->isa('Route::Node') || $ref->isa('DXProt')) {
1387                 $flag |= 4;
1388                 my $dxchan = DXChannel::get($call);
1389                 $flag |= 2 if $call ne $main::mycall && $dxchan && !$dxchan->{do_pc9x};
1390                 if ($ext) {
1391                         if ($ref->version) {
1392                                 my $version = $ref->version || 1.0;
1393                                 $version =  $version * 100 + 5300 if $version < 50;
1394                                 $extra .= ":" . $version;
1395                         }
1396                 }
1397         }
1398         return "$flag$call$extra";
1399 }
1400
1401 my %things_add;
1402 my %things_del;
1403
1404 sub _add_thingy
1405 {
1406         my $parent = shift;
1407         my $s = shift;
1408         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1409         my @rout;
1410
1411         if ($call) {
1412                 if ($is_node) {
1413                         dbg("ROUTE: added node $call to " . $parent->call) if isdbg('routelow');
1414                         @rout = $parent->add($call, $version, Route::here($here));
1415                 } else {
1416                         dbg("ROUTE: added user $call to " . $parent->call) if isdbg('routelow');
1417                         @rout = $parent->add_user($call, Route::here($here));
1418                 }
1419                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1420                         $things_add{$call} = Route::get($call);
1421                         delete $things_del{$call};
1422                 }
1423         }
1424         return @rout;
1425 }
1426
1427 sub _del_thingy
1428 {
1429         my $parent = shift;
1430         my $s = shift;
1431         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$s;
1432         my @rout;
1433         if ($call) {
1434                 my $ref;
1435                 if ($is_node) {
1436                         $ref = Route::Node::get($call);
1437                         dbg("ROUTE: deleting node $call from " . $parent->call) if isdbg('routelow');
1438                         @rout = $ref->del($parent) if $ref;
1439                 } else {
1440                         $ref = Route::User::get($call);
1441                         dbg("ROUTE: deleting user $call from " . $parent->call) if isdbg('routelow');
1442                         @rout = $parent->del_user($ref) if $ref;
1443                 }
1444                 if ($pc92_slug_changes && $parent == $main::routeroot) {
1445                         $things_del{$call} = $ref unless exists $things_add{$call};
1446                         delete $things_add{$call};
1447                 }
1448         }
1449         return @rout;
1450 }
1451
1452 # this will only happen if we are slugging changes and
1453 # there are some changes to be sent, it will create an add or a delete
1454 # or both
1455 sub gen_pc92_changes
1456 {
1457         my @add = values %things_add;
1458         my @del = values %things_del;
1459         return (\@add, \@del);
1460 }
1461
1462 sub clear_pc92_changes
1463 {
1464         %things_add = %things_del = ();
1465         $last_pc92_slug = $main::systime;
1466 }
1467
1468 my $_last_time;
1469 my $_last_occurs;
1470 my $_last_pc9x_id;
1471
1472 sub last_pc9x_id
1473 {
1474         return $_last_pc9x_id;
1475 }
1476
1477 sub gen_pc9x_t
1478 {
1479         if (!$_last_time || $_last_time != $main::systime) {
1480                 $_last_time = $main::systime;
1481                 $_last_occurs = 0;
1482                 return $_last_pc9x_id = $_last_time - $main::systime_daystart;
1483         } else {
1484                 $_last_occurs++;
1485                 return $_last_pc9x_id = sprintf "%d.%02d", $_last_time - $main::systime_daystart, $_last_occurs;
1486         }
1487 }
1488
1489 sub check_pc9x_t
1490 {
1491         my $call = shift;
1492         my $t = shift;
1493         my $pc = shift;
1494         my $create = shift;
1495
1496         # check that the time is between 0 >= $t < 86400
1497         unless ($t >= 0 && $t < 86400) {
1498                 dbg("PCPROT: time invalid t: $t, ignored") if isdbg('chanerr');
1499                 return undef;
1500         }
1501
1502         # check that the time of this pc9x is within tolerance (default 15 mins either way)
1503         my $now = $main::systime - $main::systime_daystart ;
1504         my $diff = abs($now - $t);
1505         unless ($diff < $pc9x_time_tolerance || 86400 - $diff < $pc9x_time_tolerance) {
1506                 my $c = ref $call ? $call->call : $call;
1507                 dbg("PC9XERR: $c time out of range t: $t now: $now diff: $diff > $pc9x_time_tolerance, ignored") if isdbg('chan');
1508                 return undef;
1509         }
1510
1511         my $parent = ref $call ? $call : Route::Node::get($call);
1512         if ($parent) {
1513                 # we only do this for external calls whose routing table
1514                 # record come and go. The reference for mycall is permanent
1515                 # and not that frequently used, it also never times out, so
1516                 # the id on it is completely unreliable. Besides, only commands
1517                 # originating on this box will go through this code...
1518                 if ($parent->call ne $main::mycall) {
1519                         my $lastid = $parent->lastid;
1520                         if (defined $lastid) {
1521                                 if ($t < $lastid) {
1522                                         # note that this is where we determine whether this pc9x has come in yesterday
1523                                         # but is still greater (modulo 86400) than the lastid or is simply an old
1524                                         # duplicate sentence. To determine this we need to do some module 86400
1525                                         # arithmetic. High numbers mean that this is an old duplicate sentence,
1526                                         # low numbers that it is a new sentence.
1527                                         #
1528                                         # Typically you will see yesterday being taken on $t = 84, $lastid = 86235
1529                                         # and old dupes with $t = 234, $lastid = 256 (which give answers 249 and
1530                                         # 86378 respectively in the calculation below).
1531                                         #
1532                                         if ($t+86400-$lastid > $pc9x_past_age) {
1533                                                 dbg("PCPROT: dup id on $t <= lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1534                                                 return undef;
1535                                         }
1536                                 } elsif ($t == $lastid) {
1537                                         dbg("PCPROT: dup id on $t == lastid $lastid, ignored") if isdbg('chanerr') || isdbg('pc92dedupe');
1538                                         return undef;
1539                                 }
1540                         }
1541                 }
1542         } elsif ($create) {
1543                 $parent = Route::Node->new($call);
1544         } else {
1545                 dbg("PCPROT: $call does not exist, ignored") if isdbg('pc92dedupe');
1546                 return undef;
1547         }
1548         if (isdbg('pc92dedupe')) {
1549                 my $exists = exists $parent->{lastid}; # naughty, naughty :-)
1550                 my $val = $parent->{lastid};
1551                 my $s = $exists ? (defined $val ? $val : 'exists/undef') : 'undef';
1552                 dbg("PCPROT: $call pc92 id lastid $s -> $t");
1553         }
1554         $parent->lastid($t);
1555
1556         return $parent;
1557 }
1558
1559 sub pc92_handle_first_slot
1560 {
1561         my $self = shift;
1562         my $slot = shift;
1563         my $parent = shift;
1564         my $t = shift;
1565         my $oparent = $parent;
1566
1567         my @radd;
1568
1569         my ($call, $is_node, $is_extnode, $here, $version, $build) = @$slot;
1570         if ($call && $is_node) {
1571                 if ($call eq $main::mycall) {
1572                         dbg("PCPROT: $call looped back onto $main::mycall, ignored") if isdbg('chanerr');
1573                         return;
1574                 }
1575                 # this is only accepted from my "self".
1576                 # this also kills configs from PC92 nodes with external PC19 nodes that are also
1577                 # locally connected. Local nodes always take precedence. But we remember the lastid
1578                 # to try to reduce the number of dupe PC92s for this external node.
1579                 if (DXChannel::get($call) && $call ne $self->{call}) {
1580                         $parent = check_pc9x_t($call, $t, 92); # this will update the lastid time
1581                         dbg("PCPROT: locally connected node $call from other another node $self->{call}, ignored") if isdbg('chanerr');
1582                         return;
1583                 }
1584                 if ($is_extnode) {
1585                         # reparent to external node (note that we must have received a 'C' or 'A' record
1586                         # from the true parent node for this external before we get one for the this node
1587                         unless ($parent = Route::Node::get($call)) {
1588                                 if ($is_extnode && $oparent) {
1589                                         @radd = _add_thingy($oparent, $slot);
1590                                         $parent = $radd[0];
1591                                 } else {
1592                                         dbg("PCPROT: no previous C or A for this external node received, ignored") if isdbg('chanerr');
1593                                         return;
1594                                 }
1595                         }
1596                         $parent = check_pc9x_t($call, $t, 92) || return;
1597                         $parent->via_pc92(1);
1598                         $parent->PC92C_dxchan($self->{call});
1599                 }
1600         } else {
1601                 dbg("PCPROT: must be \$mycall or external node as first entry, ignored") if isdbg('chanerr');
1602                 return;
1603         }
1604         $parent->here(Route::here($here));
1605         $parent->version($version || $pc19_version) if $version;
1606         $parent->build($build) if $build;
1607         $parent->PC92C_dxchan($self->{call}) unless $self->{call} eq $parent->call;
1608         return ($parent, @radd);
1609 }
1610
1611 # DXSpider routing entries
1612 sub handle_92
1613 {
1614         my $self = shift;
1615         my $pcno = shift;
1616         my $line = shift;
1617         my $origin = shift;
1618
1619         my (@radd, @rdel);
1620
1621         my $pcall = $_[1];
1622         my $t = $_[2];
1623         my $sort = $_[3];
1624
1625         # this catches loops of A/Ds
1626 #       if (eph_dup($line, $pc9x_dupe_age)) {
1627 #               return;
1628 #       }
1629
1630         if ($pcall eq $main::mycall) {
1631                 dbg("PCPROT: looped back, ignored") if isdbg('chanerr');
1632                 return;
1633         }
1634
1635         if ($pcall eq $self->{call} && $self->{state} eq 'init') {
1636                 if ($self->{isolate}) {
1637                         dbg("PC9x received, but $pcall is isolated, ignored");
1638                         return;
1639                 } elsif (!$self->user->wantpc9x) {
1640                         dbg("PC9x explicitly switched off on $pcall, ignored");
1641                         return;
1642                 } else {
1643                         $self->state('init92');
1644                         $self->{do_pc9x} = 1;
1645                         dbg("Do pc9x set on $pcall");
1646                 }
1647         }
1648         unless ($self->{do_pc9x}) {
1649                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1650                 return;
1651         }
1652
1653         # don't create routing entries for D records that don't already exist
1654         # this is what causes all those PC92 loops!
1655         my $parent = check_pc9x_t($pcall, $t, 92, $sort ne 'D') || return;
1656         my $oparent = $parent;
1657
1658         $parent->do_pc9x(1);
1659         $parent->via_pc92(1);
1660
1661         if ($sort eq 'F' || $sort eq 'R') {
1662
1663                 # this is the route finding section
1664                 # here is where the consequences of the 'find' command
1665                 # are dealt with
1666
1667                 my $from = $_[4];
1668                 my $target = $_[5];
1669
1670                 if ($sort eq 'F') {
1671                         my $flag;
1672                         my $ref;
1673                         my $dxchan;
1674                         if ($ref = DXChannel::get($target)) {
1675                                 $flag = 1;              # we are directly connected
1676                         } else {
1677                                 $ref = Route::get($target);
1678                                 $dxchan = $ref->dxchan;
1679                                 $flag = 2;
1680                         }
1681                         if ($ref && $flag && $dxchan) {
1682                                 $self->send(pc92r($from, $target, $flag, int($dxchan->{pingave}*1000)));
1683                                 return;
1684                         }
1685                 } elsif ($sort eq 'R') {
1686                         if (my $dxchan = DXChannel::get($from)) {
1687                                 handle_pc92_find_reply($dxchan, $pcall, $from, $target, @_[6,7]);
1688                         } else {
1689                                 my $ref = Route::get($from);
1690                                 if ($ref) {
1691                                         my @dxchan = grep {$_->do_pc9x} $ref->alldxchan;
1692                                         if (@dxchan) {
1693                                                 $_->send($line) for @dxchan;
1694                                         } else {
1695                                                 dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1696                                         }
1697                                 } else {
1698                                         dbg("PCPROT: no return route, ignored") if isdbg('chanerr')
1699                                 }
1700                         }
1701                         return;
1702                 }
1703
1704         } elsif ($sort eq 'K') {
1705                 $pc92Kin += length $line if $sort eq 'K';
1706
1707                 # remember the last channel we arrived on
1708                 $parent->PC92C_dxchan($self->{call}) unless $self->{call} eq $parent->call;
1709
1710                 my @ent = _decode_pc92_call($_[4]);
1711
1712                 if (@ent) {
1713                         my $add;
1714
1715                         ($parent, $add) = $self->pc92_handle_first_slot(\@ent, $parent, $t);
1716                         return unless $parent; # dupe
1717
1718                         push @radd, $add if $add;
1719                         $parent->reset_obs;
1720                         $parent->version($ent[4]) if $ent[4];
1721                         $parent->build($ent[5]) if $ent[5];
1722
1723                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1724                 }
1725         } elsif ($sort eq 'A' || $sort eq 'D' || $sort eq 'C') {
1726
1727                 $pc92Ain += length $line if $sort eq 'A';
1728                 $pc92Cin += length $line if $sort eq 'C';
1729                 $pc92Din += length $line if $sort eq 'D';
1730
1731                 # remember the last channel we arrived on
1732                 $parent->PC92C_dxchan($self->{call}) unless $self->{call} eq $parent->call;
1733
1734                 # this is the main route section
1735                 # here is where all the routes are created and destroyed
1736
1737                 # cope with missing duplicate node calls in the first slot
1738                 my $me = $_[4] || '';
1739                 $me ||= _encode_pc92_call($parent) unless $me ;
1740
1741                 my @ent = map {my @a = _decode_pc92_call($_); @a ? \@a : ()} grep {$_ && /^[0-7]/} $me, @_[5 .. $#_];
1742
1743                 if (@ent) {
1744
1745                         # look at the first one which will always be a node of some sort
1746                         # except in the case of 'A' or 'D' in which the $pcall is used
1747                         # otherwise use the node call and update any information
1748                         # that needs to be done.
1749                         my $add;
1750
1751                         ($parent, $add) = $self->pc92_handle_first_slot($ent[0], $parent, $t);
1752                         return unless $parent; # dupe
1753
1754                         shift @ent;
1755                         push @radd, $add if $add;
1756                 }
1757
1758                 # do a pass through removing any references to either locally connected nodes or mycall
1759                 my @nent;
1760                 for (@ent) {
1761                         next unless $_ && @$_;
1762                         if ($_->[0] eq $main::mycall || DXChannel::get($_->[0])) {
1763                                 dbg("PCPROT: $_->[0] refers to locally connected node, ignored") if isdbg('chanerr');
1764                                 next;
1765                         }
1766                         push @nent, $_;
1767                 }
1768
1769                 if ($sort eq 'A') {
1770                         for (@nent) {
1771                                 push @radd, _add_thingy($parent, $_);
1772                         }
1773                 } elsif ($sort eq 'D') {
1774                         for (@nent) {
1775                                 push @rdel, _del_thingy($parent, $_);
1776                         }
1777                 } elsif ($sort eq 'C') {
1778                         my (@nodes, @users);
1779
1780                         # we reset obscounts on config records as well as K records
1781                         $parent->reset_obs;
1782                         dbg("ROUTE: reset obscount on $parent->{call} now " . $parent->obscount) if isdbg('obscount');
1783
1784                         #
1785                         foreach my $r (@nent) {
1786                                 #                       my ($call, $is_node, $is_extnode, $here, $version, $build) = _decode_pc92_call($_);
1787                                 if ($r->[0]) {
1788                                         if ($r->[1]) {
1789                                                 push @nodes, $r->[0];
1790                                         } else {
1791                                                 push @users, $r->[0];
1792                                         }
1793                                 } else {
1794                                         dbg("PCPROT: pc92 call entry '$_' not decoded, ignored") if isdbg('chanerr');
1795                                 }
1796                         }
1797
1798                         my ($dnodes, $dusers, $nnodes, $nusers) = $parent->calc_config_changes(\@nodes, \@users);
1799
1800                         # add users here
1801                         foreach my $r (@nent) {
1802                                 my $call = $r->[0];
1803                                 if ($call) {
1804                                         push @radd,_add_thingy($parent, $r) if grep $call eq $_, (@$nnodes, @$nusers);
1805                                 }
1806                         }
1807                         # del users here
1808                         foreach my $r (@$dnodes) {
1809                                 push @rdel,_del_thingy($parent, [$r, 1]);
1810                         }
1811                         foreach my $r (@$dusers) {
1812                                 push @rdel,_del_thingy($parent, [$r, 0]);
1813                         }
1814
1815                         # remember this last PC92C for rebroadcast on demand
1816                         $parent->last_PC92C($line);
1817                 } else {
1818                         dbg("PCPROT: unknown action '$sort', ignored") if isdbg('chanerr');
1819                         return;
1820                 }
1821
1822                 foreach my $r (@rdel) {
1823                         next unless $r;
1824
1825                         $self->route_pc21($pcall, undef, $r) if $r->isa('Route::Node');
1826                         $self->route_pc17($pcall, undef, $parent, $r) if $r->isa('Route::User');
1827                 }
1828                 my @pc19 = grep { $_ && $_->isa('Route::Node') } @radd;
1829                 my @pc16 = grep { $_ && $_->isa('Route::User') } @radd;
1830                 unshift @pc19, $parent if $self->{state} eq 'init92' && $oparent == $parent;
1831                 $self->route_pc19($pcall, undef, @pc19) if @pc19;
1832                 $self->route_pc16($pcall, undef, $parent, @pc16) if @pc16;
1833         }
1834
1835         # broadcast it if we get here
1836         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1837 }
1838
1839
1840 sub handle_93
1841 {
1842         my $self = shift;
1843         my $pcno = shift;
1844         my $line = shift;
1845         my $origin = shift;
1846
1847 #       $self->{do_pc9x} ||= 1;
1848
1849         my $pcall = $_[1];                      # this is now checked earlier
1850
1851         # remember that we are converting PC10->PC93 and self will be $main::me if it
1852         # comes from us
1853         unless ($self->{do_pc9x}) {
1854                 dbg("PCPROT: PC9x come in from non-PC9x node, ignored") if isdbg('chanerr');
1855                 return;
1856         }
1857
1858         my $t = $_[2];
1859         my $parent = check_pc9x_t($pcall, $t, 93, 1) || return;
1860
1861         my $to = uc $_[3];
1862         my $from = uc $_[4];
1863         my $via = uc $_[5];
1864         my $text = $_[6];
1865         my $onode = uc $_[7];
1866         $onode = $pcall if @_ <= 8;
1867
1868         # this is catch loops caused by bad software ...
1869         if (eph_dup("PC93|$from|$text|$onode", $pc10_dupe_age)) {
1870                 return;
1871         }
1872
1873         # will we allow it at all?
1874         if ($censorpc) {
1875                 my @bad;
1876                 if (@bad = BadWords::check($text)) {
1877                         dbg("PCPROT: Bad words: @bad, dropped") if isdbg('chanerr');
1878                         return;
1879                 }
1880         }
1881
1882         # if this is a 'bad spotter' user then ignore it
1883         my $nossid = $from;
1884         $nossid =~ s/-\d+$//;
1885         if ($badspotter->in($nossid)) {
1886                 dbg("PCPROT: Bad Spotter, dropped") if isdbg('chanerr');
1887                 return;
1888         }
1889
1890         # ignore PC93 coming in from outside this node with a target of local
1891         if ($to eq 'LOCAL' && $self != $main::me) {
1892                 dbg("PCPROT: incoming LOCAL chat not from local node, ignored") if isdbg('chanerr');
1893                 return;
1894         }
1895
1896         # if it is routeable then then treat it like a talk
1897         my $ref = Route::get($to);
1898         if ($ref) {
1899                 # local talks
1900                 my $dxchan;
1901                 $dxchan = DXChannel::get($main::myalias) if $to eq $main::mycall;
1902                 $dxchan = DXChannel::get($to) unless $dxchan;
1903                 # check it...
1904                 if ($dxchan) {
1905                         if (ref $dxchan && $dxchan->isa('DXChannel')) {
1906                                 if ($dxchan->is_user) {
1907                                         $dxchan->talk($from, $to, $via, $text, $onode);
1908                                         return;
1909                                 }
1910                         } else {
1911                                 dbg("ERROR: $to -> $dxchan is not a DXChannel! (local talk)");
1912                         }
1913                 }
1914
1915                 # convert to PC10 talks where appropriate
1916                 # just go for the "best" one for now (rather than broadcast)
1917                 $dxchan = $ref->dxchan;
1918
1919                 # check it...
1920                 if (ref $dxchan && $dxchan->isa('DXChannel')) {
1921                         if ($dxchan->{do_pc9x}) {
1922                                 $dxchan->send($line);
1923                         } else {
1924                                 $dxchan->talk($from, $to, $via, $text, $onode);
1925                         }
1926                 } else {
1927                         dbg("ERROR: $to -> $dxchan is not a DXChannel! (convert to pc10)");
1928                 }
1929                 return;
1930
1931         } elsif ($to eq '*' || $to eq 'SYSOP' || $to eq 'WX') {
1932                 # announces
1933                 my $sysop = $to eq 'SYSOP' ? '*' : ' ';
1934                 my $wx = $to eq 'WX' ? '1' : '0';
1935                 my $local = $via eq 'LOCAL' ? '*' : $via;
1936
1937                 $self->send_announce(1, pc12($from, $text, $local, $sysop, $wx, $pcall), $from, $local, $text, $sysop, $pcall, $wx, $via eq 'LOCAL' ? $via : undef);
1938                 return if $via eq 'LOCAL';
1939         } elsif (!is_callsign($to) && $text =~ /^#\d+ /) {
1940                 # chat messages to non-pc9x nodes
1941                 $self->send_chat(1, pc12($from, $text, undef, $to, undef, $pcall), $from, '*', $text, $to, $pcall, '0');
1942         }
1943
1944         # broadcast this chat sentence everywhere unless it is targetted to 'LOCAL'
1945         $self->broadcast_route_pc9x($pcall, undef, $line, 0) unless $to eq 'LOCAL' || $via eq 'LOCAL';
1946 }
1947
1948 # if get here then rebroadcast the thing with its Hop count decremented (if
1949 # there is one). If it has a hop count and it decrements to zero then don't
1950 # rebroadcast it.
1951 #
1952 # NOTE - don't arrive here UNLESS YOU WANT this lump of protocol to be
1953 #        REBROADCAST!!!!
1954 #
1955
1956 sub handle_default
1957 {
1958         my $self = shift;
1959         my $pcno = shift;
1960         my $line = shift;
1961         my $origin = shift;
1962
1963         unless (eph_dup($line)) {
1964                 if ($pcno >= 90) {
1965                         my $pcall = $_[1];
1966                         unless (is_callsign($pcall)) {
1967                                 dbg("PCPROT: invalid callsign string '$_[1]', ignored") if isdbg('chanerr');
1968                                 return;
1969                         }
1970                         my $t = $_[2];
1971                         my $parent = check_pc9x_t($pcall, $t, $pcno, 1) || return;
1972                         $self->broadcast_route_pc9x($pcall, undef, $line, 0);
1973                 } else {
1974                         unless ($self->{isolate}) {
1975                                 DXChannel::broadcast_nodes($line, $self) if $line =~ /\^H\d+\^?~?$/; # send it to everyone but me
1976                         }
1977                 }
1978         }
1979 }
1980
1981 1;