perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35
  36 use strict;
  37 use vars qw(%channels %valid @ISA $count);
  38
  39 %channels = ();
  40 $count = 0;
  41
  42 %valid = (
  43                   call => '0,Callsign',
  44                   conn => '9,Msg Conn ref',
  45                   user => '9,DXUser ref',
  46                   startt => '0,Start Time,atime',
  47                   t => '9,Time,atime',
  48                   pc50_t => '5,Last PC50 Time,atime',
  49                   priv => '9,Privilege',
  50                   state => '0,Current State',
  51                   oldstate => '5,Last State',
  52                   list => '9,Dep Chan List',
  53                   name => '0,User Name',
  54                   consort => '5,Connection Type',
  55                   'sort' => '5,Type of Channel',
  56                   wwv => '0,Want WWV,yesno',
  57                   wcy => '0,Want WCY,yesno',
  58                   wx => '0,Want WX,yesno',
  59                   talk => '0,Want Talk,yesno',
  60                   ann => '0,Want Announce,yesno',
  61                   here => '0,Here?,yesno',
  62                   conf => '0,In Conference?,yesno',
  63                   dx => '0,DX Spots,yesno',
  64                   redirect => '0,Redirect messages to',
  65                   lang => '0,Language',
  66                   func => '5,Function',
  67                   loc => '9,Local Vars', # used by func to store local variables in
  68                   beep => '0,Want Beeps,yesno',
  69                   lastread => '5,Last Msg Read',
  70                   outbound => '5,outbound?,yesno',
  71                   remotecmd => '9,doing rcmd,yesno',
  72                   pagelth => '0,Page Length',
  73                   pagedata => '9,Page Data Store',
  74                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  75                   isolate => '5,Isolate network,yesno',
  76                   delayed => '5,Delayed messages,parray',
  77                   annfilter => '5,Announce Filter',
  78                   wwvfilter => '5,WWV Filter',
  79                   wcyfilter => '5,WCY Filter',
  80                   spotsfilter => '5,Spot Filter',
  81                   routefilter => '5,route Filter',
  82                   inannfilter => '5,Input Ann Filter',
  83                   inwwvfilter => '5,Input WWV Filter',
  84                   inwcyfilter => '5,Input WCY Filter',
  85                   inspotsfilter => '5,Input Spot Filter',
  86                   inroutefilter => '5,Input Route Filter',
  87                   passwd => '9,Passwd List,parray',
  88                   pingint => '5,Ping Interval ',
  89                   nopings => '5,Ping Obs Count',
  90                   lastping => '5,Ping last sent,atime',
  91                   pingtime => '5,Ping totaltime,parray',
  92                   pingave => '0,Ping ave time',
  93                   logininfo => '9,Login info req,yesno',
  94                   talklist => '0,Talk List,parray',
  95                   cluster => '5,Cluster data',
  96                   isbasic => '9,Internal Connection',
  97                   errors => '9,Errors',
  98                   route => '9,Route Data',
  99                   dxcc => '0,Country Code',
 100                   itu => '0,ITU Zone',
 101                   cq => '0,CQ Zone',
 102                   enhanced => '5,Enhanced Client,yesno',
 103                   senddbg => '8,Sending Debug,yesno',
 104                  );
 105
 106 # object destruction
 107 sub DESTROY
 108 {
 109         my $self = shift;
 110         for (keys %$self) {
 111                 if (ref($self->{$_})) {
 112                         delete $self->{$_};
 113                 }
 114         }
 115         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 116         $count--;
 117 }
 118
 119 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 120 sub alloc
 121 {
 122         my ($pkg, $call, $conn, $user) = @_;
 123         my $self = {};
 124
 125         die "trying to create a duplicate channel for $call" if $channels{$call};
 126         $self->{call} = $call;
 127         $self->{priv} = 0;
 128         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 129         if (defined $user) {
 130                 $self->{user} = $user;
 131                 $self->{lang} = $user->lang;
 132                 $user->new_group() if !$user->group;
 133                 $self->{group} = $user->group;
 134                 $self->{sort} = $user->sort;
 135         }
 136         $self->{startt} = $self->{t} = time;
 137         $self->{state} = 0;
 138         $self->{oldstate} = 0;
 139         $self->{lang} = $main::lang if !$self->{lang};
 140         $self->{func} = "";
 141
 142         # add in all the dxcc, itu, zone info
 143         my @dxcc = Prefix::extract($call);
 144         if (@dxcc > 0) {
 145                 $self->{dxcc} = $dxcc[1]->dxcc;
 146                 $self->{itu} = $dxcc[1]->itu;
 147                 $self->{cq} = $dxcc[1]->cq;
 148         }
 149
 150         $count++;
 151         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 152         bless $self, $pkg;
 153         return $channels{$call} = $self;
 154 }
 155
 156 # obtain a channel object by callsign [$obj = DXChannel->get($call)]
 157 sub get
 158 {
 159         my ($pkg, $call) = @_;
 160         return $channels{$call};
 161 }
 162
 163 # obtain all the channel objects
 164 sub get_all
 165 {
 166         my ($pkg) = @_;
 167         return values(%channels);
 168 }
 169
 170 #
 171 # gimme all the ak1a nodes
 172 #
 173 sub get_all_nodes
 174 {
 175         my $ref;
 176         my @out;
 177         foreach $ref (values %channels) {
 178                 push @out, $ref if $ref->is_node;
 179         }
 180         return @out;
 181 }
 182
 183 # return a list of all users
 184 sub get_all_users
 185 {
 186         my $ref;
 187         my @out;
 188         foreach $ref (values %channels) {
 189                 push @out, $ref if $ref->is_user;
 190         }
 191         return @out;
 192 }
 193
 194 # return a list of all user callsigns
 195 sub get_all_user_calls
 196 {
 197         my $ref;
 198         my @out;
 199         foreach $ref (values %channels) {
 200                 push @out, $ref->{call} if $ref->is_user;
 201         }
 202         return @out;
 203 }
 204
 205 # obtain a channel object by searching for its connection reference
 206 sub get_by_cnum
 207 {
 208         my ($pkg, $conn) = @_;
 209         my $self;
 210
 211         foreach $self (values(%channels)) {
 212                 return $self if ($self->{conn} == $conn);
 213         }
 214         return undef;
 215 }
 216
 217 # get rid of a channel object [$obj->del()]
 218 sub del
 219 {
 220         my $self = shift;
 221
 222         $self->{group} = undef;         # belt and braces
 223         delete $channels{$self->{call}};
 224 }
 225
 226 # is it a bbs
 227 sub is_bbs
 228 {
 229         my $self = shift;
 230         return $self->{'sort'} eq 'B';
 231 }
 232
 233 sub is_node
 234 {
 235         my $self = shift;
 236         return $self->{'sort'} =~ /[ACRSX]/;
 237 }
 238 # is it an ak1a node ?
 239 sub is_ak1a
 240 {
 241         my $self = shift;
 242         return $self->{'sort'} eq 'A';
 243 }
 244
 245 # is it a user?
 246 sub is_user
 247 {
 248         my $self = shift;
 249         return $self->{'sort'} eq 'U';
 250 }
 251
 252 # is it a clx node
 253 sub is_clx
 254 {
 255         my $self = shift;
 256         return $self->{'sort'} eq 'C';
 257 }
 258
 259 # is it a spider node
 260 sub is_spider
 261 {
 262         my $self = shift;
 263         return $self->{'sort'} eq 'S';
 264 }
 265
 266 # is it a DXNet node
 267 sub is_dxnet
 268 {
 269         my $self = shift;
 270         return $self->{'sort'} eq 'X';
 271 }
 272
 273 # is it a ar-cluster node
 274 sub is_arcluster
 275 {
 276         my $self = shift;
 277         return $self->{'sort'} eq 'R';
 278 }
 279
 280 # for perl 5.004's benefit
 281 sub sort
 282 {
 283         my $self = shift;
 284         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 285 }
 286
 287 # handle out going messages, immediately without waiting for the select to drop
 288 # this could, in theory, block
 289 sub send_now
 290 {
 291         my $self = shift;
 292         my $conn = $self->{conn};
 293         return unless $conn;
 294         my $sort = shift;
 295         my $call = $self->{call};
 296
 297         for (@_) {
 298 #               chomp;
 299         my @lines = split /\n/;
 300                 for (@lines) {
 301                         $conn->send_now("$sort$call|$_");
 302                         dbg("-> $sort $call $_") if isdbg('chan');
 303                 }
 304         }
 305         $self->{t} = time;
 306 }
 307
 308 #
 309 # send later with letter (more control)
 310 #
 311
 312 sub send_later
 313 {
 314         my $self = shift;
 315         my $conn = $self->{conn};
 316         return unless $conn;
 317         my $sort = shift;
 318         my $call = $self->{call};
 319
 320         for (@_) {
 321 #               chomp;
 322         my @lines = split /\n/;
 323                 for (@lines) {
 324                         $conn->send_later("$sort$call|$_");
 325                         dbg("-> $sort $call $_") if isdbg('chan');
 326                 }
 327         }
 328         $self->{t} = time;
 329 }
 330
 331 #
 332 # the normal output routine
 333 #
 334 sub send                                                # this is always later and always data
 335 {
 336         my $self = shift;
 337         my $conn = $self->{conn};
 338         return unless $conn;
 339         my $call = $self->{call};
 340
 341         for (@_) {
 342 #               chomp;
 343         my @lines = split /\n/;
 344                 for (@lines) {
 345                         $conn->send_later("D$call|$_");
 346                         dbg("-> D $call $_") if isdbg('chan');
 347                 }
 348         }
 349         $self->{t} = time;
 350 }
 351
 352 # send a file (always later)
 353 sub send_file
 354 {
 355         my ($self, $fn) = @_;
 356         my $call = $self->{call};
 357         my $conn = $self->{conn};
 358         my @buf;
 359
 360         open(F, $fn) or die "can't open $fn for sending file ($!)";
 361         @buf = <F>;
 362         close(F);
 363         $self->send(@buf);
 364 }
 365
 366 # this will implement language independence (in time)
 367 sub msg
 368 {
 369         my $self = shift;
 370         return DXM::msg($self->{lang}, @_);
 371 }
 372
 373 # stick a broadcast on the delayed queue (but only up to 20 items)
 374 sub delay
 375 {
 376         my $self = shift;
 377         my $s = shift;
 378
 379         $self->{delayed} = [] unless $self->{delayed};
 380         push @{$self->{delayed}}, $s;
 381         if (@{$self->{delayed}} >= 20) {
 382                 shift @{$self->{delayed}};   # lose oldest one
 383         }
 384 }
 385
 386 # change the state of the channel - lots of scope for debugging here :-)
 387 sub state
 388 {
 389         my $self = shift;
 390         if (@_) {
 391                 $self->{oldstate} = $self->{state};
 392                 $self->{state} = shift;
 393                 $self->{func} = '' unless defined $self->{func};
 394                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 395
 396                 # if there is any queued up broadcasts then splurge them out here
 397                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 398                         $self->send (@{$self->{delayed}});
 399                         delete $self->{delayed};
 400                 }
 401         }
 402         return $self->{state};
 403 }
 404
 405 # disconnect this channel
 406 sub disconnect
 407 {
 408         my $self = shift;
 409         my $user = $self->{user};
 410
 411         $user->close() if defined $user;
 412         $self->{conn}->disconnect;
 413         $self->del();
 414 }
 415
 416 #
 417 # just close all the socket connections down without any fiddling about, cleaning, being
 418 # nice to other processes and otherwise telling them what is going on.
 419 #
 420 # This is for the benefit of forked processes to prepare for starting new programs, they
 421 # don't want or need all this baggage.
 422 #
 423
 424 sub closeall
 425 {
 426         my $ref;
 427         foreach $ref (values %channels) {
 428                 $ref->{conn}->disconnect() if $ref->{conn};
 429         }
 430 }
 431
 432 #
 433 # Tell all the users that we have come in or out (if they want to know)
 434 #
 435 sub tell_login
 436 {
 437         my ($self, $m) = @_;
 438
 439         # send info to all logged in thingies
 440         my @dxchan = get_all_users();
 441         my $dxchan;
 442         foreach $dxchan (@dxchan) {
 443                 next if $dxchan == $self;
 444                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 445         }
 446 }
 447
 448 # various access routines
 449
 450 #
 451 # return a list of valid elements
 452 #
 453
 454 sub fields
 455 {
 456         return keys(%valid);
 457 }
 458
 459 #
 460 # return a prompt for a field
 461 #
 462
 463 sub field_prompt
 464 {
 465         my ($self, $ele) = @_;
 466         return $valid{$ele};
 467 }
 468
 469 # take a standard input message and decode it into its standard parts
 470 sub decode_input
 471 {
 472         my $dxchan = shift;
 473         my $data = shift;
 474         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 475
 476         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 477
 478         # the above regexp must work
 479         unless (defined $sort && defined $call && defined $line) {
 480 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 481                 dbg("DUFF Line on $chcall: $data") if isdbg('err');
 482                 return ();
 483         }
 484
 485         if(ref($dxchan) && $call ne $chcall) {
 486                 dbg("DUFF Line come in for $call on wrong channel $chcall") if isdbg('err');
 487                 return();
 488         }
 489
 490         return ($sort, $call, $line);
 491 }
 492
 493 no strict;
 494 sub AUTOLOAD
 495 {
 496         my $self = shift;
 497         my $name = $AUTOLOAD;
 498         return if $name =~ /::DESTROY$/;
 499         $name =~ s/.*:://o;
 500
 501         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 502
 503         # this clever line of code creates a subroutine which takes over from autoload
 504         # from OO Perl - Conway
 505         *{$AUTOLOAD} = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}} ;
 506     @_ ? $self->{$name} = shift : $self->{$name} ;
 507 }
 508
 509
 510 1;
 511 __END__;