perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35
  36 use strict;
  37 use vars qw(%channels %valid @ISA $count);
  38
  39 %channels = ();
  40 $count = 0;
  41
  42 %valid = (
  43                   call => '0,Callsign',
  44                   conn => '9,Msg Conn ref',
  45                   user => '9,DXUser ref',
  46                   startt => '0,Start Time,atime',
  47                   t => '9,Time,atime',
  48                   pc50_t => '5,Last PC50 Time,atime',
  49                   priv => '9,Privilege',
  50                   state => '0,Current State',
  51                   oldstate => '5,Last State',
  52                   list => '9,Dep Chan List',
  53                   name => '0,User Name',
  54                   consort => '5,Connection Type',
  55                   'sort' => '5,Type of Channel',
  56                   wwv => '0,Want WWV,yesno',
  57                   wcy => '0,Want WCY,yesno',
  58                   wx => '0,Want WX,yesno',
  59                   talk => '0,Want Talk,yesno',
  60                   ann => '0,Want Announce,yesno',
  61                   here => '0,Here?,yesno',
  62                   conf => '0,In Conference?,yesno',
  63                   dx => '0,DX Spots,yesno',
  64                   redirect => '0,Redirect messages to',
  65                   lang => '0,Language',
  66                   func => '5,Function',
  67                   loc => '9,Local Vars', # used by func to store local variables in
  68                   beep => '0,Want Beeps,yesno',
  69                   lastread => '5,Last Msg Read',
  70                   outbound => '5,outbound?,yesno',
  71                   remotecmd => '9,doing rcmd,yesno',
  72                   pagelth => '0,Page Length',
  73                   pagedata => '9,Page Data Store',
  74                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  75                   isolate => '5,Isolate network,yesno',
  76                   delayed => '5,Delayed messages,parray',
  77                   annfilter => '5,Announce Filter',
  78                   wwvfilter => '5,WWV Filter',
  79                   wcyfilter => '5,WCY Filter',
  80                   spotsfilter => '5,Spot Filter',
  81                   routefilter => '5,route Filter',
  82                   inannfilter => '5,Input Ann Filter',
  83                   inwwvfilter => '5,Input WWV Filter',
  84                   inwcyfilter => '5,Input WCY Filter',
  85                   inspotsfilter => '5,Input Spot Filter',
  86                   inroutefilter => '5,Input Route Filter',
  87                   passwd => '9,Passwd List,parray',
  88                   pingint => '5,Ping Interval ',
  89                   nopings => '5,Ping Obs Count',
  90                   lastping => '5,Ping last sent,atime',
  91                   pingtime => '5,Ping totaltime,parray',
  92                   pingave => '0,Ping ave time',
  93                   logininfo => '9,Login info req,yesno',
  94                   talklist => '0,Talk List,parray',
  95                   cluster => '5,Cluster data',
  96                   isbasic => '9,Internal Connection',
  97                   errors => '9,Errors',
  98                   route => '9,Route Data',
  99                   dxcc => '0,Country Code',
 100                   itu => '0,ITU Zone',
 101                   cq => '0,CQ Zone',
 102                  );
 103
 104 # object destruction
 105 sub DESTROY
 106 {
 107         my $self = shift;
 108         for (keys %$self) {
 109                 if (ref($self->{$_})) {
 110                         delete $self->{$_};
 111                 }
 112         }
 113         dbg('chan', "DXChannel $self->{call} destroyed ($count)");
 114         $count--;
 115 }
 116
 117 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 118 sub alloc
 119 {
 120         my ($pkg, $call, $conn, $user) = @_;
 121         my $self = {};
 122
 123         die "trying to create a duplicate channel for $call" if $channels{$call};
 124         $self->{call} = $call;
 125         $self->{priv} = 0;
 126         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 127         if (defined $user) {
 128                 $self->{user} = $user;
 129                 $self->{lang} = $user->lang;
 130                 $user->new_group() if !$user->group;
 131                 $self->{group} = $user->group;
 132                 $self->{sort} = $user->sort;
 133         }
 134         $self->{startt} = $self->{t} = time;
 135         $self->{state} = 0;
 136         $self->{oldstate} = 0;
 137         $self->{lang} = $main::lang if !$self->{lang};
 138         $self->{func} = "";
 139
 140         # add in all the dxcc, itu, zone info
 141         my @dxcc = Prefix::extract($call);
 142         if (@dxcc > 0) {
 143                 $self->{dxcc} = $dxcc[1]->dxcc;
 144                 $self->{itu} = $dxcc[1]->itu;
 145                 $self->{cq} = $dxcc[1]->cq;
 146         }
 147
 148         $count++;
 149         dbg('chan', "DXChannel $self->{call} created ($count)");
 150         bless $self, $pkg;
 151         return $channels{$call} = $self;
 152 }
 153
 154 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 155 sub get
 156 {
 157         my ($pkg, $call) = @_;
 158         return $channels{$call};
 159 }
 160
 161 # obtain all the channel objects
 162 sub get_all
 163 {
 164         my ($pkg) = @_;
 165         return values(%channels);
 166 }
 167
 168 #
 169 # gimme all the ak1a nodes
 170 #
 171 sub get_all_nodes
 172 {
 173         my $ref;
 174         my @out;
 175         foreach $ref (values %channels) {
 176                 push @out, $ref if $ref->is_node;
 177         }
 178         return @out;
 179 }
 180
 181 # return a list of all users
 182 sub get_all_users
 183 {
 184         my $ref;
 185         my @out;
 186         foreach $ref (values %channels) {
 187                 push @out, $ref if $ref->is_user;
 188         }
 189         return @out;
 190 }
 191
 192 # return a list of all user callsigns
 193 sub get_all_user_calls
 194 {
 195         my $ref;
 196         my @out;
 197         foreach $ref (values %channels) {
 198                 push @out, $ref->{call} if $ref->is_user;
 199         }
 200         return @out;
 201 }
 202
 203 # obtain a channel object by searching for its connection reference
 204 sub get_by_cnum
 205 {
 206         my ($pkg, $conn) = @_;
 207         my $self;
 208
 209         foreach $self (values(%channels)) {
 210                 return $self if ($self->{conn} == $conn);
 211         }
 212         return undef;
 213 }
 214
 215 # get rid of a channel object [$obj->del()]
 216 sub del
 217 {
 218         my $self = shift;
 219
 220         $self->{group} = undef;         # belt and braces
 221         delete $channels{$self->{call}};
 222 }
 223
 224 # is it a bbs
 225 sub is_bbs
 226 {
 227         my $self = shift;
 228         return $self->{'sort'} eq 'B';
 229 }
 230
 231 sub is_node
 232 {
 233         my $self = shift;
 234         return $self->{'sort'} =~ /[ACRSX]/;
 235 }
 236 # is it an ak1a node ?
 237 sub is_ak1a
 238 {
 239         my $self = shift;
 240         return $self->{'sort'} eq 'A';
 241 }
 242
 243 # is it a user?
 244 sub is_user
 245 {
 246         my $self = shift;
 247         return $self->{'sort'} eq 'U';
 248 }
 249
 250 # is it a clx node
 251 sub is_clx
 252 {
 253         my $self = shift;
 254         return $self->{'sort'} eq 'C';
 255 }
 256
 257 # is it a spider node
 258 sub is_spider
 259 {
 260         my $self = shift;
 261         return $self->{'sort'} eq 'S';
 262 }
 263
 264 # is it a DXNet node
 265 sub is_dxnet
 266 {
 267         my $self = shift;
 268         return $self->{'sort'} eq 'X';
 269 }
 270
 271 # is it a ar-cluster node
 272 sub is_arcluster
 273 {
 274         my $self = shift;
 275         return $self->{'sort'} eq 'R';
 276 }
 277
 278 # for perl 5.004's benefit
 279 sub sort
 280 {
 281         my $self = shift;
 282         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 283 }
 284
 285 # handle out going messages, immediately without waiting for the select to drop
 286 # this could, in theory, block
 287 sub send_now
 288 {
 289         my $self = shift;
 290         my $conn = $self->{conn};
 291         return unless $conn;
 292         my $sort = shift;
 293         my $call = $self->{call};
 294
 295         for (@_) {
 296 #               chomp;
 297         my @lines = split /\n/;
 298                 for (@lines) {
 299                         $conn->send_now("$sort$call|$_");
 300                         dbg('chan', "-> $sort $call $_");
 301                 }
 302         }
 303         $self->{t} = time;
 304 }
 305
 306 #
 307 # the normal output routine
 308 #
 309 sub send                                                # this is always later and always data
 310 {
 311         my $self = shift;
 312         my $conn = $self->{conn};
 313         return unless $conn;
 314         my $call = $self->{call};
 315
 316         for (@_) {
 317 #               chomp;
 318         my @lines = split /\n/;
 319                 for (@lines) {
 320                         $conn->send_later("D$call|$_");
 321                         dbg('chan', "-> D $call $_");
 322                 }
 323         }
 324         $self->{t} = time;
 325 }
 326
 327 # send a file (always later)
 328 sub send_file
 329 {
 330         my ($self, $fn) = @_;
 331         my $call = $self->{call};
 332         my $conn = $self->{conn};
 333         my @buf;
 334
 335         open(F, $fn) or die "can't open $fn for sending file ($!)";
 336         @buf = <F>;
 337         close(F);
 338         $self->send(@buf);
 339 }
 340
 341 # this will implement language independence (in time)
 342 sub msg
 343 {
 344         my $self = shift;
 345         return DXM::msg($self->{lang}, @_);
 346 }
 347
 348 # stick a broadcast on the delayed queue (but only up to 20 items)
 349 sub delay
 350 {
 351         my $self = shift;
 352         my $s = shift;
 353
 354         $self->{delayed} = [] unless $self->{delayed};
 355         push @{$self->{delayed}}, $s;
 356         if (@{$self->{delayed}} >= 20) {
 357                 shift @{$self->{delayed}};   # lose oldest one
 358         }
 359 }
 360
 361 # change the state of the channel - lots of scope for debugging here :-)
 362 sub state
 363 {
 364         my $self = shift;
 365         if (@_) {
 366                 $self->{oldstate} = $self->{state};
 367                 $self->{state} = shift;
 368                 $self->{func} = '' unless defined $self->{func};
 369                 dbg('state', "$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n");
 370
 371                 # if there is any queued up broadcasts then splurge them out here
 372                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 373                         $self->send (@{$self->{delayed}});
 374                         delete $self->{delayed};
 375                 }
 376         }
 377         return $self->{state};
 378 }
 379
 380 # disconnect this channel
 381 sub disconnect
 382 {
 383         my $self = shift;
 384         my $user = $self->{user};
 385
 386         $user->close() if defined $user;
 387         $self->{conn}->disconnect;
 388         $self->del();
 389 }
 390
 391 #
 392 # just close all the socket connections down without any fiddling about, cleaning, being
 393 # nice to other processes and otherwise telling them what is going on.
 394 #
 395 # This is for the benefit of forked processes to prepare for starting new programs, they
 396 # don't want or need all this baggage.
 397 #
 398
 399 sub closeall
 400 {
 401         my $ref;
 402         foreach $ref (values %channels) {
 403                 $ref->{conn}->disconnect() if $ref->{conn};
 404         }
 405 }
 406
 407 #
 408 # Tell all the users that we have come in or out (if they want to know)
 409 #
 410 sub tell_login
 411 {
 412         my ($self, $m) = @_;
 413
 414         # send info to all logged in thingies
 415         my @dxchan = get_all_users();
 416         my $dxchan;
 417         foreach $dxchan (@dxchan) {
 418                 next if $dxchan == $self;
 419                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 420         }
 421 }
 422
 423 # various access routines
 424
 425 #
 426 # return a list of valid elements
 427 #
 428
 429 sub fields
 430 {
 431         return keys(%valid);
 432 }
 433
 434 #
 435 # return a prompt for a field
 436 #
 437
 438 sub field_prompt
 439 {
 440         my ($self, $ele) = @_;
 441         return $valid{$ele};
 442 }
 443
 444 # take a standard input message and decode it into its standard parts
 445 sub decode_input
 446 {
 447         my $dxchan = shift;
 448         my $data = shift;
 449         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 450
 451         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 452
 453         # the above regexp must work
 454         unless (defined $sort && defined $call && defined $line) {
 455 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 456                 dbg('err', "DUFF Line on $chcall: $data");
 457                 return ();
 458         }
 459
 460         if(ref($dxchan) && $call ne $chcall) {
 461                 dbg('err', "DUFF Line come in for $call on wrong channel $chcall" );
 462                 return();
 463         }
 464
 465         return ($sort, $call, $line);
 466 }
 467
 468 no strict;
 469 sub AUTOLOAD
 470 {
 471         my $self = shift;
 472         my $name = $AUTOLOAD;
 473         return if $name =~ /::DESTROY$/;
 474         $name =~ s/.*:://o;
 475
 476         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 477
 478         # this clever line of code creates a subroutine which takes over from autoload
 479         # from OO Perl - Conway
 480         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
 481     @_ ? $self->{$name} = shift : $self->{$name} ;
 482 }
 483
 484
 485 1;
 486 __END__;